テキストファイルを読み込み、配列に格納したい。

Question

実現したいこと

ここに実現したいことを箇条書きで書いてください。

• テキストを読み込み、配列に格納したい

前提

別のプログラムで生成されていた配列をテキストファイルに保存したものがあるのですが、それを改めて別のプログラムで読み込み、配列にしようとしていました。

テキストファイルは以下のように配列の行ごとに[ ]で囲まれて保存されています。実際には50×80の配列です。
[1.0, 1.0, 0.0, 1.0]
[2.0, 3.0, 1.0, 1.0]
[1.0, 3.0, 1.0, 0.0]

発生している問題・エラーメッセージ

以下のソースコードで得られたAを別の50×80の場所に代入しようとしていたのが、51×1になっているためダメだと言われました。おそらく各行を1マス?として詰めて全ての行を1次元の配列にしてしまっているのだと思います。本来は、改行記号ごとに行を分けて、カンマごとに要素を分けたかったです。

ERROR: LoadError: DimensionMismatch: tried to assign 51×1 array to 50×80 destination

該当のソースコード

A = open("test.txt") do file
        content = read(file,String)
        cleaned_content = replace(content, r"[ \[\]]" => "")
        lines = split(cleaned_content, "\n")
        lines_data = [[parse(Float64,x) for x in split(line, ",") if x ≠ ""] for line in lines]
        lines_data
    end

試したこと

それぞれの行の中身を分けようとparse()を使ったりしたが、ベクトルには使用できないという意味だと思われるエラーが起きた。

Answer 1

今回の場合は Matrix の方がよい様に思います。

A = mapreduce(vcat, readlines("test.txt")) do line
    (parse.(Float64, split(line[2:end-1], ",")))'
end
show(stdout, "text/plain", A)

# 3×4 Matrix{Float64}:
#  1.0  1.0  0.0  1.0
#  2.0  3.0  1.0  1.0
#  1.0  3.0  1.0  0.0

Comments

[sobagiku]

すいません、Julia初心者で文法がわからないのですが,
"do line ... end"の "line"はどのような意味で書いてあるのでしょうか。
通常の "do ... end"とは違うのでしょうか。
それともdoとlineは分けて読むものですか？

[melian]

mapreduce も含めて読みます。

mapreduce ... do line .. end

test.txt の各行(readlines)が line に割り当てられて do .. end の中身(parse.(...))が実行されます。(map処理) 最終的に vcat で Matrix に変換されることになります。(reduce処理)

[sobagiku]

理解できました！
詳しく教えていただきありがとうございました。

Answer 2

蛇足ですが，]改行[を; ， ,を に変えてから
禁断のMeta.parseとevalのコンボを使うという剛腕な方法もありそうです。

A = replace(read("test.txt", String),
            "," => " ", r"\][^\[]+\[" => "; ") |> Meta.parse |> eval

Meta.parseは文字列がJulia言語の構文に合致しているかどうかを解析し，
エラーが出なければ，その結果をevalに通すとJuliaの実行結果として得られます。

例示したソースではreplaceを使って文字列全体をMatrixの記述に合わせてから，Juliaのプログラムの実行結果としてMatrixの結果を得ています。

メタプログラミングといって，プログラムでプログラム自体を書き換えるような
目的で使われる手法で，通常あまり利用してはいけないと言われている方法です。

a |> bの記述方法は b(a)の別の書き方です。

Julia言語は色々な書き方ができますね。

Answer 3

改行で分割しましょう。　　　　　　　　　　　　　　　　　　　　　1