PowerQueryでの日付のルール決めについて

Question

前提

PowerQueryでシステムから吐き出された日付データを
以下のようなルールで前半／後半とわかるデータに作り替えたいのですが
月によってルール決めをしないといけないため、どういった施しをすればいいのかがわかりません。

実現したいこと

以下のように変換を行いたいです。カレンダーテーブルのようなものを設けられないか試しているものの、月ごとのゆれ？に対応ができず。
加工前が右手になるのですが、たとえば2022101は「2022年10月の1週目」というデータになっています。

加工後　　加工前
10月1H 　2022101　 月6週の場合、1～３週は1H、4～６週は2H
10月1H 　2022102
10月1H　 2022103
10月2H　 2022104
10月2H 　2022105
10月2H 　2022106
11月1H 　2022111　 月5週以下の場合、1～２週は1H、3～週は2H
11月1H 　2022112
11月2H 　2022113
11月2H 　2022114
11月2H 　2022115

Comments

[sk.exe]

> システムから吐き出された日付データ

> たとえば2022101は「2022年10月の1週目」というデータになっています。

元のファイル形式が csv か xlsx 辺りだとして、システムからファイル出力された時点で既にそういう形式のデータ（厳密に言えば「日」を含んでいないので日付データではない）が格納されている、ということでしょうか。

[mit233]

ご質問ありがとうございます。おっしゃる通りで、
日付のデータは含まれてなく、加工前と記載したキーワードのみが、CSVでファイル出力されています。

Answer 1

日付のデータは含まれてなく、加工前と記載したキーワードのみが、CSVでファイル出力されています。

列名
2022101
2022102
2022103
2022104
2022105
2022106
2022111
2022112
2022113
2022114
2022115

とりあえずこういうファイルがShift-JISで保存されているとして、
おおまかな仕組みとしては下記のような形でよろしいのではないかと。

(1) 加工前の値を text 型として扱い、[年月]と[週]に分割する。

(2) [年月]を date 型のデータに変換し、その日付が含まれる年月の最終週（週の数）を取得する。

(3) [週]を number 型のデータとして扱い、その値が「年月の最終週（上記 2 の結果）を 2 で割った結果」以下なら "1H"、そうではなければ "2H" という文字列を取得する。

(4) [月初日]の値をフォーマットした文字列と上記 3 の結果を文字列結合する。

let
    Source = Csv.Document(File.Contents("C:\FolderName\FileName.csv"),[Delimiter=",", Encoding=932, QuoteStyle=QuoteStyle.None]),
    PromoteHeaders = Table.PromoteHeaders(Source, [PromoteAllScalars=true]),
    ChangedType = Table.TransformColumnTypes(PromoteHeaders,{{"列名", type text}}),
    GetYearAndMonth = Table.AddColumn(ChangedType, "年月", each Text.Middle([列名],0,6)),
    GetWeek = Table.AddColumn(GetYearAndMonth, "週", each Number.FromText(Text.Middle([列名],6,1))),
    GetStartOfMonth = Table.AddColumn(GetWeek, "月初日", each Date.FromText([年月], [Format="yyyyMM", Culture="ja-JP"])),
    GetEndOfMonth = Table.AddColumn(GetStartOfMonth, "月末日", each Date.EndOfMonth([月初日])),
    GetWeekOfMonth = Table.AddColumn(GetEndOfMonth, "月の最終週", each Date.WeekOfMonth([月末日])),
    GetPeriodOfHelfMonth = Table.AddColumn(GetWeekOfMonth, "月半期区分", each if [週] <= ([月の最終週] / 2) then "1H" else "2H"), 
    GetResult = Table.AddColumn(GetPeriodOfHelfMonth, "月と月半期区分を結合", each Date.ToText([月初日],[Format="MM月", Culture="ja-JP"]) & [月半期区分])
in
    GetResult

ファイルパスや列名などについては適宜修正して下さい。

Comments

[mit233]

ご回答ありがとうございます。
頂いたやり方で解決ができました。