terraformでAWS Elasticacheを作成したい

Question

実現したいこと

terraformでAWS Elasticacheを作成したい

前提

terraformでAWS Elasticacheを作成中以下のエラーメッセージが発生しました。

作成されるelasticacheのvpcがdefault vpcになってしまいます。

発生している問題・エラーメッセージ

エラーメッセージ

Error: creating ElastiCache Replication Group (redis-cluster): InvalidParameterCombination: Subnet group [redis] belongs to a different VPC [vpc-xxxxx(作成したsubnetのvpc id)] than [vpc-yyyyy(defaultのvpc id)]

該当のソースコード

terraform {
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = ">= 4.1.0"
    }
  }
}
resource "aws_vpc" "this" {
  cidr_block           = "10.0.0.0/16"
  enable_dns_hostnames = true
  enable_dns_support   = true

  tags = {
    Name = local.app_name
  }
}

resource "aws_subnet" "redis_private_1a" {
  vpc_id            = aws_vpc.this.id
  cidr_block        = "10.0.50.0/24"
  availability_zone = "ap-northeast-1a"
  tags = {
    Name = "redis-private-1a"
  }
}

resource "aws_subnet" "redis_private_1c" {
  vpc_id            = aws_vpc.this.id
  cidr_block        = "10.0.60.0/24"
  availability_zone = "ap-northeast-1c"
  tags = {
    Name = "redis-private-1c"
  }
}

resource "aws_subnet" "redis_private_1d" {
  vpc_id            = aws_vpc.this.id
  cidr_block        = "10.0.70.0/24"
  availability_zone = "ap-northeast-1d"
  tags = {
    Name = "redis-private-1d"
  }
}

resource "aws_security_group" "redis" {
  name = "${local.app_name}-redis"

  ingress {
    from_port   = 6379
    to_port     = 6379
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
}

resource "aws_elasticache_subnet_group" "redis" {
  name        = "redis"
  description = "Subnet group for Redis cluster"
  subnet_ids = [
    aws_subnet.redis_private_1a.id,
    aws_subnet.redis_private_1c.id,
    aws_subnet.redis_private_1d.id,
  ]

}

resource "aws_cloudwatch_log_group" "redis" {
  name              = "${local.app_name}-redis"
  retention_in_days = 1
}

resource "aws_elasticache_parameter_group" "redis" {
  name   = "redis-parameter-group"
  family = "redis6.x"

  parameter {
    name  = "cluster-enabled"
    value = "no"
  }
}

resource "aws_elasticache_replication_group" "redis" {
  replication_group_id       = "redis-cluster"
  description                = "Redis cluster for Websocket pub/sub"
  engine                     = "redis"
  engine_version             = "6.x"
  node_type                  = "cache.t3.small"
  parameter_group_name       = aws_elasticache_parameter_group.redis.name
  subnet_group_name          = aws_elasticache_subnet_group.redis.name
  num_cache_clusters         = 3
  port                       = 6379
  automatic_failover_enabled = true
  security_group_ids = [aws_security_group.redis.id]
  apply_immediately = false
}

試したこと

iam userには全権限付与しています。

補足情報（FW/ツールのバージョンなど）

Terraform v1.3.3
on darwin_arm64

• provider registry.terraform.io/hashicorp/aws v4.59.0

Your version of Terraform is out of date! The latest version
is 1.4.4. You can update by downloading from https://www.terraform.io/downloads.html

Comments

[yu_1985]

メッセージを見る限り、そちらで定義しているサブネットグループの名前とメッセージで指定しているとされているサブネットグループの名前が異なっているのですが、これは実際にTerraform applyをしているコードと一致していますか？

> Subnet group [redis-subnet-group] belongs to a different VPC

貼ったソースでは「redis」という名前で定義しているかと思います。

[sst]

Error: creating ElastiCache Replication Group (redis-cluster): InvalidParameterCombination: Subnet group [redis] belongs to a different VPC [vpc-xxxxx] than [vpc-yyyyy]

すみません。エラーメッセージの掲載ミスでした。

[yu_1985]

> Subnet group [redis] belongs to a different VPC [vpc-xxxxx] than [vpc-yyyyy]

では、Terraformで作ったのではない同名のサブネットグループが既に存在していたりしませんか？

[sst]

存在していません。redisは一つです。

[yu_1985]

tfstateの中身はどうなっていますか。
terraform state list
で確認したら、tfstateに想定していないものが残っていたりしないでしょうか

[sst]

resource "aws_security_group" "redis" {
name = "${local.app_name}-redis"
+ vpc_id = aws_vpc.this.id
ingress {
from_port = 6379
to_port = 6379
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}

egress {
from_port = 0
to_port = 0
protocol = "-1"
cidr_blocks = ["0.0.0.0/0"]
}
}

aws_security_groupにvpc_idを追加したら解決しました。
推測ですが、作成されるclusterのvpcをsecurity groupから参照しているみたいです。
ご協力ありがとうございました！

Answer 1

aws_security_groupにvpc_idを追加したら解決しました

resource "aws_security_group" "redis" {
  name   = "${local.app_name}-redis"

  + vpc_id = aws_vpc.this.id

  ingress {
    from_port   = 6379
    to_port     = 6379
    protocol    = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }

  egress {
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
}