VBSでコンパイルエラー発生

Question

実現したいこと

VBAで動いていたコードをVBSに移行するのに悩んでいます。
下記のコード、Likeが使えなくてRegExpを利用したところですが
そもそも下記の「ReDim Preserve tmp(1 To i)の行で
コンパイルエラーが出ます
具体的には「)がありません」とのこと
下記以外の場所にも怪しいところはなさそうで
該当の行を外すとエラーは消えます

発生している問題・エラーメッセージ

')'がありません。
800A03EE
Microsoft VBScript コンパイルエラー

該当のソースコード

Dim temp()
Set regEx = CreateObject("VBScript.RegExp")
regEx.Pattern = testPattern

For Each test In fso.GetFolder(FolderPath).Files
 If regEx.Test(test.Name) Then
  ReDim Preserve tmp(1 To i)
  Set tmp(i) = f
  i = i + 1
 End If
Next

試したこと

他のエラーはなんとか検索してなおしてきましたが
ここが謎でつまづいています…お助けいただければ幸いです

Answer 1

VBScript では下限値、上限値を指定して配列を宣言できません。
配列のサイズ変更は、新しく配列を用意してコピーするので、配列が大きくなると遅くなります。
大き目の配列を用意し、複数件まとめて拡張するようにしたほうが良いです。

例)

Option Explicit
Dim fso, f
Dim tmp(), count
Dim i
Redim tmp(100)
Set fso = CreateObject("Scripting.FileSystemObject")
count = 0
For Each f In fso.GetFolder("C:\").Files
	count = count + 1
	If count > Ubound(tmp) Then
		Redim Preserve tmp(count + 100)
	End If
    Set tmp(count) = f
Next
For i = 1 To count
	MsgBox tmp(i).Name
Next

Scripting.Dictionary を使うのも良いかと思います。

例)

Option Explicit
Dim fso, f
Dim tmp, i
Set fso = CreateObject("Scripting.FileSystemObject")
Set tmp = CreateObject("Scripting.Dictionary")
i = 0
For Each f In fso.GetFolder("C:\").Files
	i = i + 1
	Set tmp(i) = f
Next
For i = 1 To tmp.Count
	MsgBox tmp(i).Name
Next