accessにおいて、フォーム間でデータのやり取りをしたい

Question

前提

accessについて質問します。
フォームAからフォームBに値を渡して、表示したいのですがうまくいきません。

実現したいこと

フォーム間で値の受け渡しをしたい

該当のソースコード

'フォームA
Public test As Integer
Private Sub 詳細情報_Click()
    'オートインクリメントを格納
    test = Me!id
    'フォームBを開く
    DoCmd.OpenForm "フォームB", , , , , ID
    
End Sub

'フォームB
Private Sub コマンド9_Click()
    '引数の有無によってメッセージを出し分ける
    MsgBox test '空文字が格納されていた'
    If IsNull(Me.OpenArgs) Then
        'こっちに行った
        MsgBox "引数なし"
    Else
        MsgBox Me.OpenArgs
    End If
End Sub

試したこと

試したことは主に３つ
1つ目は、DoCmd.OpenFormの引数を、DoCmd.OpenForm "フォームB", , , , , ,IDにし(1つ引数を増やしました)、MsgBox testで確認しました。しかし空文字でした
2つ目は、DoCmd.OpenFormの引数を、DoCmd.OpenForm "フォームB", , , , , IDにし(元に戻しました)、Private Sub コマンド9_Clickの引数をCancel As Integerにして、IsNull(Me.OpenArgs)で確認、
「プロシージャの宣言が、イベントまたはプロシージャの定義と一致していません」というエラーがでてきて落ちました
3つ目はPublic test As IntegerをフォームAに書き、MsgBox testで出力。結果空文字

Answer 1

フォームを開くときに、そのフォームに値を渡す方法としては、OpenArgs引数というものが用意されています。
せっかく用意してくれているので、それを使うのがいいでしょう。

OpenFormにカーソルをおいてF1キーを押すと下記のヘルプページが表示されます。

DoCmd.OpenForm メソッド (Access) | Microsoft Learn
構文
expression.OpenForm (FormName, View, FilterName, WhereCondition, DataMode, WindowMode, OpenArgs)
パラメータ
・・・
OpenArgs 省略可能 バリアント型 文字列式。 この式は、フォームの OpenArgs プロパティを設定するために使用されます。 この設定は、Open イベント プロシージャなどのフォーム モジュールのコードで使用可能です。 OpenArgs プロパティは、マクロや式でも参照できます。

'フォームA
Public test As Integer
Private Sub 詳細情報_Click()
    'フォームBを開く
    '質問のコードは引数の位置が間違っている(WindowMode になっている)
    DoCmd.OpenForm "フォームB", , , , , , Me!id
    '下記の書き方もできます。引数が多いことは下記の方が分かりやすい。
    'DoCmd.OpenForm "フォームB",  OpenArgs:=Me!id   
End Sub

上記でフォームBのOpenArgsプロパティにMe!idが格納されている。

'フォームB
Private Sub コマンド9_Click()
    If IsNull(Me.OpenArgs) Then
        MsgBox "引数なし"
    Else
        MsgBox Me.OpenArgs
    End If
End Sub

---

「フォーム間で値の受け渡しをしたい」という質問に対する回答は上記になりますが、
その前に何をするためのこの手段を選択したのでしょうか。

詳細情報_Click() というのは、前の質問の
accessにおいて、繰り返しボタンの識別
上記の「詳細」ボタンのことでしょうか。
だとすると、今回の目的は、
一覧フォーム(帳票フォーム)のカレントレコードと同じIDのレコードを詳細フォーム(単票フォーム)に表示したいということではないですか。

だとしたら、
もう一度、上のリンク先の内容をみると、WhereCondition という引数があります。

WhereCondition 省略可能 バリアント型 (Variant) 有効な SQL WHERE 句を文字列式で指定します。ただし、WHERE という語を指定する必要はありません。

「SQL WHERE 句」つまり抽出条件式を渡すことができるということです。
つまり、下記でクリックしたカレントレコードのidと一致するレコードを抽出して表示できます。

    DoCmd.OpenForm "フォームB", , , "id=" & Me.id 
    '下記の書き方もできます。
    'DoCmd.OpenForm "フォームB",  WhereCondition:="id=" & Me.id   

こうすれば、フォームBのコードは不要です。

Comments

[syosinsya109]

回答ありがとうございます。
このプログラムではフィルターに指定したwhere句が入ると思いますが、データ一つ一つを取り出すことは可能なのでしょうか。
例)Me.ID

[hatena19]

フォームBがテーブルと連結したフォームなら、IDと一致したレコードが抽出されますので、そのレコードの全フィールドの値を取り出すことは可能です。IDも当然可能です。

一覧フォームから詳細データを表示したいという目的の場合のコード例になります。

Answer 2

1つ目は、DoCmd.OpenFormの引数を、DoCmd.OpenForm "フォームB", , , , , ,IDにし(1つ引数を増やしました)、MsgBox testで確認しました。しかし空文字でした

ここでの test は[フォームA]のフォームモジュールのモジュールレベルで宣言された変数ではないため。

3つ目はPublic test As IntegerをフォームAに書き、MsgBox testで出力。結果空文字

同上。

とりあえず[フォームB]のフォームモジュールの先頭にOption Explicit ステートメントを記述されることをお奨めします。

2つ目は、DoCmd.OpenFormの引数を、DoCmd.OpenForm "フォームB", , , , , IDにし(元に戻しました)

それでは引数 OpenArgs ではなく引数 WindowMode に[ID]の値を渡すことになってしまいます。

フォームAからフォームBに値を渡して、表示したい

既に開かれている[フォームA]のコントロール[ID]の値を別のモジュールから直接参照したいのであれば、次のように記述なさればよろしいでしょう。

MsgBox Forms![フォームA]![ID].Value

Comments

[syosinsya109]

回答ありがとうございます。いくつか質問させてください

＞フォームモジュールのモジュールレベルで宣言された変数ではないため。
とはどういいことでしょうか。publicではだめなのでしょうか

＞次のように記述なさればよろしいでしょう
そのプログラムを使用するとして、デメリットはあるのでしょうか
例)更新したら値が消える。2画面以上の値渡しができない等

[sk.exe]

> publicではだめなのでしょうか

その変数が宣言されたモジュールの種類や場所によって、変数のスコープ（適用範囲）は異なります。

フォームモジュールやクラスモジュールのモジュールレベルで宣言された Public 変数は、その変数名だけを記述しても他のモジュールから参照することはできません。

今回のケースならば

MsgBox Forms![フォームA].test

ように記述すれば他のモジュールからでも一応は参照できますが、その時点での[フォームA]の[ID]を直接参照できればよいなら、いちいち仲介用の変数を設ける必要はないでしょう。

> そのプログラムを使用するとして、デメリットはあるのでしょうか

異なるフォーム間で値の受け渡しを行なう目的が不明であるため、具体的にどのようなケースにおいて問題が発生し得るかについては今のところお答えいたしかねます。

[syosinsya109]

なるほど。。
為になる回答をありがとうございました