[VB.NET] 無効化されたDataGridViewボタンセルのClickイベントが上がらないようにしたい

Question

実現したいこと

DataGridView コントロールのボタン列のボタンを無効にする
こちらのサイトを参考にDataGridViewButtonColumnのカスタムコントロールを作成しました。

ここで紹介されているソースは見た目を変更するだけなので、無効化されたボタンをクリックしてもCellClickイベントやCellContentClickイベントは発生してしまいます。
イベント発生時に都度ボタンの状態を確認して無効ならば処理をしないという手もありますが、
そもそもイベントが上がらないようにできないかと考えました。

発生している問題・分からないこと

OnClickとOnContentClickをオーバーライドし、ボタンが有効な場合のみ基底クラスのメソッドを呼ぶようにしました。
これによってイベントが上がらなくなると踏んでいましたが、CellClickイベントやCellContentClickイベントは上がってしまいました。

該当のソースコード

Public Class DataGridViewDisableButtonColumn
    Inherits DataGridViewButtonColumn

    Public Sub New()
        Me.CellTemplate = New DataGridViewDisableButtonCell
    End Sub

End Class

Public Class DataGridViewDisableButtonCell
    Inherits DataGridViewButtonCell

    Private _enabled As Boolean

    Public Property Enabled() As Boolean
        Get
            Return _enabled
        End Get
        Set(ByVal value As Boolean)
            _enabled = value
        End Set
    End Property

    ' Override the Clone method so that the Enabled property is copied.
    Public Overrides Function Clone() As Object
        Dim cell As DataGridViewDisableButtonCell = CType(MyBase.Clone(), DataGridViewDisableButtonCell)
        Return cell
    End Function

    ' By default, enable the button cell.
    Public Sub New()
        Me._enabled = True
    End Sub

    Protected Overrides Sub Paint(
        ByVal graphics As System.Drawing.Graphics, ByVal clipBounds As System.Drawing.Rectangle, ByVal cellBounds As System.Drawing.Rectangle,
        ByVal rowIndex As Integer, ByVal elementState As System.Windows.Forms.DataGridViewElementStates,
        ByVal value As Object, ByVal formattedValue As Object, ByVal errorText As String,
        ByVal cellStyle As System.Windows.Forms.DataGridViewCellStyle, ByVal advancedBorderStyle As System.Windows.Forms.DataGridViewAdvancedBorderStyle,
        ByVal paintParts As System.Windows.Forms.DataGridViewPaintParts
    )
        If (Me._enabled) Then
            ' The button cell is enabled, so let the base class handle the painting.
            MyBase.Paint(graphics, clipBounds, cellBounds, rowIndex, elementState, value, formattedValue, errorText, cellStyle, advancedBorderStyle, paintParts)

        Else
            ' The button cell is disabled, so paint the border,
            ' background, and disabled button for the cell.

            ' Draw the cell background, if specified.
            If (paintParts And DataGridViewPaintParts.Background = DataGridViewPaintParts.Background) Then
                Dim cellBackground As SolidBrush = New SolidBrush(cellStyle.BackColor)

                graphics.FillRectangle(cellBackground, cellBounds)
                cellBackground.Dispose()
            End If

            ' Draw the cell borders, if specified.
            If (paintParts And DataGridViewPaintParts.Border = DataGridViewPaintParts.Border) Then
                PaintBorder(graphics, clipBounds, cellBounds, cellStyle, advancedBorderStyle)
            End If

            ' Calculate the area in which to draw the button.
            Dim buttonArea As Rectangle = cellBounds
            Dim buttonAdjustment As Rectangle = Me.BorderWidths(advancedBorderStyle)
            buttonArea.X = buttonArea.X + buttonAdjustment.X
            buttonArea.Y = buttonArea.Y + buttonAdjustment.Y
            buttonArea.Height = buttonArea.Height - buttonAdjustment.Height
            buttonArea.Width = buttonArea.Width - buttonAdjustment.Width

            ' Draw the disabled button.
            ButtonRenderer.DrawButton(graphics, buttonArea, VisualStyles.PushButtonState.Disabled)

            ' Draw the disabled button text.
            If (Me.FormattedValue.GetType Is GetType(String)) Then
                TextRenderer.DrawText(graphics, Me.FormattedValue.ToString, Me.DataGridView.Font, buttonArea, SystemColors.GrayText)
            End If
        End If
    End Sub

    Protected Overrides Sub OnClick(e As DataGridViewCellEventArgs)
        If (Me._enabled) Then
            MyBase.OnClick(e)
        End If
    End Sub

    Protected Overrides Sub OnContentClick(e As DataGridViewCellEventArgs)
        If (Me._enabled) Then
            MyBase.OnContentClick(e)
        End If
    End Sub

