VBS インデックスを使用したコレクション要素の取り出し方法

Question

質問内容

VBScriptにおいて、インデックスを使用してコレクション要素を取り出す方法についてご教示願います。

該当のソースコード

Option Explicit

Dim xlApp
Dim MyBook
Dim Sheet_A
Dim Sheet_B
Dim Sheet_C
Dim Sheet_D
Dim Col_Sheets
Dim i

Set xlApp = CreateObject("Excel.Application")

xlApp.Application.Visible = true
xlApp.DisplayAlerts = False

Set MyBook = xlApp.Workbooks.Add()
With MyBook
    Set Sheet_A = .Worksheets(1)
    Set Sheet_B = .Sheets.Add(, Sheet_A)
    Set Sheet_C = .Sheets.Add(, Sheet_B)
    Set Sheet_D = .Sheets.Add(, Sheet_C)
End with

'各シートをコレクションに追加
Set Col_Sheets = CreateObject("Scripting.Dictionary")

With Col_Sheets
    .Add Sheet_A, "A"
    .Add Sheet_B, "B"
    .Add Sheet_C, "C"
    .Add Sheet_D, "D"
End with

For i = 1 To Col_Sheets.Count
    'ここでエラーが発生します。
    col_Sheets.Item(i).Range("A1").Value = 1
Next

やりたいこと

VBAでは、コレクション.Item(インデックス)で要素を取り出せるはずですが、
VBSでは、「オブジェクトがありません。」とエラーが出てしまいます。

ググっても解決策が見つかりませんでした。

Answer 1

下記を対応したところ動くことを確認しました。
・Dictionary への追加する際の引数が逆のようです。正しくは Add <キー>, <値>の順番になります。
・コレクションを参照する際は一旦、keys か Items を Variant 変数に代入する必要があるようです。（理由は知らないです。）

With Col_Sheets
    .Add "A", Sheet_A
    .Add "B", Sheet_B
    .Add "C", Sheet_C
    .Add "D", Sheet_D
End With

Dim items
items = Col_Sheets.items
For i = 0 To Col_Sheets.Count - 1
    items(i).Range("A1").Value = 1
Next

'別の方法
'Dim key
'For Each key In Col_Sheets
'    Dim sheet
'    Set sheet = Col_Sheets(key)
'    sheet.Range("A1").Value = 1
'Next

Comments

[tomiieee]

ご回答いただきありがとうございました。
非常に助かりました。