gnuplotで複数のヒストグラムに関数をフィッティングさせ、それらを同時に表示したいです。

Question

gnuplotで作成した複数のヒストグラムに関数をフィッティングし、その結果を同時に表示させたいです。
関数は f(x) = aexp(-(x-b)**2/(2c**2)) です。
イメージはこのようなものになります。
よろしくお願い致します。

Comments

[y_waiwai]

質問文は編集できます
無駄に質問建てないで、追記修正しよう

Answer 1

# data
$data1 <<EOD
-2.2
-1.3
-1.25
-1.2
-1.1
-0.9
-0.85
-0.8
-0.7
-0.6
-0.5
-0.4
-0.35
-0.3
-0.25
-0.2
-0.1
0.1
0.2
0.25
0.3
0.35
0.4
0.45
0.5
0.6
0.65
0.7
0.8
0.85
0.9
1.1
1.2
1.3
1.4
2.2
EOD

$data2 <<EOD
2.2
3.1
3.2
3.25
3.3
3.35
3.4
3.5
3.6
3.7
3.8
3.85
3.9
4.1
4.2
4.25
4.3
4.35
4.4
4.5
4.6
4.7
4.8
4.85
4.9
5.1
5.2
5.3
5.4
6.2
EOD

# setting
set xrange [-6:8]
set yrange [0:20]
set xtics 1
set boxwidth 1

# save histogram data to a temporary file
temp_data1 = 'hist_temp1.dat'
set table temp_data1
plot $data1 u (floor($1)+0.5):(1) smooth frequency with boxes
unset table

temp_data2 = 'hist_temp2.dat'
set table temp_data2
plot $data2 u (floor($1)+0.5):(1) smooth frequency with boxes
unset table

# fitting
f(x,a,b,c) = a*exp(-(x-b)**2/(2*c**2))
fit f(x,a1,b1,c1) temp_data1 u 1:2 via a1,b1,c1
fit f(x,a2,b2,c2) temp_data2 u 1:2 via a2,b2,c2

# plot
plot $data1 u (floor($1)+0.5):(1) smooth frequency with boxes, f(x,a1,b1,c1) w l, \
     $data2 u (floor($1)+0.5):(1) smooth frequency with boxes, f(x,a2,b2,c2) w l