Visual Studioのカスタムコントロールの罫線描画について

Question

###前提・実現したいこと
System.Windows.Forms.Buttunを継承したカスタムコントロールにてOnPaintを利用して幅と色を指定して罫線を引いています。
コントロールの上にエクスプローラ等の別画面を開いた際、罫線が画面上に見えているコントロールの幅にて引かれます。その後エクスプローラを閉じた時にその罫線が消えずに残るので、ボタンの中に罫線が引かれたままになってしまいます。(マウスオーバーすると消えます)
エクスプローラを閉じた時に自動で罫線も元の大きさにもどしたいのですがやり方を教えていただけますでしょうか。
ボタン内のbackcolorや文字を再描画できれば良いと思うのですが、、、。

###発生している問題・エラーメッセージ

エラーメッセージ

###該当のソースコード

Public Class CustomButton
    Inherits Button
    ''' <summary>枠線色</summary>
    Private pBorderColor As Color = Color.FromArgb(213I, 223I, 229I)
    ''' <summary>枠線影色</summary>
    Private pBorderShadow As Color = Color.White
    ''' <summary>枠線太さ</summary>
    Private pBorderWidth As Integer = 1
    ''' <summary>枠線スタイル</summary>
    Private pBorderStyle As ButtonBorderStyle = ButtonBorderStyle.Solid
    ''' <summary>枠線スタイル</summary>
    Private pTextAlign As HorizontalAlignment

    ''' <summary>枠線</summary>
    Public Property BorderColor() As Color
        Get
            Return pBorderColor
        End Get
        Set(ByVal value As Color)
            pBorderColor = value
        End Set
    End Property

    ''' <summary>枠線影色</summary>
    Public Property BorderShadow() As Color
        Get
            Return pBorderShadow
        End Get
        Set(ByVal value As Color)
            pBorderShadow = value
        End Set
    End Property

    ''' <summary>枠線太さ</summary>
    Public Property BorderWidth() As Integer
        Get
            Return pBorderWidth
        End Get
        Set(ByVal value As Integer)
            pBorderWidth = value
        End Set
    End Property

    ''' <summary>枠線スタイル</summary>
    Public Property BorderStyle() As ButtonBorderStyle
        Get
            Return pBorderStyle
        End Get
        Set(ByVal value As ButtonBorderStyle)
            pBorderStyle = value
        End Set
    End Property

    Protected Overrides Sub OnPaint(ByVal e As PaintEventArgs)
        MyBase.OnPaint(e)

        Dim tBorderRect As Rectangle = e.ClipRectangle
        ControlPaint.DrawBorder(e.Graphics, tBorderRect, BorderColor, pBorderWidth,
        pBorderStyle, BorderColor, pBorderWidth, pBorderStyle,
        BorderColor, pBorderWidth, pBorderStyle, BorderColor, pBorderWidth, pBorderStyle)

    End Sub

End Class

###試したこと
Windows7にて現象が再現します。
クラシックのテーマだと確実に再現します。
上記テーマでなくても、画面外にフォームを移動してコントロールが画面枠に重なるようにすると再現します。
ダブルバッファリングを有効にしてみましたがダメでした。

###補足情報(言語/FW/ツール等のバージョンなど)
.netFramework4.0、Visual Studio 2015

Answer 1

ちょっと同じ現象はでないのですが、フォームを画面外に移動して戻すと罫線色で文字が消えました。

Dim tBorderRect As Rectangle = e.ClipRectangle

これだと再描画が必要な部分になってしまうので、

Dim tBorderRect As Rectangle = Me.ClientRectangle

これでどうでしょうか。

Comments

[trainy]

ご回答ありがとうございます。

まさにおっしゃる通りで、変更したら正常に動くようになりました。

今月末納期なためレイアウトに関しては諦めかけていたので感動です。

ありがとうございました。

[crowmt]

無事に解決できたようで何よりです、
こちらも納期地獄で死にかけております。
お互い頑張りましょう！