【VB.NET】子フォームから親フォームのデータグリッドの操作について

Question

現在、MDBからレコードを読み込み、
データグリッド・フォームに内容を表示させるアプリを作成しています。

■前提

下記のような親・子フォームが存在します。
【親フォーム】
・データグリッドにレコードの一覧を表示。
・子フォームを開く際、IDを引き渡している。

【子フォーム】
・レコードの詳細を表示。
・プロパティでIDを取得。
・フォームを開く際にIDをキーに、MDBからレコードを読み込む。

子フォームにあるボタンを押すことで、
親フォームにあるデータグリッドのフォーカスを移動したいと考えております。
また子フォームのデータも、親フォームのフォーカス移動に併せて
表示しなおすことを考えております。
（※画像参照）

■質問

(1)子フォームから親フォームのデータグリッドのフォーカス移動は可能でしょうか。
(2)子フォームの開きなおしをせずに、親フォームから新たにIDを取得し、レコードを読み込みなおすことは可能でしょうか。

以上、よろしくお願いします。

■開発環境

・作成アプリケーションの種類：Windowsフォーム
・開発環境：Windows7 64bit／Visual Studio Professional 2012 ／.NET Framework 4.5

■修正コード１

Public Class 親フォーム

  Private Sub Button詳細_Click(sender As Object, e As EventArgs) Handles Button詳細.Click
    Using  子フォーム As New 子フォーム
      AddHandler 子フォーム.UpClick, AddressOf 子フォーム_UpClick
   Dim _data as New DataStructure
   '選択している行のデータを取得
     _data.ID=....
   
   子フォーム.SetData( _data )
   子フォーム.ShowDialog(Me)
    End Using
  End Sub

  Private Sub 子フォーム_UpClick(sender As Object, e As EventArgs)
    With DataGridView1
       '1行上を選択
       '新たに選択した行のデータを取得
        Dim _data as New DataStructure
       _data.ID=....

       子フォーム.SetData( _data )
    End With
  End Sub
End Class


Public Class 子フォーム
  Private _ID As Integer
  Public Property ID() As Integer
        Get
            Return _ID
        End Get
        Set(value As Integer)
            _ID = value
        End Set
    End Property

  Public Structure DataStructure
     Dim ID As Integer
     '.............
  End Structure  

  Private Sub frmHitSyosai_Load(sender As Object, e As EventArgs) Handles MyBase.Load
   display()
  End Sub

 Private sub display()
  Dim strSql as String
  'SQLを作成
  strSql = "SELECT * FROM テーブル WHERE USRID = ID"
  'OleDbDataReaderでレコード取得
  
  '表示処理
  lblID.text = ...
 End Sub

 Public Event UpClick(ByVal sender As Object, ByVal e As EventArgs)
 
 '親フォームからデータを取得
 Public Sub SetData(ByVal d As DataStructure)
     '表示ロジック
   display()
  End Sub

  '上をクリックした旨のイベントを発行
  Private Sub ButtonUp_Click(sender As Object, e As EventArgs) Handles ButtonUp.Click
    RaiseEvent UpClick(Me, New EventArgs)
  End Sub

End Class

■修正コード２

Public Class 子フォーム
  Private _ID As Integer
  Public Property ID() As Integer
        Get
            Return _ID
        End Get
        Set(value As Integer)
            _ID = value
        End Set
    End Property

  Public Structure DataStructure
     Dim ID As Integer
     '.............
  End Structure  

  Private Sub frmHitSyosai_Load(sender As Object, e As EventArgs) Handles MyBase.Load
   display()
  End Sub

 Private sub display()
  Dim strSql as String
  'SQLを作成
  strSql = "SELECT * FROM テーブル WHERE USRID = ID"
  'OleDbDataReaderでレコード取得
  
  '表示処理
  lblID.text = ID
 Debug.Print(ID)
 '.............
 Me.Refresh()

 End Sub
 
 '親フォームからデータを取得
 Public Sub SetData(ByVal d As DataStructure)
     '表示ロジック
   display()
  End Sub

  Private Sub ButtonUp_Click(sender As Object, e As EventArgs) Handles ButtonUp.Click
    Dim frm As New 親フォーム
    frm = CType(Me.Owner, 親フォーム)
    frm.子フォーム_UpClick(sender, e)
  End Sub

End Class

