aspxのファイルをhtmlで表示させる方法について

Question

aspxのデータをhtmlで表示したいです。
下記URLのデータのようなaspxの情報を静的なhtmlで表示したいです。
http://xml.pinnaclesports.com/pinnacleFeed.aspx
できれば、範囲指定をして表示させたいのでタグで範囲指定する方法等、あればそちらも併せてお伺いしたいです。
何卒よろしくお願い致します。

Answer 1

質問がアバウト過ぎて分からない事だらけです。

aspxのデータと書いてあるから中身はHTMLかと思ったら、指定されてるURLの中身はXMLだった。
なぜ素直にXMLをHTMLにしたいと言わないのか？
入力データは毎回そのURLから読み込まなければならないのか？
タグで範囲指定するのはプログラマーなのか？それともユーザーなのか？
静的なhtmlで表示したいというのはhtmlファイルを生成するという意味なのか？
htmlを生成するのはリアルタイムなのか？
せめてプログラム言語は何を使うのかくらいは書いてほしい。

まあ文句ばっか言って何も解決策を書かない回答は嫌いなので、とりあえず作りますよ。
質問のタグにASP.NETって付いてるからASP.NET Formで作りますよ。
質問者がVB.NETを読めるのか知らないけど。
指定されたURLのデータは1MByte以上あるので、表示に毎回20秒くらいかかるけど。
htmlファイルを生成する意味はまったくないけど。
出力先のローカルパスとリダイレクト先のURLは調整する必要があるけど。
たぶん求めているのはコレじゃないとは思うけど。

Imports System.Web.UI.HtmlControls		'← System.Web の参照必須！

Partial Public Class WebForm1
	Inherits System.Web.UI.Page

	Private Class EventData
		Public gamenumber As Long
		Public sporttype As String
		Public league As String

		Public participants As List(Of Participant) = New List(Of Participant)
	End Class

	Private Class Participant
		Public participant_name As String
	End Class

	Private m_EventList As List(Of EventData) = New List(Of EventData)

	Private Sub WebForm1_Init(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Init

		Dim xDocument = New System.Xml.XmlDocument()
		Call xDocument.Load("http://xml.pinnaclesports.com/pinnacleFeed.aspx")

		Dim xEventsElements = xDocument.GetElementsByTagName("events")
		Dim xEvents = xEventsElements(0)

		For Each xEvent As System.Xml.XmlNode In xEvents

			Dim eventData = New EventData
			For Each xEventChild As System.Xml.XmlNode In xEvent.ChildNodes
				Select Case xEventChild.Name
					Case "gamenumber"
						eventData.gamenumber = Long.Parse(xEventChild.InnerText)
					Case "sporttype"
						eventData.sporttype = xEventChild.InnerText
					Case "league"
						eventData.league = xEventChild.InnerText

					Case "participants"
						For Each xParticipant As System.Xml.XmlNode In xEventChild.ChildNodes

							Dim participant = New Participant()
							For Each xParticipantChild As System.Xml.XmlNode In xParticipant.ChildNodes
								Select Case xParticipantChild.Name
									Case "participant_name"
										participant.participant_name = xParticipantChild.InnerText
								End Select
							Next
							eventData.participants.Add(participant)
						Next
				End Select
			Next
			m_EventList.Add(eventData)


			Dim sb = New System.Text.StringBuilder(200)
			sb.Append(eventData.league & " (" & eventData.sporttype & ") : ")
			sb.Append(eventData.participants(0).participant_name)
			For i As Integer = 1 To eventData.participants.Count - 1
				sb.Append(" vs " & eventData.participants(1).participant_name)
			Next

			ListBox1.Items.Add(New ListItem(sb.ToString, eventData.gamenumber.ToString))
		Next
	End Sub


	Protected Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click

		Dim fileName = "work.html"
		Dim pathLocal = "C:\inetpub\TestApp\" & fileName
		Dim pathURL = "/TestApp/" & fileName

		Dim gameNumber = Long.Parse(ListBox1.SelectedValue)

		Dim eventData As EventData = Nothing
		For Each item In m_EventList
			If item.gamenumber = gameNumber Then
				eventData = item
				Exit For
			End If
		Next

		Dim enc As System.Text.Encoding = System.Text.Encoding.UTF8

		Using html As New HtmlGenericControl("html")

			Using head As New HtmlGenericControl("Head")
				html.Controls.Add(head)

				Using meta As New HtmlMeta
					head.Controls.Add(meta)
					With meta
						.HttpEquiv = "Content-Type"
						.Content = "text/html"
						.Attributes("charset") = enc.WebName
					End With
				End Using

				Using title As New HtmlTitle
					head.Controls.Add(title)
					title.Text = eventData.league & " (" & eventData.sporttype & ")"
				End Using
			End Using

			Using body As New HtmlGenericControl("body")
				html.Controls.Add(body)

				Dim div = New HtmlGenericControl("div")
				body.Controls.Add(div)
				div.InnerText = "League : " & eventData.league

				div = New HtmlGenericControl("div")
				body.Controls.Add(div)
				div.InnerText = "Sport Type : " & eventData.sporttype

				For Each participant In eventData.participants
					div = New HtmlGenericControl("div")
					body.Controls.Add(div)
					div.InnerText = "Participant : " & participant.participant_name
				Next
			End Using

			Using file As New System.IO.FileStream(pathLocal, IO.FileMode.Create)
				Using writer As New System.Web.UI.HtmlTextWriter(New System.IO.StreamWriter(file, enc))
					html.RenderControl(writer)
					writer.Flush()
				End Using
			End Using
		End Using

		Response.Redirect(pathURL, False)
	End Sub
End Class