AccessVBAで作ったExcelファイルのセル結合時の確認メッセージを非表示にしたい。

Question

実現したいこと

AccessVBAからExcelファイルのセル結合時の確認メッセージを非表示にしたい。

発生している問題・エラーメッセージ

現在AccessVBAからExcelを操作してセル結合をしようとしているのですが、左上のセルを参照しますがよろしいですか？的なメッセージが出てきます。

該当のソースコード

’①セル結合では意味無し？　そのままメッセージが表示される
 DoCmd.SetWarnings False
    .Range(.cells(1,1),.cells(4,1)).Merge
 DoCmd.SetWarnings True

’②コンパイルエラー(多分ExcelVBAのコード)
Application.DisplayAlerts = False
　.Range(.cells(1,1),.cells(4,1)).Merge
Application.DisplayAlerts = False

試したこと

検索するも
①はAccessクエリを操作するときに使う？(DELETE文等)
②はExcelVBA上で書いたら多分動く(しかしAccessVBAでやる必要あり)
今回のようなAccessVBAからExcelを操作するときにどうしたらセル結合のメッセージをなくせるでしょうか？

詳しい方いらっしゃいましたら、ご教授ください。
よろしくお願いいたします。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Comments

[nonoshu]

１）補足情報に質問者さんの環境（OS,OAccess、Excelそれぞれのバージョン）を追記出来ますか？
２）ソースコードは端折らず出来るだけそのまま掲載できますか？
（公開できない情報などは伏せ字にしても構いません）
（私が自作で書いたコードではセル結合時に何もメッセージは表示されませんでしたので）
（環境ではなく省略されている部分に原因があるかもしれないと考えました）

[ataru2222]

回答して頂き、ありがとうございます。
ちなみに①のコードでいけましたか？
②のコードでいけましたか？

書いておりませんでしたが、結合する２つ以上のセルに値が入っている状態でも出ませんでしたか？

よろしくお願いいたします。

[sazi]

withがありませんが？
コードは省略せずに全て投稿して下さい。

Answer 1

Sub Test()

    Dim xlsApp As Object
    Dim xlsWorkbook As Object
    Dim xlsWorksheet As Object
    
    Set xlsApp = CreateObject("Excel.Application")
    xlsApp.Visible = True
    
    Set xlsWorkbook = xlsApp.Workbooks.Add
    Set xlsWorksheet = xlsWorkbook.Worksheets(1)
    
    With xlsWorksheet
        'A1セルの値を設定
        .Cells(1, 1).Value = 1
        'A1セルとの結合時に警告メッセージを出させるため敢えてB1セルの値を設定
        .Cells(1, 2).Value = 2
        'Excelアプリケーションの警告メッセージを無効にする
        xlsApp.DisplayAlerts = False
        'A1セルからB1セルまでの範囲を結合
        .Range(.Cells(1, 1), .Cells(1, 2)).Merge
        'Excelアプリケーションの警告メッセージを有効にする
        xlsApp.DisplayAlerts = True
        .Range(.Cells(1, 1), .Cells(1, 2)).Select
    End With

    Set xlsWorksheet = Nothing
    Set xlsWorkbook = Nothing
    Set xlsApp = Nothing

End Sub

基本的には以上のような流れでよいでしょう。

DoCmd.SetWarnings False

これはAccessが出すシステムメッセージを抑制する命令であって、Excelには影響しません。

Application.DisplayAlerts = False

このステートメントをAccessデータベースのモジュールに記述されているのであれば、
ここでの Application とは実行中の Access.Application オブジェクトであって、
（ Access 側から操作されている）Excel.Application オブジェクトではありません。

Access.Application オブジェクトに DisplayAlerts というメンバーはありませんので、
そもそもこのコードを実行することは出来ません。

Comments

[ataru2222]

sk.exe様
回答していただきありがとうございます。

やはりできなかったのですね。
詳しく解説していただいたこと、本当に勉強になりました。

１、forで１行目以外の値を削除
２、値が変わったら(最終行の一つ手前で)セル結合
で実装しました。

ありがとうございました。

[sk.exe]

> やはりできなかったのですね。

いえ、「Access.Applicationオブジェクトの」ではなく「Excel.Applicationオブジェクトの」DisplayAlertsプロパティの値を False に設定してから任意のExcel.RangeオブジェクトのMergeメソッドを実行すればよい、と申し上げています。
私が例示したサンプルコードとコメントを再度読み直してください。

[ataru2222]

sk.exe様
Set xlsApp = CreateObject("Excel.Application")

xlsApp.DisplayAlerts = False

とすればExcel側の機能を呼び出せるということなんですね。勉強になりました。
本当にありがとうございました。