単一のセルから一部の情報取得

Question

お世話になります。

excelのシートのセルに以下のような情報が記述されています。
”■(設定A) □(設定B)”

※■がこの場合の設定の対象、□は対象ではない。(チェックボックスの代わりに使用)
このような情報が1つのセルにあった場合に、■がある方の()の中の設定のみを読み取って以降の処理で活用していきたいのですが、どのようにして判別したらよいのでしょうか？お力を貸していただけると大変助かります。

多くの回答ありがとうございます。いろいろと試行錯誤しながら考えていますのでベストアンサーは今しばらくお待ちいただければと思います。

Answer 1

正規表現でマッチングさせてはどうでしょうか

Dim regEx, matches As Object
Set regEx = CreateObject("VBScript.RegExp")

regEx.Pattern = "■\(([^\)]*)\)"

Set matches = regEx.Execute("■(設定A) □(設定B)") 
Debug.Print matches(0).submatches(0) ' ⇒ 設定A
Set matches = regEx.Execute("□(設定A) ■(設定B)") 
Debug.Print matches(0).submatches(0) ' ⇒ 設定B

Answer 2

入力された文字列のレイアウトが多少崩れていても取得できるよう、取得したい条件をそのままロジックにしてみました。

最初に見つけた■から次の□の前までを選択項目として取得する方法となっています。

Sub test()
    Dim strInput As String
    Dim strVal As String
    Dim iPos As Integer
    
    strInput = Sheets("Sheet14").Cells(2, 2)
    
    
    iPos = InStr(strInput, "■")
    
    If iPos = 0 Then
        '■は見つからなかった
        Exit Sub
    Else
        'とりあえず見つけた位置以降の文字列を取得
        strVal = Mid(strInput, iPos + 1)
        
        '次の□を検索
        iPos = InStr(strVal, "□")
        If iPos > 0 Then
            '見つかった場合は□以降を除去
            strVal = Mid(strVal, 1, iPos - 1)
        End If
        '念のため■も残っていないか検索
        iPos = InStr(strVal, "■")
        If iPos > 0 Then
            '見つかった場合は■以降を除去
            strVal = Mid(strVal, 1, iPos - 1)
        End If
    End If
    
    '括弧外に余分なスペースがあれば除去
    strVal = Trim(strVal)
    '前後の括弧を除去
    strVal = Mid(strVal, 2, Len(strVal) - 2)
   
    MsgBox strVal
    
End Sub

参考になれば幸いです。

Answer 3

”■(設定A) □(設定B)” のフォーマットを崩さない前提で、セルA1に入っているとして。

Sub test()
    Arr = Split(Range("A1").Value, " ")
    
    If Left(Arr(0), 1) = "■" Then
        Shori = Mid(Arr(0), 2)
        Shori = Replace(Shori, "(", "")
        Shori = Replace(Shori, ")", "")
    ElseIf Left(Arr(1), 1) = "■" Then
        Shori = Mid(Arr(1), 2)
        Shori = Replace(Shori, "(", "")
        Shori = Replace(Shori, ")", "")
    End If

    Msgbox Shori
End Sub

やっつけで済みません。
同じ処理をしている部分は関数化するとか工夫の余地はありますね。

Comments

[ynakano]

両方に"■"はない前提ですね。
両方にあったら「設定A」が引っかかります。

[coko1]

両方にはないのは前提になります。しかし、基本的なフォーマットは変わらないとしても”　”があるのが前提かといわれると難しいところです。
ほぼ間違いなくあるであろう、といった感じなので...

[ynakano]

区切り文字は何でも良いですが、フォーマットは決めておかないと処理ができない、もしくは著しく煩雑になりますね。

それか閉じ括弧を区切り文字にしてtrimで余分なスペースを落とすかですかね。