[Unity] Shader Graphで光の当たる部分を表示して影の部分が透明になるオブジェクトを作成したい

Shader Graphでライト（懐中電灯など）を当てると、光の当たる部分だけ浮かび上がるオブジェクトを作成したいと思っています。

Blenderでは下図のように再現できるのですが、これをUnityでも再現したいと思っています。

構想としては、光が強く当たる部分を1として影を0にしてAlphaに入れればいいと思っているのですが、光量の取得の仕方が分からない状態です。

CustomFunctionでメインライトを取得する方法が紹介されていたのですが、これだとDirectionLightの光にしか反応せず、スポットライトのような光に反応しなくて困っています。

#ifdef SHADERGRAPH_PREVIEW
    Direction = half3(0.5, 0.5, 0);
    Color = 1;

#else
    Light light = GetMainLight();
    Direction = light.direction;
    Color = light.color;
#endif

Shader Graphで光の当たる部分だけ浮かび上がり、影の部分は透明なオブジェクトを作成したいと思っています。
よろしくお願いいたします。

行動規範の内容に同意します

回答1件

ベストアンサー

メインライトだけでなく追加ライトも考慮する必要があるでしょうね。
下記のように改変してみましたがいかがでしょうか。ちょっと仕様を変更し、ワールド座標とワールド法線を受け取って照明強度を返すような作りに変更しました。

HLSL
1#ifdef SHADERGRAPH_PREVIEW
2    Attenuation = 1.0;
3#else
4    Light light = GetMainLight(TransformWorldToShadowCoord(WorldPosition));
5    float lightIntensity = max(max(light.color.r, light.color.g), light.color.b);
6    Attenuation = saturate(dot(light.direction, WorldNormal)) * lightIntensity * light.shadowAttenuation;
7    int lightCount = GetAdditionalLightsCount();
8    for (int i = 0; i < lightCount; i++)
9    {
10        light = GetAdditionalLight(i, WorldPosition, unity_ProbesOcclusion);
11        lightIntensity = max(max(light.color.r, light.color.g), light.color.b);
12        Attenuation += lightIntensity * light.distanceAttenuation * light.shadowAttenuation * saturate(dot(light.direction, WorldNormal));
13    }
14    Attenuation = saturate(Attenuation);
15#endif

Custom Functionノードはに入力としてWorldPositionとWorldNormalを、出力としてAttenuationを用意しました。
そしてWorldPositionとWorldNormalにそれぞれワールド座標・ワールド法線を接続し、出力されたAttenuationはAlphaに接続しています。