JuliaのDataFramesMetaでERROR: LoadError: syntax: invalid syntax ##

Question

Julia1.7.2で以下のコードを書きましたがエラーが出ます。

using CSV, DataFrames, DataFramesMeta

df1 = CSV.read("C:/Users/user/Downloads/DF1.txt", DataFrame, header=1)
df2 = CSV.read("C:/Users/user/Downloads/DF2.txt", DataFrame, header=1)

for r in eachrow(df1)
    df_match = @linq df2 |>
    where(:id1 = r[:id1]) |>
    where(:C1 = r[:C1]) |>
    where(:C2 = r[:C2]) |>
    where(:P1 = r[:P1]) |>
    where(:P2 = r[:P2])
    println(df_match)
end

ERROR: LoadError: syntax: invalid syntax ##311 = getindex(Core.getfield(#self#, :r), ##311)
Stacktrace:
 [1] top-level scope
   @ c:\Users\user\Documents\sv_match.jl:6
in expression starting at c:\Users\user\Documents\sv_match.jl:6

##の数字はなぜか毎度違う数字が表示されます。
:の代わりに""で囲むと『ERROR: LoadError: syntax: invalid syntax id1...』と類似のエラーが出ます。
データフレーム自体がうまく読めていないのかとも思いましたが、以下のようにしても異常は見当たりません。

using CSV, DataFrames, DataFramesMeta

df1 = CSV.read("C:/Users/user/Downloads/DF1.txt", DataFrame, header=1)
df2 = CSV.read("C:/Users/user/Downloads/DF2.txt", DataFrame, header=1)

for r in eachrow(df1)
    println(r[:id1])
    println(df2[1,:id1])
end

ABBBCBDBEBFB

Answer 1

興味があって調べてみました。その結果，
Julia言語のパッケージにはよくあることですが，最新のDataFramesMetaの@linq，@where
のマクロが「depricated(廃止?)」になっており，
文法がドラスティックに変わっているようです。
詳しくはreplでusing DataFramesMeta→?→@linq等で確かめてみて下さい。

• @linq → @chain
• @where → @subset

に変更すべし，となっていますが文法も別言語といえるぐらい別のものに変わっています。
ネットにあるこれまでの日本語情報は全く役に立たなくなることでしょう。

一応，次のような感じでしょうか?

using CSV, DataFrames, DataFramesMeta

df1 = CSV.read("C:/Users/user/Downloads/DF1.txt", DataFrame, header=1)
df2 = CSV.read("C:/Users/user/Downloads/DF2.txt", DataFrame, header=1)

for r in eachrow(df1)
    @chain begin
        @subset df2 begin
            :id1 .== r.id1
            :C1 .== r.C1
            :C2 .== r.C2
            :P1 .== r.P1
            :P2 .== r.P2
        end
        println
    end
end

追記

すみません。勘違いしていました。@linqはまだ文法としてあるみたいです。

• r[:id1]ではうまく@linqマクロが認識しないので，r.id1等に変更
• 複数の要素に等価チェックをするので=ではなく.==を使う

等でOKではないでしょうか？

for r in eachrow(df1)
    df_match = @linq df2 |>
    where(:id1 .== r.id1) |>
    where(:C1 .== r.C1) |>
    where(:C2 .== r.C2) |>
    where(:P1 .== r.P1) |>
    where(:P2 .== r.P2)
    println(df_match)
end

Comments

[i113]

どうも有り難うございます。お陰様で解決しました。
前から気になっていた言語で、ちょっと機械があったので挑戦してみたのですが、なかなか厳しそうです。
どうして情報が少ないことがネックなのに、自ら蓄積を無効化するのか...