関数でRotateを反応させたい

Question

以下のフクロウの関数を用いてこれらを回転させたいのですが、Rotateが反応しません。
どこに入れるのが適切でしょうか。ご教示頂きたいです！
よろしくお願いします！

void setup() {
 size(400,400);
}

void draw() {
 background(176, 204, 226);
 for (int x =35; x < width + 70; x += 70) {
   int gray = int (random(0,102));
   owl(x, 110, gray);
   owl(x, 210,gray);
   owl(x,310,gray);
   owl(x,410,gray);
 }
}

void owl(int x, int y, int g) {
 pushMatrix();
 translate(x, y);
 stroke(138-g, 138-g, 125-g);
 strokeWeight(70);
 line(0, -35, 0, -65); // Body
 noStroke();
 fill(255);
 ellipse(-17.5, -65, 35, 35); // Left eye dome
 ellipse(17.5, -65, 35, 35);  // Right eye dome
 arc(0, -65, 70, 70, 0, PI);  // Chin
 fill(51, 51, 30);
 ellipse(-14, -65, 8, 8); // Left eye
 ellipse(14, -65, 8, 8);  // Right eye
 quad(0, -58, 4, -51, 0, -44, -4, -51); // Beak
 float angle = 0;
 rotate(angle);
 angle += 0.1;
 popMatrix();
}

Comments

[fiveHundred]

言語や使用ライブラリなどが不明なため回答不可能です。

[Susan.S]

processing を用いたコードです。

[meg_]

> processing を用いたコードです。
質問タグを差し替えてください。

Answer 1

下記でどうでしょうか？

float angle = 0;

void setup() {
 size(400,400);
}

void draw() {
 background(176, 204, 226);
 for (int x =35; x < width + 70; x += 70) {
   int gray = int (random(0,102));
   owl(x, 110, gray);
   owl(x, 210,gray);
   owl(x,310,gray);
   owl(x,410,gray);
 }
}

void owl(int x, int y, int g) {
 pushMatrix();
 translate(x, y);
 rotate(angle);
 stroke(138-g, 138-g, 125-g);
 strokeWeight(70);
 line(0, -35, 0, -65); // Body
 noStroke();
 fill(255);
 ellipse(-17.5, -65, 35, 35); // Left eye dome
 ellipse(17.5, -65, 35, 35);  // Right eye dome
 arc(0, -65, 70, 70, 0, PI);  // Chin
 fill(51, 51, 30);
 ellipse(-14, -65, 8, 8); // Left eye
 ellipse(14, -65, 8, 8);  // Right eye
 quad(0, -58, 4, -51, 0, -44, -4, -51); // Beak
 angle += 0.1;
 popMatrix();
}

• angleを先頭で初期化しました。
• rotateの場所を変更しました。

Comments

[Susan.S]

思い通りに回転しました。
ありがとうございます！

Answer 2

Processing初見です。

質問の元ネタは
http://haship.github.io/education/pw1/2018/09-20180607.pdf
ですね。元ネタがあるなら書いておくと解答を得やすいかもしれません。

---

問題はRotate関数が思うように動作しないということですが、

 float angle = 0;
 rotate(angle);
 angle += 0.1;

コードを見るにrotate(0)つまり回転しないように書かれているのが原因ではないでしょうか。
angle+=0.1についても毎回0に初期化しているので意味が無さそうです。

解決するにはangleの宣言を関数owlの外でグローバル変数として行うのはいかがでしょうか。

Comments

[Susan.S]

rotateの場所がよくなかったようです。
ありがとうございます！