回答編集履歴

Unlit/Worldの場合の対策を追記

2019/12/07 04:18

投稿

Bongo

スコア10811

test CHANGED Viewed

@@ -181,3 +181,167 @@
 ![図2](a5e452a0849a2c4e81cd2570791d3bd8.gif)
+**追記**
+`Unlit/World`の場合は何を手がかりにサンプリング座標の変化率を算出するべきかですが、シェーダーコード以外のスクリプトが「[Unity2D テクスチャブレンド](https://teratail.com/questions/184671)」のものとほとんど変わらないと仮定しますと、好都合なことにシェーダーコード内の`modelPos`が利用できそうです。
+これはメッシュが持っている頂点座標ですが、メッシュは縦横1.0の正方形が並んだ形に作られていて、この正方形内ぴったりにタイルの画像を貼り付ける形になっています。ですので`modelPos`の変化率をもとにサンプリング位置の変化率を算出できるはずです。
+ですが`Unlit/World`のケースだともっと影響の大きい要因として、元のテクスチャがそれぞれの地形を並べて一枚にしている都合上隣のタイルの色が漏れて格子模様（元のテクスチャは地形を横に並べているため色漏れは横方向にだけ発生するので、「縦縞模様」と言った方が適切かもしれません）が生じてしまう現象があるかと思います。
+ですので[Unity2D テクスチャが潰れる](https://teratail.com/questions/198656)のシェーダーコードと同様に、タイルの外周部分をサンプリング座標の飛び幅分だけそぎ落とす処置も組み合わせてみました。変更部分は`frag`の後半だけです。
+```ShaderLab
+			fixed4 frag(v2f i) : SV_Target
+			{
+				// まずは前回同様weightを計算する
+				float f = dot(float2(_EdgeDist, 1.0 - _EdgeDist), float2(fractal(i.modelPos * _EdgeDistFreq), 0.5));
+				float upper = 1.0 - 2.0 * (1.0 - i.weight) * (1.0 - f);
+				float lower = 2.0 * i.weight * f;
+				float weight = lerp(lower, upper, step(0.5, i.weight));
+				// weightを比較してどの範囲にいるか判定し、それを越えない最大のインデックスを調べる
+				uint index = 0;
+				[unroll(TYPE_COUNT_MAX)]
+				for (int k = 0; k < _TypeCount; k++)
+				{
+					if (_TypeLevels[k] < weight)
+					{
+						index = k + 1;
+						continue;
+					}
+					break;
+				}
+				index = min(index, _TypeCount - 1);
+				// さらに、その一つ下・一つ上のインデックスを求めておく
+				uint prevIndex = index > 0 ? index - 1 : 0;
+				uint nextIndex = min(index + 1, _TypeCount - 1);
+				// 範囲の下限・上限の高さを取得し、lowerLevelを0、upperLevelを1としたときのweightの位置を調べる
+				float lowerLevel = (index == prevIndex) ? 0.0 : _TypeLevels[prevIndex];
+				float upperLevel = (index == nextIndex) ? 1.0 : _TypeLevels[index];
+				float weightInRange = (lowerLevel == upperLevel) ? 0.0 : (weight - lowerLevel) / (upperLevel - lowerLevel);
+				// weightInRangeが0.5以上かどうかでnextIndex、prevIndexのいずれかを選択する
+				uint edgeIndex = weightInRange >= 0.5 ? nextIndex : prevIndex;
+				// weightInRangeが0.5の時0、そこより範囲境界に近いほど1になるような値を作る
+				// このとき_EdgeSharpness乗して、カーブを適宜鋭くする
+				float edgeFactor = saturate(pow(abs(weightInRange * 2.0 - 1.0), _EdgeSharpness));
+				// 範囲中心および範囲境界に対応するUVを取得し、そこからそれぞれ色を取得する
+				float4 edgeVector = _TypeUvs[edgeIndex / 2];
+				float4 centerVector = _TypeUvs[index / 2];
+				float2 edgeUv = lerp(edgeVector.xy, edgeVector.zw, edgeIndex % 2);
+				float2 centerUv = lerp(centerVector.xy, centerVector.zw, index % 2);
+				// 色取得の前に、modelPos変化率とUV変化率を算出する
+				float2 dPosdx = ddx(i.modelPos);
+				float2 dPosdy = ddy(i.modelPos);
+				float2 dUvdx = dPosdx * _TileSize;
+				float2 dUvdy = dPosdy * _TileSize;
+				// 色漏れ防止のため、modelPos変化率の分だけtileUvの外周を
+				// そぎ落としてから_TileSizeをかけてuvOffsetとする
+				float2 cornerOffset = abs(dPosdx) + abs(dPosdy);
+				float2 uvOffset = lerp(cornerOffset, 1.0 - cornerOffset, i.tileUv) * _TileSize;
+				// tex2Dの代わりにtex2Dgradを使って色を取得する
+				// このとき、第3・第4引数としてUV変化率を使用する
+				fixed4 edgeColor = tex2Dgrad(_MainTex, edgeUv + uvOffset, dUvdx, dUvdy);
+				fixed4 centerColor = tex2Dgrad(_MainTex, centerUv + uvOffset, dUvdx, dUvdy);
+				// 範囲中心でcenterColorが100%、境界部分でcenterColorとedgeColorが
+				// 50%混合になるように2つの色を混ぜ合わせる
+				return lerp(centerColor, edgeColor, edgeFactor * 0.5);
+			}
+```
+テクスチャの設定はGenerate Mip MapsをオンにしてFilter ModeをTrilinearとした状態で、対策なしだと下図のように縦スジが目立ってしまいますが...
+![図3](b7526cd9714ed4461f7a7400ceff6bc3.gif)
+対策ありだと下図のようにマシになりました。
+![図4](2d74baa4d356bce533766d36c4508e26.gif)