スプレッドシートQuery関数で、別条件のデータをまとめて1つのコードで出力したい

Question

スプレッドシートのQuery関数の使い方について質問です。

違う条件のコード同士を1つの式に組み込み、商品の販売重量を年月ごとに集計したいのですが、上手くいきません。

(コードはGASのSetFormulaメソッドを使って書いています)

実現したいこと

販売した商品の重量を年月ごとに集計したいです。

具体的には、

① 全商品 (20g、80g、1kg全て) の販売重量
② 20gの販売重量
③ 80gの販売重量
④ 1kgの販売重量

を年月ごとに集計したいです。

(参照先のデータ一部抜粋↓)

(Query関数で出力したデータ↓)

上記の出力データは、先述「① 全商品の販売重量」の集計データです。
以下のコード (以降「コード1」と書きます) を使いました。

sheet.getRange(1, 1).setFormula(`=QUERY('発送管理表'!C:F,"select year(C), month(C)+1, sum(F) where C is not null group by year(C), month(C)+1 label year(C) '年', month(C)+1 '月', sum(F) '全商品の販売重量 (kg)'",2)`);

このコードに、さらに ②～④ 各商品の販売重量データを表示させるコードを組み込み、1つの式ですべてのデータを出力しようとしています。

イメージとしては、

・D列に20gの販売重量
・E列に80gの販売重量
・F列に1kgの販売重量

を出力し、各商品の集計結果が一目でわかるようにしたいです。

発生している問題・エラーメッセージ

以下がエラーメッセージの内容です。

関数 QUERY のパラメータ 2 のクエリ文字列を解析できません: PARSE_ERROR: Encountered " "where" "where "" at line 1, column 37. Was expecting one of: ")" ... "*" ... "+" ... "-" ... "/" ... "%" ...

試したこと

まず手始めに、年月ごとの20gの販売重量を表すコード (以降「コード2」と書きます) を別途用意しました。
(年月の表示は省いています)

sheet.getRange(1, 11).setFormula(`=QUERY('発送管理表'!C:F,"select sum(F) where D = '20g' group by year(C), month(C)+1 label sum(F) '20gの販売重量 (kg)'",2)`);

結果が以下の画像です。

このデータが、一番最初に掲載した画像のD列にも表示されるよう、コード1にコード2を組み込んで以下のようにしてみました。

sheet.getRange(1, 1).setFormula(`=QUERY('発送管理表'!C:F,"select year(C), month(C)+1, (sum(F) where C is not null group by year(C), month(C)+1),(sum(F) where D = '20g' group by year(C), month(C)+1) label year(C) '年', month(C)+1 '月', sum(F) '全商品の販売重量 (kg)', sum(F) '20gの販売重量 (kg)",2)`);

全商品の販売重量のコード、20gの販売重量のコードは条件が違うため、それぞれ () で括って入れ子のようにしています。

ですが、これではエラーが起きてしまいます。

Query関数では、それぞれ別条件のデータを1つの式で表すことはできないのでしょうか？
ご教示よろしくお願いします。

Answer 1

（GASに組み込んだ形での回答は省略し、コアとなる数式のみ提示します）

Query関数で、別条件のデータを1つの式に表す方法

ARRAYFORMULA関数と配列とカンマを使用します。

一般化すると：

=ARRAYFORMULA({QUERY式, QUERY式, ...})

たとえば、「年、月、全商品の合計、20gの商品の合計」の4列を表示したい場合

=ARRAYFORMULA(
  {
    QUERY('発送管理表'!C:F, 
      "select year(C), month(C)+1, sum(F) where C is not null group by year(C), month(C)+1
       label year(C) '年', month(C)+1 '月', sum(F) '全商品の販売重量 (kg)'",2
    ),
    QUERY('発送管理表'!C:F,
      "select sum(F) where D = '20g' group by year(C), month(C)+1 
       label sum(F) '20gの販売重量 (kg)'",2
    )  
  }
)

とします。
同様に、80g、1kgも追加すれば可能です。

---

ただし上記の数式の連結では、以下の制限があります。
・その重量がない月が存在する場合、エラーになる（例：「6月は1kg、20g、80gのデータがあるが、7月は1kgと80gのデータしか存在しない」というような場合）
・決まった重量種類しか対応できず、仮に途中で新しい重量が追加された場合は、数式を修正する必要が生じる。

これらの制限は、下記のようにPIVOTを使用することで回避できます。

=QUERY('発送管理表'!C:F,
  "select year(C), month(C)+1, sum(F) where C is not null group by year(C), month(C)+1 pivot D
    label year(C) '年', month(C)+1 '月', sum(F) 'の販売重量 (kg)'")

これだけだと、各重量カテゴリの小計だけの表示になっており、各年月の重量合計が表示されていません。
各年月の重量合計も一緒に表示したい場合は、下記のように 重量カテゴリの合計を集計する QUERY 式を ARRAYFORMULA で連結する必要があります。

=ARRAYFORMULA({    
    QUERY('発送管理表'!C:F,"select year(C), month(C)+1, sum(F) where C is not null group by year(C), month(C)+1 
        label year(C) '年', month(C)+1 '月', sum(F) '全商品の販売重量 (kg)'"
    ),
    QUERY('発送管理表'!C:F,"select  sum(F) where C is not null group by year(C), month(C)+1 pivot D  
      label sum(F) 'の販売重量 (kg)'"
    )
})

---

コメントで「イレギュラーな重量は除外したい」とのことだったので、
たとえば、20g、80g、1kg だけ抽出したい場合は
下記のようになります。

（WHERE句に
and (D='80g' or D='1kg' or D='20g')
を追加すればいいだけです）

=ARRAYFORMULA({    
    QUERY('発送管理表'!C:F,
      "select year(C), month(C)+1, sum(F) 
       where C is not null  and (D='80g' or D='1kg' or D='20g') 
       group by year(C), month(C)+1  
       label year(C) '年', month(C)+1 '月', sum(F) '全商品の販売重量 (kg)'"
    ),
    QUERY('発送管理表'!C:F,
      "select  sum(F) 
       where C is not null  and (D='80g' or D='1kg' or D='20g') 
       group by year(C), month(C)+1 pivot D 
       label sum(F) 'の販売重量 (kg)'"
    )
})

参考：
Query Language Reference (Version 0.7)

Comments

[raddish]

ご回答ありがとうございます。

頂いたアドバイスをもとにやってみたところ、実現できました。
20g、80g、1kgのほかにもイレギュラーで売れた重量 (5kg、10kgなど) の列も出力されましたが、これに関しては仕方ないと判断するしかないですよね。列の非表示などで対応しようと思います。

今回の質問でARRAYFORMULAとpivotの使い方がわかり、大変参考になりました。
ありがとうございます！

[退会済みユーザー]

イレギュラーで売れた重量は除外し、指定した重量だけ集計する方法について追記しました。

[raddish]

こんなことまで出来るんですね、、ありがとうございます！