VBSでWordファイルの文字列を置換する

Question

VBSでWordファイルの文字列の置換をします。
プログラムを実行すると

行: 36
文字: 5
エラー: オブジェクトでサポートされていないプロパティまたはメソッドです。: 'doc.Selection'
コード: 800A01B6
ソース: Microsoft VBScript 実行時エラー

とエラーメッセージが出ます。
また、エラーの出る36行目から関係する40行目をコメントアウトにして
実行すると特にエラーが出ないので、正常に終了しているのだと思いますが、
プロセスにワードが残ったままになります。
27行目の処理ではプロセスの終了はできないでしょうか。
宜しくお願い致します。

Dim FindWord
Dim ReplaceWord
Const wdReplaceAll = 2

' docxファイルの文字列を置換処理するプログラム
FindWord = InputBox("置換対象文字は？", "置換対象文字指定", "")
If FindWord ="" Then WScript.Quit
ReplaceWord = InputBox("置換後文字は？", "置換後文字指定", "")

'Wordオブジェクト作成
Dim wordApp
Set wordApp = WScript.CreateObject("Word.Application")
wordApp.Visible = False

' ファイル操作用のオブジェクトを得る
Dim FSO
Set FSO = CreateObject("Scripting.FileSystemObject")
Dim ThisVbsPath
ThisVbsFolderPath = FSO.GetParentFolderName(WScript.ScriptFullName)
' ファイルの一覧を得る
For Each f In FSO.GetFolder(ThisVbsFolderPath).Files
    ' docx ファイルだけ処理する
    If LCase(FSO.GetExtensionName(f.Name)) = "docx" And Left(FSO.GetFileName(f),2) <> "~$" Then
        ReplaceDoc f.Path
    End If
Next
Set wordApp = nothing


' 各docx ファイルを処理するサブルーチン
Sub ReplaceDoc(fname)
    Dim doc
    ' Wordファイルを開いて処理
    Set doc = wordApp.Documents.Open(fname)
    ' Wordのテキストを一括置換する
    With doc.Selection
        .Find.Text = FindWord
        .Find.Replacement.Text = ReplaceWord
        .Find.Execute 'Replace:=wdReplaceAll
    End With
    ' ファイルを保存して閉じる
    doc.Save
    doc.Close
End Sub

Answer 1

少し修正してみました。こちらでどうでしょうか？

Option Explicit

Dim FindWord
Dim ReplaceWord
Const wdReplaceAll = 2

' docxファイルの文字列を置換処理するプログラム
FindWord = InputBox("置換対象文字は？", "置換対象文字指定", "")
If FindWord ="" Then WScript.Quit
ReplaceWord = InputBox("置換後文字は？", "置換後文字指定", "")

'Wordオブジェクト作成
Dim wordApp
Set wordApp = WScript.CreateObject("Word.Application")
wordApp.Visible = False

' ファイル操作用のオブジェクトを得る
Dim FSO
Set FSO = CreateObject("Scripting.FileSystemObject")
Dim ThisVbsFolderPath
ThisVbsFolderPath = FSO.GetParentFolderName(WScript.ScriptFullName)
' ファイルの一覧を得る
Dim f
For Each f In FSO.GetFolder(ThisVbsFolderPath).Files
    ' docx ファイルだけ処理する
    If LCase(FSO.GetExtensionName(f.Name)) = "docx" And Left(FSO.GetFileName(f),2) <> "~$" Then
        ReplaceDoc f.Path
    End If
Next
wordApp.Quit

' 各docx ファイルを処理するサブルーチン
Sub ReplaceDoc(fname)
    Dim doc
    ' Wordファイルを開いて処理
    Set doc = wordApp.Documents.Open(fname)
    ' Wordのテキストを一括置換する
    With wordApp.Selection
        .Find.Text = FindWord
        .Find.Replacement.Text = ReplaceWord
        .Find.Execute,,,,,,,,,,wdReplaceAll
    End With
    ' ファイルを保存して閉じる
    doc.Save
    doc.Close
End Sub

■ Option Explicit について
追加）Option Explicit
→ これを追加すると変数の宣言忘れを防止することができます。VBScript や VBA でコーディングする場合は先頭に入れておくことをお勧めします。

■ Selection プロパティについて
変更前）doc.Selection
変更後）wordApp.Selection
Selection は doc のプロパティではありません。
wordAapp.Selection もしくは doc.ActiveWindow.Selection とすることでエラー回避できるかと思います。

■ プロセスを強制終了させる方法について

27行目の処理ではプロセスの終了はできないでしょうか。

プロセスが残りっぱなしなるようなケースは、Quit メソッドを試してください。

変更前）Set wordApp = nothing
変更後）wordApp.Quit

Comments

[nkym771]

■ Selection プロパティについて
■ プロセスを強制終了させる方法について
ご提示ありがとうございます。動作しました。

■ Option Explicit について
.Find.Execute,,,,,,,,,,wdReplaceAll
もありがとうございました。
「.Find.Execute,,,,,,,,,,wdReplaceAll」を見て再度調べ、
https://learn.microsoft.com/ja-jp/office/vba/api/word.find.execute
のページの見方が分かりました。