groupby句に関して

Question

【やりたいこと】
各商品の色番号ごとの合計販売個数を出したい。

このような表をスプレッドシートにて「５個セットボール」「おもちゃ」という２つのシートから下記のクエリ文を用いて抽出して表を作成しました。

=QUERY({'５個セットボール'!D1:M;'おもちゃ'!D2:M},"select Col1,Col3,Col10 WHERE Col1 contains '5個' and Col1 contains 'ボール'")

表
A列　　　　　　　B列　　　　C列
商品名. 　　　　　個数,　　　色
5個セットボール　　1　　　　col.１３０
5個セットボール　　 2 　 　　COL.３８
5個/ボール　　 　　　1 　　　 col.１
5個セットボール 　　 1 　 　　 col.１１１
5個セットのボール　　1 　　　COL.２５
.
※B列の数字は半角ですが、C列の色番号の数字は全角です。

【できないこと、やりたいこと】
色ごとにまとめようと考え、B列をsumしてgroupby句で色ごとにまとめれば良いと考え
=QUERY(B2:C,"SELECT B,C,sum(B) group by C")
このように表記しましたが、エラーが出てしまいます。
「関数 QUERY のパラメータ 2 のクエリ文字列を解析できません: ADD_COL_TO_GROUP_BY_OR_AGG: B」

どのようにすれば、色ごとにまとめることができるのでしょうか。

Answer 1

GROUP BYを使った場合は、SELECT句に書けるものは、下記の3つに限定されます。
①定数
②集約関数　（SUM(〇〇)等）
③GROUP BY句のところで指定した列名

=QUERY(B2:C,"SELECT B,C,sum(B) group by C")　
という式の場合、
「C」は③に該当、
「sum(B)」は②に該当しますが
「B」は上記のいずれにも当てはまらないため、エラーになります。

したがって、Bを省略して

=QUERY(B2:C,"SELECT C,sum(B) group by C")

とするか
1列目にBに関係する何らかのデータ（たとえばCで集約した場合のBの最小値）を表示させたいならば

=QUERY(B2:C,"SELECT min(B),C,sum(B) group by C")

等とします。

Comments

[tavernity_nagai]

いつも丁寧な回答ありがとうございます！
基礎の理解が乏しくgroup byやorder byでいつも迷ってしまいますが
無事に解決しました。