DataGridViewのComboBox列の最終行の処理がうまくいかない

Question

実現したいこと

• DataGridViewのComboBox列を編集可能としたい

前提

DataGridViewにComboBox列を設け、入力済みの値から選択、もしくはユーザーが新しい項目を入力できるようにするため、dobon.netさんを参考にコードを組みました。
DataGridViewのコンボボックスにユーザーが文字列を入力できるようにする

また、Enter押下時に次のセルに移るようコードを組んでいます。

発生している問題・エラーメッセージ

該当ページのコメント欄にも書かれていますが、最終行のコンボボックスにて文字列入力→Enterを行うと入力内容が消えてしまい、コンボボックスには空文字列が追加されてしまいます。
（CellValidatingイベントにてFormattedValueが空となる）

該当のソースコード

Public Class Form1

    Private TEST_DATA As String() = {
        "1,ABC,あいうえお",
        "2,XYZ,かきくけこ",
        "3,ABC,さしすせそ"
    }

    Private Sub Form1_Load(sender As Object, e As EventArgs) _
        Handles Me.Load

        DataGridView1.AllowUserToAddRows = False

        'コンボボックス列の取得
        Dim cbc As DataGridViewComboBoxColumn = CType(DataGridView1.Columns(1), DataGridViewComboBoxColumn)

        'データの設定
        For Each str As String In TEST_DATA
            Dim elem As String() = str.Split(","c)

            If (Not cbc.Items.Contains(elem(1))) Then
                'コンボボックスの項目に追加する
                cbc.Items.Add(elem(1))
            End If

            '行の追加
            Dim index As Integer = DataGridView1.Rows.Add()

            For i = 0 To 2
                DataGridView1.Rows(index).Cells(i).Value = elem(i)
            Next
        Next

        '空行を追加
        DataGridView1.Rows.Add()

    End Sub

    '-----------------------------------------------------------------
    ' Enterにて次のセルに進めるようにするための処理
    '   https://dobon.net/vb/dotnet/datagridview/enterkeymoveright.html
    '-----------------------------------------------------------------
    Private Sub DataGridView1_KeyDown(sender As Object, e As KeyEventArgs) _
        Handles DataGridView1.KeyDown
        Dim dgv As DataGridView = CType(sender, DataGridView)

        If (e.KeyCode = Keys.Enter) Then

            If (dgv.CurrentCellAddress.X = dgv.ColumnCount - 1) AndAlso
               (dgv.CurrentCellAddress.Y = dgv.RowCount - 1) Then
                '最終行最終列の場合は、何もしない（最終行最終列で
                'Tabキーを送信すると、次のコントロールにフォーカスが移動）
                Return
            End If

            'Tabキーを送信する
            SendKeys.Send("{TAB}")

            'フォーカスが下に移動しないようにする
            e.Handled = True
        End If

    End Sub

    Private Sub DataGridView1_CellEndEdit(sender As Object, e As DataGridViewCellEventArgs) _
        Handles DataGridView1.CellEndEdit
        Dim dgv As DataGridView = CType(sender, DataGridView)

        '最終行最終列の場合は、何もしない
        If (e.ColumnIndex = dgv.ColumnCount - 1) AndAlso
           (e.RowIndex = dgv.RowCount - 1) Then
            Return
        End If

        '最終行以外では、フォーカスを上に移動
        '（最終行以外では、編集後、フォーカスが下に移動するため）
        If (e.RowIndex < dgv.RowCount - 1) Then
            SendKeys.Send("{UP}")
        End If

        'Tabキーを送信する
        SendKeys.Send("{TAB}")

    End Sub

    '-----------------------------------------------------------------
    ' コンボボックスにテキスト入力できるようにするための処理
    '   https://dobon.net/vb/dotnet/datagridview/comboboxdropdownstyle.html
    '-----------------------------------------------------------------
    Private Sub DataGridView1_EditingControlShowing(sender As Object, e As DataGridViewEditingControlShowingEventArgs) _
        Handles DataGridView1.EditingControlShowing
        Dim dgv As DataGridView = CType(sender, DataGridView)

        If (TypeOf e.Control Is DataGridViewComboBoxEditingControl) Then
            '該当する列か調べる
            If (dgv.CurrentCell.OwningColumn.Name = "Column2") Then
                '編集のために表示されているコントロールを取得
                Dim cb As DataGridViewComboBoxEditingControl = CType(e.Control, DataGridViewComboBoxEditingControl)
                cb.DropDownStyle = ComboBoxStyle.DropDown

                'イベントハンドラを削除
                RemoveHandler cb.KeyPress, AddressOf DataGridViewComboBox_KeyPress

                'KeyPressイベントハンドラを追加
                AddHandler cb.KeyPress, AddressOf DataGridViewComboBox_KeyPress
            End If
        End If

    End Sub

    Private Sub DataGridView1_CellValidating(sender As Object, e As DataGridViewCellValidatingEventArgs) _
        Handles DataGridView1.CellValidating
        Dim dgv As DataGridView = CType(sender, DataGridView)

        '該当する列か調べる
        If (dgv.Columns(e.ColumnIndex).Name = "Column2") AndAlso
           (TypeOf dgv.Columns(e.ColumnIndex) Is DataGridViewComboBoxColumn) Then
            Dim cbc As DataGridViewComboBoxColumn = CType(dgv.Columns(e.ColumnIndex), DataGridViewComboBoxColumn)

            'コンボボックスの項目に追加する
            If Not cbc.Items.Contains(e.FormattedValue) Then
                cbc.Items.Add(e.FormattedValue)
            End If

            'セルの値を設定しないと、元に戻ってしまう
            dgv(e.ColumnIndex, e.RowIndex).Value = e.FormattedValue
        End If

    End Sub

    Private Sub DataGridViewComboBox_KeyPress(ByVal sender As Object, ByVal e As KeyPressEventArgs)
        Dim cb As DataGridViewComboBoxEditingControl = CType(sender, DataGridViewComboBoxEditingControl)

        If (DataGridView1.CurrentCell.OwningColumn.Name = "Column2") AndAlso
           (TypeOf DataGridView1.CurrentCell.OwningColumn Is DataGridViewComboBoxColumn) Then
            cb.DroppedDown = False
        End If

    End Sub

