エクセルで各データの個数を集計し、個数順に並べたい

Question

商品名を記載したデータがあります。

商品
ぶどう
みかん
みかん
レモン
なし
なし
みかん
ぶどう

このデータを商品の個数順でまとめ、個数順に並べ替えたいです。
可能であれば関数のみで行いたいです。
(個数が同数の場合の表示順に指定はありません)

商品	個数
みかん	3
ぶどう	2
なし	2
レモン	1

※下に空白列が続いても可

---

各商品の初出列を出す方法で、個数ごとに集計まではできたのですが、
その後、E列・F列の表を値のみ貼り付けしてソートが必要です。
（E列・F列にも数式が入っているため、ソートしても並び順が変わらないため）
E列・F列の表を参照し、LARGE関数などを使い、新しい表を作れば、
個数順に並び替えた表ができそうですが、作り方が分かりません。

※B列の式 =IF(COUNTIF(B$2:B2,B2)=1,ROW(),"")
※E列の式 =IF(ROW(A1)<=COUNT(B$2:B$9),INDEX(A:A,SMALL(B$2:B$9,ROW(A1)),0),"")
※F列の式 =IF(E2<>"",COUNTIF(test!A$2:A$9,E2),"")

	A	B	C	D	E	F
1	商品	初出列			商品	個数
2	ぶどう	2			ぶどう	2
3	みかん	3			みかん	3
4	みかん				レモン	1
5	レモン	5			なし	2
6	なし	6
7	なし
8	みかん
9	ぶどう

各商品の個数をカウントする方法から作る方法もあると思いますが、
こちらも進め方が分かりません。
※B列の式　=COUNTIF(A$2:$A$9,A2)

	A	B
1	商品	個数
2	ぶどう	2
3	みかん	3
4	みかん	3
5	レモン	1
6	なし	2
7	なし	2
8	みかん	3
9	ぶどう	2

Excelのバージョンは2013です。
作業列の使用、表の作成に制限はありません。
よろしくお願いします。

Answer 1

[B2] =IF(COUNTIF(A$2:A2,A2)>1,"",COUNTIF(A$2:A$9,A2))
[C2] =IFERROR(B2+ROW()*0.0001,"")
[D2] =LARGE(C$2:C$9,ROW()-1)
[E2] =MATCH(D2,C$2:C$9,0)

[G2] =IFERROR(INDEX(A$2:A$9,$E2),"")
[H2] =IFERROR(INDEX(B$2:B$9,$E2),"")

@jinojiさんの回答のパクりです。
エラーとなる部分を修正し、分かり易く整理したものになります。
なのでベストアンサーは辞退します。

Comments

[nkym771]

エラーの修正・内容整理、ありがとうございます。
助かりました。

Answer 2

手元に2013がないのでちゃんと確認できませんが、こんな感じでどうでしょう。

 [B2] =IF(COUNTIF($A1:$A2)>1,"",COUNTIF($A$2:$A$9,$A2))
 [C2] =IF(LEN($B2)=0,"",$B2+1-ROW()*0.00001)
 [E2] =IFERROR(INDEX($A$2:$A$9,MATCH(LARGE($C$2:$C$9,ROW()-1,$C$2:$C$9,0)),"")
 [F2] =IF(LEN($E2)=0,"",COUNTIF($A$2:$A$9,$E2))

※それぞれの数式は行数分コピーしてください

---

なお、最新のExcelやMicrosoft365だとこんな感じです。

 [E2] =SORTBY(UNIQUE(A2:A9),COUNTIF(A2:A9,UNIQUE(A2:A9)),-1)
 [F2] =COUNTIF(A2:A9,E2#)

Comments

[nkym771]

ありがとうございました。
お二人の回答で解決できました。