Comments

[退会済みユーザー]

何を作っているか（Windows Forms? WPF? ASP.NET Web Forms? その他？）と自分の開発環境（開発マシンの OS, Visual Studio のバージョン・エディション、.NET のバージョンなど）は書けませんか？

[f-hanako]

失礼いたしました。追記しましたので、お手数ですがご確認お願いします。

Answer 1

実際に動くコードを貼り付けます。
細かいエラーは考慮していません。
また、前回の回答では、深く考えずに、Usingを用いていましたが、YAmaGNZ様のご指摘の通りですので、このあたりも含めて書き直しました。

Public Class Form1    '親フォーム
    'フォーム上に、DataGridView1
    'Form2起動用にButton1
    'を配置
    Private _frm2 As Form2
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        'ＤＢから表を取得（ここでは、ソースで）
        Dim tbl As DataTable = New DataTable("table1")
        tbl.Columns.Add("ID")
        tbl.Columns.Add("NAME")
        tbl.Columns.Add("AGE")
        Dim row As DataRow
        row = tbl.NewRow()
        row("ID") = "1"
        row("NAME") = "TARO"
        row("AGE") = "30"
        tbl.Rows.Add(row)
        row = tbl.NewRow()
        row("ID") = "2"
        row("NAME") = "HANAKO"
        row("AGE") = "25"
        tbl.Rows.Add(row)
        row = tbl.NewRow()
        row("ID") = "3"
        row("NAME") = "JIRO"
        row("AGE") = "20"
        tbl.Rows.Add(row)
        With DataGridView1
            .DataSource = tbl
            .SelectionMode = DataGridViewSelectionMode.FullRowSelect
            .MultiSelect = False
            .Rows(0).Selected = True
            .AllowUserToAddRows = False
        End With
    End Sub
    Private Sub Button1_Click_1(sender As Object, e As EventArgs) Handles Button1.Click
        If _frm2 Is Nothing OrElse _frm2.IsDisposed Then
            _frm2 = New Form2
        End If
        AddHandler _frm2.UpClick, AddressOf 子フォーム_UpClick
        AddHandler _frm2.DwClick, AddressOf 子フォーム_dwClick
        _frm2.ShowDialog(Me)
    End Sub
    Private Sub 子フォーム_UpClick(sender As Object, e As EventArgs)
        With DataGridView1
            '上の行番号を算出。最上位に行った場合は最下位にする。
            Dim r As Integer = .SelectedCells(0).RowIndex
            r = r - 1
            If r < 0 Then
                r = .Rows.Count - 1
            End If
            selectR(r)
        End With
    End Sub
    Private Sub 子フォーム_dwClick(sender As Object, e As EventArgs)
        With DataGridView1
            '下の行番号を算出。最下位に行った場合は最上位にする。
            Dim r As Integer = .SelectedCells(0).RowIndex
            r = r + 1
            If r > .Rows.Count - 1 Then
                r = 0
            End If
            selectR(r)
        End With
    End Sub
    Private Sub selectR(ByVal r As Integer)
        With DataGridView1
            '指定された行を選択
            .Rows(r).Selected = True
            '指定された行の値を取得し、form2に送る
            Dim _data As New Form2.DataStructure
            _data.ID = CInt(.Rows(r).Cells("ID").Value)
            _data.name = .Rows(r).Cells("NAME").Value.ToString
            _data.age = CInt(.Rows(r).Cells("AGE").Value)
            _frm2.SetData(_data)
        End With
    End Sub
End Class

Public Class Form2
    'フォーム上に、「上」用Button1、「下」用Button2
    '表示用にlblID,lblNamem,lblAge
    'を配置
    Public Event UpClick(ByVal sender As Object, ByVal e As EventArgs)
    Public Event DwClick(ByVal sender As Object, ByVal e As EventArgs)
    Public Structure DataStructure
        Dim ID As Integer
        Dim name As String
        Dim age As Integer
    End Structure
    Public Sub SetData(ByVal data As DataStructure)
        lblID.Text = data.ID.ToString
        lblName.Text = data.name
        lblAge.Text = data.age.ToString
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        RaiseEvent UpClick(Me, New EventArgs)
    End Sub

    Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
        RaiseEvent DwClick(Me, New EventArgs)
    End Sub
End Class

Comments

[f-hanako]

