Variable not in scope: in Haskell

Question

Haskell初心者です。本のコードを少し変えて写したのですがエラーが出て解決できません。
todoリストで、コマンドライン引数で値を渡して、テキストファイルに入出力をするプログラムです。コマンドラインに渡す形式としては以下です。removenに渡している「２」で消したい番号を指定してます。

./todo add todo.txt "予定などのTodo"
./todo view todo.txt
./todo remove todo.txt 2

エラー内容は以下です。

todo.hs:33:5: error:
    Variable not in scope:
      bracketOnError
        :: IO (FilePath, Handle)
           -> ((FilePath, Handle) -> IO ())
           -> ((FilePath, Handle) -> IO ())
           -> IO ()

ソースコードの全文です。エラー個所に ERROR とコメントをつけておきました

{-# OPTIONS -Wall #-}
import System.IO
import System.Environment
import System.Directory
import Data.List

main = do
    (command:argList) <- getArgs
    dispatch command argList

dispatch :: String -> [String] -> IO ()
dispatch "add" = add
dispatch "view" = view
dispatch "remove" = remove
dispatch _ = error "no match method"

add :: [String] -> IO()
add [fileName, todoItem] = appendFile fileName (todoItem ++ "\n")

view :: [String] -> IO ()
view [fileName] = do
    contents <- readFile fileName
    let todoTasks = lines contents
        numberedTasks = zipWith (\n line -> show n ++ " " ++ line) [0..] todoTasks
    putStrLn $ unlines numberedTasks

remove :: [String] -> IO()
remove [fileName, numberString] = do
    contents <- readFile fileName
    let number = read numberString
        oldTodoItems = zipWith (\n line -> show n ++ " " ++ line) [0..] $ lines contents
        newTodoItems = unlines $ delete (oldTodoItems !! number) oldTodoItems
    bracketOnError  {- ERROR -}
        (openTempFile "." "temp")
        (\ (tempName, tempHandle) -> do
            hClose tempHandle
            removeFile tempName)
        (\ (tempName, tempHandle) -> do
            hPutStr tempHandle newTodoItems
            hClose tempHandle
            removeFile fileName
            renameFile tempName fileName)

Answer 1

エラーの内容ですが、「bracketOnError という変数がスコープ内にありません」です。

bracketOnError は Control.Exception モジュールで 定義されています ので、import Control.Exception を追加してみてください。