事前に定義してある型に応じて、データの取得方法を変えたい

Question

前提

ExcelCreatorを利用して、該当のデータ型に応じてセル内のデータを取得しています。
(vb.net自体を最近始めたばかりなので方法を知らないだけかもしれません。)

該当のソースコード

Public Class [DataName]
    Public Property 数字 As Integer?
    Public Property 文字 As String
    Public Property 日付 As Date?
    Public Property 小数 As Decimal?
End Class

  Dim model = New ExcelLibModels.DataName
      model.数字 = XlsxCreator.Cell("H4").GetInteger
      model.文字 = XlsxCreator.Cell("J4").Str
      model.日付 = XlsxCreator.Cell("K4").GetDate
      model.小数 = XlsxCreator.Cell("E7").GetDecimal
  Return model

実現したいこと

• セル毎に該当の型を毎回処理しているのですが、処理部分を一つにまとめたい

(実際のデータは200項目程あるので見づらい)

  Dim model = New ExcelLibModels.DataName
      Dim GetExcelData = Function(Cells As String)
   　　　'ここで該当の型を判定して、データに合った方法で取りたい
      End Function
      model.数字 = GetExcelData("H4")
      model.文字 = GetExcelData("J4")
      model.日付 = GetExcelData("K4")
      model.小数 = GetExcelData("E7")
  Return model

試したこと

下記のように書いていたのですが、model.～の文字が長いものもあって逆に見づらくなるので避けたい。

  Dim model = New ExcelLibModels.DataName
      Dim GetExcelData = Function(DataType As Type, Cells As String)
   　　　'case  TypeName = で判定、処理
      End Function
      model.数字 = GetExcelData(model.数字.GetType(),"H4")
      model.文字 = GetExcelData(model.文字.GetType(),"J4")
      model.日付 = GetExcelData(model.日付.GetType(),"K4")
      model.小数 = GetExcelData(model.小数.GetType(),"E7")
  Return model

下記の方法だとmodel内に取得した情報が入らなかった。
(一部どうやってやったのかうろ覚えです、すみません)

  Dim model = New ExcelLibModels.DataName

    with model
      'DataTypeを型宣言せずどうやってとっていたのか不明です
       Dim inputExcelData = Sub(DataType, Cells As String)
　　　　 'if分岐で型を取得
   　　　  'DataType =  XlsxCreator.Cell(Cells).Str
       End Sub
       inputExcelData(model.数字,"H4")
       inputExcelData(model.文字,"J4")
       inputExcelData(model.日付,"K4")
       inputExcelData(model.小数,"E7")
    End with
      
  Return model

補足情報（FW/ツールのバージョンなど）

利用しているのは上記に書いてある4つの型のみです。
必要情報がない場合教えてください。

Comments

[cure_fontaine]

XlsxCreator.Cell("ｘｘｘ")　の行を２００行実行するよりも、A1~Z50などの様にセルをまとめて配列に格納した方が早いのではないでしょうか。

[reimei]

確かにそうですね。その考え方は思いつかなかったです。
まだ当方の技術不足で、うまく活用できる方法が明確に浮かびませんが
その方法も視野にいれてコーディングしてみます。

Answer 1

「まとめる」という意味を取り違えていたらごめんなさい、と前置きしておきます。

ExcelLibModels.DataName に対する各プロパティが、どのセル位置にあるか示す属性を作成します。

Public Class CellsAttribute
    Inherits Attribute
    Public Sub New(cells As String)
        Me.Cells = cells
    End Sub
    Public ReadOnly Property Cells As String
End Class

これを使ってプロパティを修飾します。

Public Class DataName
    <Cells("H4")> Public Property 数字 As Integer?
    <Cells("J4")> Public Property 文字 As String
    <Cells("K4")> Public Property 日付 As Date?
    <Cells("E7")> Public Property 小数 As Decimal?
End Class

リフレクションを使ってプロパティを列挙し、プロパティの型、CellsAttribute からセル位置を取得し、値をセットします。

Imports System.Reflection


Dim GetExcelData = Function(DataType As Type, Cells As String)
                       Select Case DataType
                           Case GetType(Integer?)
                               Return XlsxCreator.Cell(Cells).GetInteger
                           Case GetType(String)
                               Return XlsxCreator.Cell(Cells).Str
                           Case GetType(Date?)
                               Return XlsxCreator.Cell(Cells).GetDate
                           Case GetType(Decimal?)
                               Return XlsxCreator.Cell(Cells).GetDecimal
                           Case Else
                               Return Nothing
                       End Select
                   End Function

Dim model As New ExcelModels.DataName
For Each pi As PropertyInfo In model.GetType().GetProperties()
    Dim cellsAttr As CellsAttribute = TryCast(
                        pi.GetCustomAttributes(GetType(CellsAttribute), True).FirstOrDefault,
                        CellsAttribute)
    If cellsAttr IsNot Nothing Then
        Dim value As Object = GetExcelData(pi.PropertyType, cellsAttr.Cells)
        pi.SetValue(model, value)
    End If
Next

追記

単純に、オーバーロード関数を作るのもいいいかもしれません。

Sub inputExcelData(ByRef Item As Integer?, Cells As String)
    Item = XlsxCreator.Cell(Cells).GetInteger
End Sub
Sub inputExcelData(ByRef Item As String, Cells As String)
    Item = XlsxCreator.Cell(Cells).Str
End Sub
Sub inputExcelData(ByRef Item As Date?, Cells As String)
    Item = XlsxCreator.Cell(Cells).GetDate
End Sub
Sub inputExcelData(ByRef Item As Decimal?, Cells As String)
    Item = XlsxCreator.Cell(Cells).GetDecimal
End Sub

使い方

inputExcelData(model.数字, "H4")
inputExcelData(model.文字, "J4")
inputExcelData(model.日付, "K4")
inputExcelData(model.小数, "E7")

Comments

[reimei]

まさに望んでいたものでした！
確認したところ正常に動きかつ見やすくなり、助かりました。
ありがとうございます！