【Mac M1環境】applescriptを使って、MS outlookから連続自動メールを送信するコードの書き方。

Question

【質問】
Applescriptsを使って、Mac M1のOutlookを操作して、数百通のメール送信を自動化する方法に関して、教えて下さい。

尚、上の質問は、下記質問の後継質問となります。
７割方解決し掛かっているのですが、質問の内容が変わってきたので、下記質問を閉めた上で、新たな質問とさせて頂きます。
【Mac M1環境】Pythonで開発中ですが、win32comに相当するモジュールはありますか？
https://teratail.com/questions/nnpga3zbo9zqdq

＜やりたい事＞
下記の様なメールリストが、あります。（実際にには数百の宛先に送付する必要があります。）

上のメールリストに対して、applescriptを使って、下記の様なOutlookメールを個別に自動送信して、楽をしたいと思っております。
（尚、「手動のBCC送信ではダメなのか？」と周りからは言われたのですが、BCCメールは、経験上、誰も読まないのを知っているので、個別メールにしたいと思っております。）

山田様、
こんにちは！これはテストです。

＜現状＞　メールの自動送信までは出来ております。
ただ、客先毎に、メール本文を微妙に変える事ができずに困っております。（「山田様」と冒頭に書きたいだけです。それ以外の部分は同じです。）

下記のテキストを用意しました。
＜name1.txt＞

山田
高橋
鈴木
塩見
山崎
村上

＜address1.txt＞

[e-mail]
[e-mail]
[e-mail]
[e-mail]
[e-mail]
[e-mail]

＜現在のコード＞

tell application "Microsoft Outlook"
set srcFile to ("/Users/xxxx_yyy/Desktop/code/address1.txt") as text
set lns to paragraphs of (read srcFile as «class utf8»)
repeat with ln in lns
set the clipboard to ln
set theMessage to make new outgoing message with properties {subject:"こんにちは！これはテストです。", plain text content:"Hello"}
make new recipient with properties {email address:{address:ln}} at end of to recipients of theMessage
send theMessage
end repeat
end tell

上のコードを動かすと、下記の個別メールが、address1.txt1に記載の受信者に、個別にかつ正常に飛ぶ事を確認しました。
＜これは出来ている。＞

こんにちは！これはテストです。

ただ、上に書いた様に、それぞれのメールに、{宛先様}を記載したいのです。
つまり、繰り返しになりますが、下記の様にして送信したいと考えております。

＜この様に送信したい。＞

山田様、
こんにちは！これはテストです。

repeat 文を使って色々とやってみたのですが、どうも上手く行きません。
教えて頂きたく。

Answer 1

解決しました。
下記が最終コードです。

set org to AppleScript's text item delimiters -- オリジナルの区切り文字を保存
set AppleScript's text item delimiters to "," -- 区切り文字を","に変更

set srcFile to ("/Users/xxxxx_yyy/Desktop/code/product2022/recipient1.csv") as text
set lns to paragraphs of (read srcFile as «class utf8»)
set theAttachment to alias "Users:xxxxx_yyy:Desktop:code:product2022:test.pdf" -- the attachment path
set theText to loadText("/Users/xxxxx_yyy/Desktop/code/product2022/promail2.txt")
repeat with ln in lns
	
	set theList to every text item of ln -- 区切り文字で分解してリストを作成
	set theHonbun to (item 1 of theList) -- リストから宛先を取り出して本文を作成
	set theAddress to item 2 of theList -- リストからアドレスを取り出し
	
	display dialog theHonbun -- 確認のため本文を表示
	display dialog theAddress -- 確認のためアドレスを表示
	
	tell application "Microsoft Outlook"
		
		set theMessage to make new outgoing message with properties {subject:theHonbun & "様、
先日はありがとうございました。これはテストです。", plain text content:theHonbun & "様、これからは本文です。本日は、こんにちは！テストです。先日はありがとうございました。これはテストです。"}

make new recipient with properties {email address:{address:theAddress}} at end of to recipients of theMessage
make new attachment at the end of theMessage with properties {file:theAttachment}

send theMessage
		
	end tell
	
end repeat

set AppleScript's text item delimiters to org -- オリジナルの区切り文字に戻す

Answer 2

手元にOutlookがないので直接の回答にはならないのですが、次のような形にするのはどうでしょうか。

まず、元のExcelで、A列が宛先、B列がメールアドレスのシンプルなシートを作り、それをCSVでrecipient.csvという名前で保存します。
中身は次のような形になります。

山田,[e-mail]
高橋,[e-mail]
鈴木,[e-mail]

これを1行ずつ読み込み、名前とメールアドレスに分解します。この形なら1つのrepeat文で両方が得られます。
以下、この形で本文とメールアドレスを取り出す例です。

set org to AppleScript's text item delimiters -- オリジナルの区切り文字を保存
set AppleScript's text item delimiters to "," -- 区切り文字を","に変更

set srcFile to ("/Users/xxxx_yyy/Desktop/code/recipient.csv") as text
set lns to paragraphs of (read srcFile as «class utf8»)
repeat with ln in lns
	
	set theList to every text item of ln -- 区切り文字で分解してリストを作成
	set theHonbun to (item 1 of theList) & "様
こんにちは！これはテストです。" -- リストから宛先を取り出して本文を作成
	set theAddress to item 2 of theList -- リストからアドレスを取り出し

	display dialog theHonbun -- 確認のため本文を表示
	display dialog theAddress -- 確認のためアドレスを表示
	
end repeat

set AppleScript's text item delimiters to org -- オリジナルの区切り文字に戻す

Comments

[yujin1202]

週末にご回答を頂き、本当にありがとうございました。
日曜日の午後１時にご回答を確認し、別の部分で詰まったりしたので、時間が掛かりましたが、日曜日の午後９時過ぎに、正常に動作するのを確認できました。
お陰様で、週明けの月曜日朝一に、数百通のメール送信が完了できる事になりました。
感謝のお言葉もありません。ありがとうございました。

[segavvy]

いえいえ、お役にたてたようで良かったです！