End Class

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

Google等で検索すると通常のButtonの例は出てきます。
Buttonのカスタムコントロールを作成した上で、上記と同様にOnClickをオーバーライドし、基底クラスのOnClickを呼ばないようにしたところ、こちらは期待通りにClickイベントが上がりませんでした。

そもそもオーバーライドしたOnClickはDataGridViewButtonCellのものなので、DataGridViewのCellClick/CellContentClickは止められないということでしょうか？

補足

開発環境：
Microsoft Visual Studio Enterprise 2015（Version 14.0.25431.01 Update 3）
Microsoft .NET Framework（Version 4.8.09037）

Answer 1

そもそもオーバーライドしたOnClickはDataGridViewButtonCellのものなので、DataGridViewのCellClick/CellContentClickは止められないということでしょうか？

DataGridViewButtonCell のソースを見ると、DataGridViewButtonColumn(DataGridViewCell) の OnCellClick メソッドは DataGridView の OnCellClick メソッドから呼ばれているので、DataGridViewButtonColumn のみで解決するのは難しそうです。
https://referencesource.microsoft.com/#System.Windows.Forms/winforms/Managed/System/WinForms/DataGridViewMethods.cs,d5fd6e0c66ee6656

DataGridView を継承して対応しましょう。

Public Class DataGridViewEx
    Inherits DataGridView

    Public Overridable Function GetDataGridViewCell(e As DataGridViewCellEventArgs) As DataGridViewCell
        If e.RowIndex >= 0 Then
            Dim dataGridViewRow As DataGridViewRow = Me.Rows.SharedRow(e.RowIndex)
            If e.ColumnIndex >= 0 Then
                Return dataGridViewRow.Cells(e.ColumnIndex)
            Else
                Return dataGridViewRow.HeaderCell
            End If
        Else
            If e.ColumnIndex >= 0 Then
                Return Me.Columns(e.ColumnIndex).HeaderCell
            Else
                Return Me.TopLeftHeaderCell
            End If
        End If
    End Function

    Protected Overrides Sub OnCellClick(e As DataGridViewCellEventArgs)
        Dim buttonCell As DataGridViewDisableButtonCell =
            TryCast(GetDataGridViewCell(e), DataGridViewDisableButtonCell)
        If buttonCell IsNot Nothing Then
            If buttonCell.Enabled Then
                MyBase.OnCellClick(e)
            End If
        Else
            MyBase.OnCellClick(e)
        End If
    End Sub

    Protected Overrides Sub OnCellContentClick(e As DataGridViewCellEventArgs)
        Dim buttonCell As DataGridViewDisableButtonCell =
            TryCast(GetDataGridViewCell(e), DataGridViewDisableButtonCell)
        If buttonCell IsNot Nothing Then
            If buttonCell.Enabled Then
                MyBase.OnCellContentClick(e)
            End If
        Else
            MyBase.OnCellContentClick(e)
        End If
    End Sub

End Class

余談ですが、私は DataGridView を素で使うことはしません。必ず継承して使います。

理由は
・ダブルバッファが有効でない
・ComboBox や CheckBox を変更したら値を反映したい
・描画抑止の機能がない
・複数セルへ貼り付けできない
などです。

Comments

[teretail]

やはりDataGridViewも継承しないと解決できないのですね・・・
ご提示いただいたソースで試したところ期待通りCellClickイベント、CellContentClickイベントが上がらないことを確認できました。
ありがとうございました！