End Class

試したこと

コメント欄を参考にKeyPressイベントにてDroppedDown = Falseを設定するようにしましたが、解決しませんでした。（デバッガにてイベントが上がってきていることは確認できました）

また、Enter入力時にTABキーを送信するロジックが悪さしているかもしれないと考え、該当イベント処理をコメントアウトしましたが、結果は変わりませんでした。

なお、EnterキーでなくTABキーにて編集を終了した場合はうまくいきます。

補足情報（FW/ツールのバージョンなど）

開発環境
Visual Studio 2015 Version 14.0.25431.01 Update 3
Microsoft .NET Framework Version 4.8.04084

よろしくお願いいたします。

Comments

[TN8001]

VBできないのと未確認なのでこちらに書きますが、

> また、Enter押下時に次のセルに移るようコードを組んでいます。

[DataGridViewでEnterキーを押すと隣のセルにフォーカスが移動されるようにする - .NET Tips (VB.NET,C#...)](https://dobon.net/vb/dotnet/datagridview/enterkeymoveright.html)

のこれですよね。
> DataGridViewのイベントを使用する方法

こっちの方法だとどうでしょう？
> ProcessDialogKeyとProcessDataGridViewKeyメソッドをオーバーライドする方法

[teretail]

返信遅くなってしまいすみません。
確認したところこの方法ならばEnter押下時に次のセルに移動し、
かつコンボボックスには入力された内容が残るようです。
Enterキーで隣のセルに移るという動作が前提となりますが、
作成しようとしているアプリケーションの要件は満たせそうなので大変助かりました。
ありがとうございます。

[TN8001]

そうですか。よかったです^^

お手数ですが閲覧者にもわかる程度にまとめていただいて、質問を「解決済」にしてください。

[ヘルプ｜質問をした後に自己解決してしまった](https://teratail.com/help#resolve-myself)

Answer 1

dobon.netさんにて公開されているProcessDialogKeyとProcessDataGridViewKeyメソッドをオーバーライドする方法を併用することにより、最終行でもEnter入力時にコンボボックスの入力内容が残るようになりました。

ただし、この方法はあくまでもEnterキーの入力をTabキーの入力に置き換えることで成り立っており、Enterキーによるセル移動でのCellValidatingイベントでFormattedValueが空となる問題の根本解決には至っておりません。

Public Class Form1

    Private TEST_DATA As String() = {
        "1,ABC,あいうえお",
        "2,XYZ,かきくけこ",
        "3,ABC,さしすせそ"
    }

    '-----------------------------------------------------------------
    ' Enterにて次のセルに進めるようにするための処理
    '   https://dobon.net/vb/dotnet/datagridview/enterkeymoveright.html
    '-----------------------------------------------------------------
    Public Class DataGridViewEx
        Inherits DataGridView

        <System.Security.Permissions.UIPermission(
        System.Security.Permissions.SecurityAction.Demand,
        Window:=System.Security.Permissions.UIPermissionWindow.AllWindows)>
        Protected Overrides Function ProcessDialogKey(ByVal keyData As Keys) As Boolean
            'Enterキーが押された時は、Tabキーが押されたようにする
            If (keyData And Keys.KeyCode) = Keys.Enter Then
                Return Me.ProcessTabKey(keyData)
            End If
            Return MyBase.ProcessDialogKey(keyData)
        End Function

        <System.Security.Permissions.SecurityPermission(
            System.Security.Permissions.SecurityAction.Demand,
            Flags:=System.Security.Permissions.SecurityPermissionFlag.UnmanagedCode)>
        Protected Overrides Function ProcessDataGridViewKey(ByVal e As KeyEventArgs) As Boolean
            'Enterキーが押された時は、Tabキーが押されたようにする
            If e.KeyCode = Keys.Enter Then
                Return Me.ProcessTabKey(e.KeyCode)
            End If
            Return MyBase.ProcessDataGridViewKey(e)
        End Function

    End Class

    Private Sub Form1_Load(sender As Object, e As EventArgs) _
        Handles Me.Load

        DataGridView1.AllowUserToAddRows = False

        'コンボボックス列の取得
        Dim cbc As DataGridViewComboBoxColumn = CType(DataGridView1.Columns(1), DataGridViewComboBoxColumn)

        'データの設定
        For Each str As String In TEST_DATA
            Dim elem As String() = str.Split(","c)

            If (Not cbc.Items.Contains(elem(1))) Then
                'コンボボックスの項目に追加する
                cbc.Items.Add(elem(1))
            End If

            '行の追加
            Dim index As Integer = DataGridView1.Rows.Add()

            For i = 0 To 2
                DataGridView1.Rows(index).Cells(i).Value = elem(i)
            Next
        Next

        '空行を追加
        DataGridView1.Rows.Add()

    End Sub

    '-----------------------------------------------------------------
    ' コンボボックスにテキスト入力できるようにするための処理
    '   https://dobon.net/vb/dotnet/datagridview/comboboxdropdownstyle.html
    '-----------------------------------------------------------------
    Private Sub DataGridView1_EditingControlShowing(sender As Object, e As DataGridViewEditingControlShowingEventArgs) _
        Handles DataGridView1.EditingControlShowing
        Dim dgv As DataGridView = CType(sender, DataGridView)

        If (TypeOf e.Control Is DataGridViewComboBoxEditingControl) Then
            '該当する列か調べる
            If (dgv.CurrentCell.OwningColumn.Name = "Column2") Then
                '編集のために表示されているコントロールを取得
                Dim cb As DataGridViewComboBoxEditingControl = CType(e.Control, DataGridViewComboBoxEditingControl)
                cb.DropDownStyle = ComboBoxStyle.DropDown
            End If
        End If

    End Sub

    Private Sub DataGridView1_CellValidating(sender As Object, e As DataGridViewCellValidatingEventArgs) _
        Handles DataGridView1.CellValidating
        Dim dgv As DataGridView = CType(sender, DataGridView)

        '該当する列か調べる
        If (dgv.Columns(e.ColumnIndex).Name = "Column2") AndAlso
           (TypeOf dgv.Columns(e.ColumnIndex) Is DataGridViewComboBoxColumn) Then
            Dim cbc As DataGridViewComboBoxColumn = CType(dgv.Columns(e.ColumnIndex), DataGridViewComboBoxColumn)

            'コンボボックスの項目に追加する
            If Not cbc.Items.Contains(e.FormattedValue) Then
                cbc.Items.Add(e.FormattedValue)
            End If

            'セルの値を設定しないと、元に戻ってしまう
            dgv(e.ColumnIndex, e.RowIndex).Value = e.FormattedValue
        End If

    End Sub

End Class

Answer 2

この回答はGPT-4による自動生成回答です

oxEditingControl)

    'Enterキーが押された時は、編集を終了する
    If (e.KeyChar = Chr(Keys.Enter)) Then
        cb.EditingControlDataGridView.EndEdit()
        e.Handled = True
    End If
End Sub

End Class

### 試したこと

最終行のコンボボックスで文字列入力→Enterを行った際に、CellValidatingイベントでFormattedValueが空になることが原因と思われます。しかし、具体的な解決策が分かりません。

### 補足情報

- Visual Studio 2019
- .NET Framework 4.7.2
- Windows Formsアプリケーション

どのように修正すれば、最終行のコンボボックスで文字列入力→Enterを行っても入力内容が消えず、正常に動作するでしょうか？

Comments

[teretail]

質問に質問で返されても・・・