複数行の横並びデータを列を区切って縦並びに変更したい

Question

■やりたい事

Google スプレッドシートで
横並びのデータを列を区切って縦並びに変更したいです。
その際、各行の先頭列に元データから一意のセルを付加。
これらを関数・数式のみで他シートを介さずに実行したい。

上記の画像の「①並び替え前」を「②並び替え後」の通りに並び替えたいです。
※セル背景色は必要ないです

解法に近しい、URLリンクをご提示頂けるだけでもありがたいです。どうぞよろしくお願いします。

■追記：今出来ている事

クエリと直積(?)で解決を試みています。

=QUERY({B3:B12,E3:G12;B3:B12,H3:J12;B3:B12,K3:M12}," WHERE Col2<>'' order by Col1 asc")

欲を言うと配列結合「{B3... M12}」の列指定を「E～KO」などで済ませたいです。
※ArrayFormula関数/ADDRESS関数/column関数/int関数などを活用しスピらせたいのですが、全く回りません。。。

---

Answer 1

質問の①の表の構成で A列の通し番号が使えるなら

=LAMBDA(array,LAMBDA(x,ARRAYFORMULA(Query(BYROW({QUOTIENT(x,3)+1,MOD(x,3)+1},LAMBDA(r,vlookup(INDEX(r,,1),array,{2,{2,3,4}+INDEX(r,,2)*3},FALSE))),"where Col2 is not null")))(SEQUENCE(ROWS(array)*(COLUMNS(array)-4)/3,1,0)))(A3:M12)

↓横に長すぎるんで同じ式にインデント付けたのも

=LAMBDA(array,
  LAMBDA(x,
    ARRAYFORMULA(
      Query(
        BYROW({QUOTIENT(x,3)+1,MOD(x,3)+1},
          LAMBDA(r,
            vlookup(INDEX(r,,1),array,{2,{2,3,4}+INDEX(r,,2)*3},FALSE)
          )
        ),
      "where Col2 is not null")
    )
  )(SEQUENCE(ROWS(array)*(COLUMNS(array)-4)/3,1,0))
)(A3:M12)

Comments

[mobius]

ありがとうございます。完璧です。希望通りそのままが実現できています。
惚れ惚れする数式、感激です。今から解読するのが楽しみでなりません。
sawaさんの回答をベストアンサーとさせて頂きます。
本当にありがとうございました。

Answer 2

B3 から M12 のレンジで getValues() して取れる二次元配列を data とします。

const sheet = SpreadsheetApp.getActiveSheet();
const data = sheet.getRange(3, 2, 10, 12).getValues();

この data を加工して、並び替え後の表の内容となる二次元配列を data2 として得るには以下のようにします。

まず以下のような補助関数 chunk(ary, n) を作っておきます。

const chunk = (ary, n) => 
  ary.length <= n ? [ary] : [ary.slice(0, n), ...chunk(ary.slice(n), n)];

これを使って data から data2を得るには以下のようにします。

const data2 = data.flatMap(
   ([name, _url, _mail, ...values]) => 
        chunk(values, 3)
          .filter(ary => ary.some(v => v))
          .map(ary => [name, ...ary])
  );

console.log(data2);

data2 は以下のようになります。

Comments

[mobius]

ご回答いただきありがとうございます
ご教示頂いたGASで希望通りの二次元配列が生成されました。質問投稿からわずか30分で完璧なscript・・・本当に驚いています。しかしながら大変申し上げにくいのですが、私はこれらを『関数・数式のみ』で実現したく考えております。せっかくご教授頂いたのに申し訳ございません。

[退会済みユーザー]

あ〜。Google App Script が求められている質問ではなかったのですね。。。失礼しました。