親formのコントロールを子formで行う方法

Question

VB.NET 初心者です。初投稿失礼します。
visual studio 2019 を使用しており、簡易的なwindowsフォームアプリケーションを作成しています。

やりたいこと

お店の商品をモバイルオーダーのように注文するようなプログラムを作っています。親formにて商品の写真を選び、画像をタッチ（picturebox）すると子formで作成したNumerickUpDown で個数を選択し、Buttonを押すと親formに作成したlistboxに　"商品名×〇(個数)"　と表示されると同時に子formを閉じるプログラムを作成したいです。自分なりに調べてみましたが、途中でつまってしまいました。どなたか教えていただけるとすごく助かります。

Public Class 子Form
    Private Shared 子forminstace As 子Form

    Public Shared Property 子forminstance() As 子Form
        Get
            Return 子forminstace
        End Get
        Set(ByVal value As 子Form)
            子forminstace = value
        End Set
    End Property

    Public Property NumerickUpDown() As String
        Get
            Return NumericUpDown1.Value
        End Get
        Set(value As String)
            NumericUpDown1.Value = value
        End Set
    End Property

    Private Sub 子Form_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        子Form.子forminstace = Me
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim num As Integer = NumericUpDown1.Value
        If num > 0 Then

        End If
    End Sub
End Class

Comments

[y_waiwai]

で、しつもんはなんでしょうか

[xeee]

言葉足らずで申し訳ないです。どのような書き方をすれば、listboxに出力できるかを教えていただきたいです。

Answer 1

いかようにも書けるので、まずは設計から始めてみましょう。
・親画面から子画面に何の情報を渡すのか
・子画面から親画面に何の情報を返すのか
・親画面の更新は子から行うのか、それとも子が返す情報を受け取って親画面が行うのか
これらを列挙し、何か矛盾がないか、足りない情報はないか検討してください。
たとえば、子画面が親画面を更新するなら、親画面のインスタンスを子画面が知ってなきゃいけないよねーとか、ListBox に表示するための商品名も渡さなきゃいけないねーとか。
きちんと設計できれば書かなければいけないコードが見えてくるはずです。

追記

反応がないのでサンプルを書いておきます。(^_^;)

・親画面からは何も渡しません。
・子画面からは NumericUpDown に入力された値を返します。
・ListBox の更新は親が行います。

' 親画面
Public Class ParentForm

    Private Sub ParentForm_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        PictureBox1.Tag = "商品001"    ' 商品名を Tag プロパティにセットする
        PictureBox1.Image = Image.FromFile("test.bmp")
    End Sub

    Private Sub PictureBox1_Click(sender As Object, e As EventArgs) Handles PictureBox1.Click
        Dim pbox As PictureBox = DirectCast(sender, PictureBox)
        Using child As New ChildForm()
            If child.ShowDialog() = DialogResult.OK Then
                ListBox1.Items.Add(String.Format("{0} x {1}", pbox.Tag, child.StockCount))
            End If
        End Using
    End Sub

End Class

' 子画面
Public Class ChildForm

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        _StockCount = NumericUpDown1.Value
        DialogResult = DialogResult.OK
    End Sub

    Private _StockCount As Decimal

    Public ReadOnly Property StockCount As Decimal
        Get
            Return _StockCount
        End Get
    End Property

End Class

Comments

[xeee]

返信遅れて申し訳ありません!　もう一度構造から考え直してみます。サンプルコードまでわざわざ書いて頂いて本当に助かります!頑張って完成させてみます。