MS ACCESSで SQLServer上のテーブルが既に公開されている（ODBC）が 接続定義を変更したい

Question

実現したいこと

添付の画像は　ACCESSで　SQLServer上のあるテーブルが　リンクテーブルとして　閲覧できる状況を表しています。

このリンクテーブルにマウスを充てると、ツールチップテキストが現れますが、この接続情報を今回かえたいです。
SQLServe上のアカウント管理が従来まで　非常にひどかったのですが、今回ODBCで接続・公開する範囲を狭めようと　別アカウントを手配することになりました。

発生している問題・分からないこと

ツールチップテキストの内容が　どこから表示されているかわからなくて　変更方法がわかりません

該当のソースコード

特になし

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

該当記事は見つけられませんでした。

補足

特になし

Answer 1

ODBCで接続・公開する範囲を狭めようと　別アカウントを手配することになりました。

このリンクテーブルにマウスを充てると、ツールチップテキストが現れますが、
この接続情報を今回かえたいです。

単にテーブルの再リンクを実行したいだけなら
リンクテーブルマネージャーを使用なさればよいでしょう。

何らかのタイミングや条件に応じてリンク先を動的に変更するプログラムを
VBAで作成したい、ということであれば cx20 さんが例示されたように
DAO.TableDef オブジェクトを使用なさればよいでしょう。

Answer 2

Access で SQL Server ヘリンクテーブルを貼る方法としていくつかありますが、簡単なのは 下記 VBA で行う方法かと思います。

■ Access でリンク テーブルのSQL Serverへの DSN レス接続を作成する方法
https://learn.microsoft.com/ja-jp/office/troubleshoot/access/create-dsn-less-connection-linkted-table

Sub Test()
    Dim stLocalTableName As String
    Dim stRemoteTableName As String
    Dim stServer As String
    Dim stDatabase As String
    Dim stUsername As String
    Dim stPassword As String
    
    stLocalTableName = "dbo_テーブル名"
    stRemoteTableName = "dbo.テーブル名"
    stServer = "サーバー名"
    stDatabase = "データベース名"
    stUsername = "ユーザー名"
    stPassword = "パスワード名"
    
    AttachDSNLessTable stLocalTableName, stRemoteTableName, stServer, stDatabase, stUsername, stPassword
End Sub

Function AttachDSNLessTable(stLocalTableName As String, stRemoteTableName As String, stServer As String, stDatabase As String, Optional stUsername As String, Optional stPassword As String)
    On Error GoTo AttachDSNLessTable_Err
    Dim td As TableDef
    Dim stConnect As String

    For Each td In CurrentDb.TableDefs
        If td.Name = stLocalTableName Then
            CurrentDb.TableDefs.Delete stLocalTableName
        End If
    Next
    
    If Len(stUsername) = 0 Then
        '//Use trusted authentication if stUsername is not supplied.
        stConnect = "ODBC;DRIVER=SQL Server;SERVER=" & stServer & ";DATABASE=" & stDatabase & ";Trusted_Connection=Yes"
    Else
        '//WARNING: This will save the username and the password with the linked table information.
        stConnect = "ODBC;DRIVER=SQL Server;SERVER=" & stServer & ";DATABASE=" & stDatabase & ";UID=" & stUsername & ";PWD=" & stPassword
    End If
    
    Set td = CurrentDb.CreateTableDef(stLocalTableName, dbAttachSavePWD, stRemoteTableName, stConnect)
    CurrentDb.TableDefs.Append td
    AttachDSNLessTable = True
    
    Exit Function
    
AttachDSNLessTable_Err:
    AttachDSNLessTable = False
    MsgBox "AttachDSNLessTable encountered an unexpected error: " & Err.Description

End Function