Terraformで生成したEC2インスタンスにアクセスできない。

Question

Terraformで生成したEC2インスタンスにアクセスできない。

簡単なTerraform設定ファイルを作成して、EC2インスタンスを生成し、設定自体も正しくできているはずですが、アクセスできません。
ブラウザを介して生成した場合にはアクセスできるため、その差分を確認しましたが、特におかしな点はありませんでした。

以下はサンプルコードです。
簡素化してありますが、必要な設定はしています。

provider "aws" {
  region = "ap-northeast-1"
}

resource "aws_vpc" "example" {
  cidr_block = "10.0.0.0/16"
}

resource "aws_subnet" "example" {
  vpc_id = aws_vpc.example.id
  cidr_block = "10.0.1.0/24"
}

resource "aws_security_group" "example" {
  name = "example"
  vpc_id = aws_vpc.example.id
  ingress {
    from_port = 22
    to_port = 22
    protocol = "tcp"
    cidr_blocks = ["0.0.0.0/0"]
  }
  egress {
    from_port        = 0
    to_port          = 0
    protocol         = "-1"
    cidr_blocks      = ["0.0.0.0/0"]
  }
}

resource "aws_key_pair" "example" {
  key_name   = "example"
  public_key = file("~/.ssh/id_rsa.pub")
}

resource "aws_eip" "example" {
  vpc = true
}

resource "aws_instance" "example" {
  ami = "ami-be4a24d9"
  instance_type = "t2.micro"
  key_name = aws_key_pair.example.key_name
  vpc_security_group_ids = [aws_security_group.example.id]
  subnet_id = aws_subnet.example.id
  associate_public_ip_address = true
  tags = {
    Name = "happy-new-year"
  }
}

想定した原因

• セキュリティグループの設定が正しくできていない。
• インスタンスがセキュリティグループに接続されていない。
• ネットワーク(VPC・サブネット)の設定不備

試したこと

ブラウザ上で生成したアクセス可能なインスタンスとの照合。
特に差異は見られませんでした。

セキュリティグループはインバウンドは「22」を、アウトバウンドは「-1(all)」を許可してあり、インスタンスをそれに接続しているため、セキュリティルールに関いてはOK!

ネットワークもVPCとサブネットを正しく設定しているためOK
もっともインターネットからアクセスできないのはこれには関係ありませんが、、、

状況としてはSSHにアクセスできないのではなく、ポートそのものが解放されていない状況です。
ポートスキャンで確認しました。

---

どなたか原因のご指摘をお願いします。

Comments

[yu_1985]

> ブラウザを介して生成した場合

それはこのTerraform内で作成したVPCに作成していますか？

簡素化と書いてありますが、簡素化してしまったら必要な設定があるかわかりません。
パッと見問題ありそうなのはルートテーブルの設定をしていないことですが、該当のサブネットのルートテーブル設定はどうなっていますか？

> ネットワークもVPCとサブネットを正しく設定しているためOK
上のほうにも書いてあるのですが、「正しい」とは何をもってそう判断していますか？

[trash.taro]

> それはこのTerraform内で作成したVPCに作成していますか？
それとは別に、独立したインスタンスとそれに伴ってデフォルトで設定される設定です。

確かに、ルートテーブルの設定をしていませんでした。
そもそも、インターネットゲートウェイの設定もしていませんでした。

失礼いたしました。
もう少し自分で確認してみます。

[trash.taro]

助かりました。
解決できました。

```

provider "aws" {
region = "ap-northeast-1"
}

resource "aws_vpc" "example2" {
cidr_block = "10.0.0.0/16"
}

resource "aws_subnet" "example2" {
vpc_id = aws_vpc.example2.id
cidr_block = "10.0.1.0/24"
}

resource "aws_internet_gateway" "example2" {
vpc_id = aws_vpc.example2.id
}

resource "aws_route_table" "example2" {
vpc_id = aws_vpc.example2.id
route {
cidr_block = "0.0.0.0/0"
gateway_id = aws_internet_gateway.example2.id
}
}

resource "aws_route_table_association" "example2" {
subnet_id = aws_subnet.example2.id
route_table_id = aws_route_table.example2.id
}

resource "aws_security_group" "example2" {
name = "example2"
vpc_id = aws_vpc.example2.id
ingress {
from_port = 22
to_port = 22
protocol = "tcp"
cidr_blocks = ["0.0.0.0/0"]
}
egress {
from_port = 0
to_port = 0
protocol = "-1"
cidr_blocks = ["0.0.0.0/0"]
}
}

resource "aws_key_pair" "example2" {
key_name = "example2"
public_key = file("~/.ssh/id_rsa.pub")
}

resource "aws_eip" "example2" {
vpc = true
}

resource "aws_instance" "example2" {
ami = "ami-be4a24d9"
instance_type = "t2.micro"
key_name = aws_key_pair.example2.key_name
vpc_security_group_ids = [aws_security_group.example2.id]
subnet_id = aws_subnet.example2.id
associate_public_ip_address = true
tags = {
Name = "happy-new-year"
}
}
```

インターネットゲートウェイの設定忘れと、それに伴うルーティングテーブルの設定忘れが原因です。
インターネットゲートウェイを生成していないんだから、インターネットからアクセスできないのは当然でした、、、

ありがとうございます。

Answer 1

インターネットゲートウェイ作ってなかった。
当然ルーティングテーブルも、、、

Loving yu_1985 💓💓💓