回答ありがとうございます。
実際に動くコードまでありがとうございます。
理解しやすく、無事目標の動きを作成することができました。
今回、ベストアンサーとさせていただきます。
ありがとうございました。

Answer 2

Public Class 親フォーム

  Private Sub Button詳細_Click(sender As Object, e As EventArgs) Handles Button詳細.Click
    Using  子フォーム As New 子フォーム    '－－－－－－１
      AddHandler 子フォーム.UpClick, AddressOf 子フォーム_UpClick


    End Using
  End Sub

  Private Sub 子フォーム_UpClick(sender As Object, e As EventArgs)
    With DataGridView1
       '1行上を選択


       子フォーム.SetData( _data )         '－－－－－－２
    End With
  End Sub
End Class

上記の１の「子フォーム」と、２の「子フォーム」が別インスタンスになっています。

こういう場合は

   Private WithEvents 詳細 As New 子フォーム

    Private Sub Button詳細_Click(sender As Object, e As EventArgs) Handles Button詳細.Click
       Dim _data as New DataStructure
       '選択している行のデータを取得
       _data.ID=....

       詳細.SetData( _data )
       詳細.ShowDialog(Me)

    End Sub

    Private Sub 子フォーム_UpClick(sender As Object, e As EventArgs) Handles 詳細.UpClick
       With DataGridView1
          '1行上を選択
          '新たに選択した行のデータを取得
          Dim _data as New DataStructure
          _data.ID=....

          詳細.SetData( _data )
       End With
    End Sub

という感じでUsingを使用せずに書くべきだと個人的には思います。

もし、Usingを使用するのであれば

  Private Sub 子フォーム_UpClick(sender As Object, e As EventArgs)
    With DataGridView1
       '1行上を選択
       '新たに選択した行のデータを取得
        Dim _data as New DataStructure
       _data.ID=....

       DirectCast(sender, 子フォーム).SetData( _data )
    End With

と、新たにインスタンスを生成しない書き方をすべきです。

Comments

[f-hanako]

ありがとうございます。
インスタンスやUsingの使い方について、理解せずに作成していました…。
今回のご指摘を受けて改めて勉強したいと思います。

Answer 3

子フォームを「修正コード２」のように修正したところ、
子フォームから親フォームのデータグリッドを操作できるようになりました。

しかし、子フォームの表示が更新されません。
IDの引き渡し等はきちんとできていることは確認しています。
フォームの更新後にRefresh()も入れているのですが、更新されませんでした。

他に描画の更新方法はありますか。こちらも合わせてご指摘いただければ幸いです。

Answer 4

参考となるURLは
別のフォームのデータを取得、設定する
があります。

同じ立場になった場合、個人的には、コードが長くなりますが、以下のような感じで作成すると思います。

Public Class 親フォーム

  Private Sub Button詳細_Click(sender As Object, e As EventArgs) Handles Button詳細.Click
    Using  子フォーム As New 子フォーム
      AddHandler 子フォーム.UpClick, AddressOf 子フォーム_UpClick
      子フォーム.ShowDialog(Me)
    End Using
  End Sub

  Private Sub 子フォーム_UpClick(sender As Object, e As EventArgs)
    With DataGridView1
       '1行上を選択
       '新たに選択した行のデータを取得
        Dim _data as New DataStructure
       _data.ID=....

       子フォーム.SetData( _data )
    End With
  End Sub
End Class


Public Class 子フォーム
  Public Event UpClick(ByVal sender As Object, ByVal e As EventArgs)
  '親フォームからデータを取得
  Public Sub SetData(ByVal d As DataStructure)
     label_id.text=d.ID
     '......表示
  End Sub

  '上をクリックした旨のイベントを発行
  Private Sub ButtonUp_Click(sender As Object, e As EventArgs) Handles ButtonUp.Click
    RaiseEvent UpClick(Me, New EventArgs)
  End Sub
  Public Structure DataStructure
    Dim ID As Integer
    '.............
  End Structure
End Class

Comments

[f-hanako]

回答ありがとうございます。
satouさんに提示していただいたコードを参考に修正してみたのですが、
親フォームのイベントを呼び出せませんでした。
いくつかサイトを調べてみたのですが、どこがおかしいのか見当がつきません…。
追記したコードで気になった個所がありましたら、ご指摘お願いできませんか。
よろしくお願いします。