Crystal Reports の接続先DBを変更したい

Question

前提

VB.NET で Crystal Reports を使用したシステムの改修をすることになりました。
Crystal Reports は未経験で、システム開発当時の担当者もいない状況です。

Crystal Reports は客先のオンプレミスの SQL Server に接続する設定になっていますが、私の開発環境からは接続できません。

検索しても新規にレポートを作る手順の説明ばかりで、既存のレポートの接続先を変更する情報が見つかりません。

実現したいこと

レポートデザイナを開き、フィールドエクスプローラのデータベースフィールドからデータベースエキスパートを開いた際、選択したテーブルにオンプレミスのサーバー名とインスタンス名が表示されていますが、さしあたりこれを開発環境の (localdb)\MSSQLLocalDB にしたいです。

最終的にはVB側で接続先を指定したいです。

VB側の改修は多少複雑になっても構いませんが、最低限レポートのデザインは維持したいです。

試したこと

「選択したテーブル」からオンプレミスの設定を削除する。
→オンプレミスのデータを参照するコントロールがすべて削除された。

「選択したテーブル」に (localdb)\MSSQLLocalDB を追加してコントロールの参照先の変更を試みる。
→該当するプロパティが見つからない。

補足情報（FW/ツールのバージョンなど）

Visual Studio 2017 Community
SAP Crystal Reports for Visual Studio (SP32) installation package for Microsoft Visual Studio IDE (VS 2019 and below)

Comments

[KOZ6.0]

「Crystal Reports データソース変更」で検索したら、参考になりそうな記事がいくらでも出てくるんですが・・・

[gosaro]

できました。ありがとうございます。
データソースというキーワードが思いつきませんでした…

Answer 1

レポートの接続先をVBで変更するためのコードを記載しておきます。
大昔に作ったものなので、今も同じように動くかどうかわかりませんが、大筋はかわっていないと思います。

Imports CrystalDecisions.Shared
Imports CrystalDecisions.CrystalReports.Engine

Module Module1

    Sub Main()
        Using report As New ReportDocument()
            report.Load("レポート名.rpt")
            SetLogonInfo(report, "サーバー名", "データベース名", "ユーザ名", "パスワード")
            report.ReadRecords()
            If report.HasRecords Then
                report.PrintToPrinter(1, False, 0, 0)
            End If
        End Using
    End Sub

    Private Sub SetLogonInfo(report As ReportDocument,
                             server As String, database As String,
                             user As String, password As String)
        If Not report.IsSubreport Then
            For Each subReport As ReportDocument In report.Subreports
                SetLogonInfo(subReport, server, database, user, password)
            Next
        End If
        For Each table As Table In report.Database.Tables
            Dim logonInfo As TableLogOnInfo = table.LogOnInfo
            With logonInfo.ConnectionInfo
                .ServerName = server
                .DatabaseName = database
                .UserID = user
                .Password = password
            End With
            Dim tableName As String = logonInfo.TableName
            Dim pos As Integer = tableName.IndexOf(".")
            If pos >= 0 Then
                tableName = user & "." & tableName.Substring(pos + 1)
                logonInfo.TableName = tableName
            End If
            table.ApplyLogOnInfo(logonInfo)
            table.Location = tableName
        Next
    End Sub

End Module