表の下にオブジェクトを挿入するマクロについて（再投稿）

現状出来ている部分を少し扱いやすいよう修正し、コード中で????となっていた色変更部分を補完しました。

Enum COL
    ID = 2
    LV = 3
End Enum

' プロジェクトネットワーク図作成マクロ
Sub test()
    ' 変数宣言
    Dim RoopCount As Long ' ループカウンタ
    Dim ID_Count As Long ' ループカウンタ
    Dim LastRow As Long ' ID最終行取得
    Dim TestID As String ' ID取得

    With Worksheets("Sheet2")

        ' B列が空欄であればfor文を抜ける ⇒ 正しくは、B列の最終データ行までループ処理を行う
        RoopCount = .Cells(Rows.Count, COL.ID).End(xlUp).Row

        Dim clShapes As New Collection

        For ID_Count = 4 To RoopCount

            ' B列にIDが記入されていれば処理を行う
            If .Cells(ID_Count, COL.ID).Value <> "" Then
                ' 表のB列試験ID最終行を取得
                LastRow = .Cells(Rows.Count, COL.ID).End(xlUp).Row

                ' B列試験ID取得
                TestID = .Cells(ID_Count, COL.ID).Value

                ' オブジェクト追加
                'Set myDocument = Worksheets(2)
                'myDocument.Shapes.AddShape msoShapeRoundedRectangle, 50, 50, 88, 37
                '' シェイプを選択
                'ActiveSheet.Shapes(1).Select
                Dim shp As Shape
                Set shp = .Shapes.AddShape(msoShapeRoundedRectangle, 50, 50, 88, 37)

                '文字色の設定
                shp.TextFrame2.TextRange.Font.Fill.ForeColor.RGB = vbBlack
                shp.TextFrame2.VerticalAnchor = msoAnchorMiddle
                shp.TextFrame2.TextRange.ParagraphFormat.Alignment = msoAlignCenter

                '罫線色の設定
                shp.Line.ForeColor.RGB = vbGreen    'vbGreenのような予約語でなく、RGB(0,255,0)という記述も可能です

                '塗りつぶしの設定
                shp.Fill.ForeColor.RGB = vbWhite

                '文字列を入れる
                'Selection.Characters.Text = TestID 'A列のみ
                shp.TextEffect.Text = TestID 'A列のみ

                '作成したシェイプをコレクションに追加しておく
                clShapes.Add shp, TestID

            End If
        Next

        '矢印を引く（ルールはわからないのでとりあえず"A001"から"A002"への引き方）
        Dim shp1 As Shape
        Dim shp2 As Shape

        Dim shpAllow As Shape

        Set shp1 = clShapes("A001")
        Set shp2 = clShapes("A002")

        '矢印の作成
        Set shpAllow = .Shapes.AddConnector(msoConnectorStraight, 353.25, 51.25, 384.5, 88)
        shpAllow.Line.EndArrowheadStyle = msoArrowheadOpen

        '始点の設定（A001の右辺）
        shpAllow.ConnectorFormat.BeginConnect shp1, 4
        '終点の設定（A002の左辺）
        shpAllow.ConnectorFormat.EndConnect shp2, 2

    End With

End Sub

他にも内容に応じて配置を変更したり、矢印を設置する必要があるのだと思いますが、配置のルールも提示いただいていないようですし、あとは自力で頑張ってみてください。
（矢印の引き方はサンプルとして１本だけ記述しました。）
（配置の方法は他の方からサンプルコードが提示されているようですので、組み合わせてご利用ください。）

「開発」メニューの中にある「マクロの記録」で操作内容をマクロ化すると開発がはかどる場合があります。

今回でいうと、シェイプを作成してから「マクロの記録」を開始し、シェイプの色や位置などを変更して記録終了すると、シェイプの色や位置を変更した操作を自動的にVBAで作成してくれます。
（一度にたくさんの操作をしたり余分な操作をしたりすると、目的の命令がどこにあるのかわかりにくくなるので、細かい単位で記録することをお勧めします。）

参考になれば幸いです。

お急ぎということですので、ある程度まで作成しました。

' プロジェクトネットワーク図作成マクロ
Sub test()
' 変数宣言
Dim RoopCount As Long ' ループカウンタ
Dim ID_Count As Long ' ループカウンタ
Dim LastRow As Long ' ID最終行取得
Dim TestID As String ' ID取得
Dim myDocument As Worksheet
 'LV1～LV4用のcollection
Dim Coll1 As New Collection
Dim Coll2 As New Collection
Dim Coll3 As New Collection
Dim Coll4 As New Collection
Dim i, j, k, l, m As Integer
Dim jn, kn, ln, mn As Integer
Dim LV1(10), LV2(10), LV3(10), LV4(10) As String
Dim LV1Row(10), LV2Row(10), LV3Row(10), LV4Row(10) As Integer

i = 1
j = 0
k = 0
l = 0
m = 0

With Worksheets("Sheet1")

' B列が空欄であればfor文を抜ける
RoopCount = .Cells(Rows.Count, "B").End(xlUp).Row
For ID_Count = 3 To RoopCount

' B列にIDが記入されていれば処理を行う
If .Cells(ID_Count, 2).Value <> "" Then
' 表のC列を確認し、LVに応じて各LVの配列にデータを振り分け、また、その時の行数を取得しておく。
LastRow = .Cells(Rows.Count, 2).End(xlUp).Row
    Select Case .Cells(ID_Count, 3)
    Case "LV1"
    LV1(j) = .Cells(ID_Count, 2)
    LV1Row(j) = ID_Count
    j = j + 1
    Case "LV2"
    LV2(k) = .Cells(ID_Count, 2)
    LV2Row(k) = ID_Count
    k = k + 1
    Case "LV3"
    LV3(l) = .Cells(ID_Count, 2)
    LV3Row(l) = ID_Count
    l = l + 1
    Case "LV4"
    LV4(m) = .Cells(ID_Count, 2)
    LV4Row(m) = ID_Count
    m = m + 1
    End Select
    End If
Next

'各レベルのカウント数
jn = j
kn = k
ln = l
mn = m

' オブジェクト追加
Set myDocument = Worksheets(1)

For j = 1 To jn
    TestID = .Cells(LV1Row(j - 1), 2).Value
myDocument.Shapes.AddShape msoShapeRoundedRectangle, 50, 50 + i * 50, 88, 37
' シェイプを選択
Coll1.Add ActiveSheet.Shapes.Item(j)
'塗りつぶしの設定
Coll1.Item(j).Fill.ForeColor.ObjectThemeColor = msoThemeColorBackground1
Coll1.Item(j).Line.ForeColor.RGB = RGB(0, 0, 0)
'文字列を入れる
Coll1.Item(j).DrawingObject.Text = TestID
Coll1.Item(j).DrawingObject.Font.Color = 0
i = i + 1
Next

i = 0
For k = 1 To kn
    TestID = .Cells(LV2Row(k - 1), 2).Value
myDocument.Shapes.AddShape msoShapeRoundedRectangle, 150, 50 + i * 50, 88, 37
' シェイプを選択
Coll2.Add ActiveSheet.Shapes.Item(jn + k)
'塗りつぶしの設定
Coll2.Item(k).Fill.ForeColor.ObjectThemeColor = msoThemeColorBackground1
Coll2.Item(k).Line.ForeColor.RGB = RGB(0, 0, 0)
'文字列を入れる
Coll2.Item(k).DrawingObject.Text = TestID
Coll2.Item(k).DrawingObject.Font.Color = 0
i = i + 1
Next

i = 0

For l = 1 To ln
        TestID = .Cells(LV3Row(l - 1), 2).Value
myDocument.Shapes.AddShape msoShapeRoundedRectangle, 250, 50 + i * 50, 88, 37
' シェイプを選択
Coll3.Add ActiveSheet.Shapes.Item(jn + kn + l)
'塗りつぶしの設定
Coll3.Item(l).Fill.ForeColor.ObjectThemeColor = msoThemeColorBackground1
Coll3.Item(l).Line.ForeColor.RGB = RGB(0, 0, 0)
'文字列を入れる
Coll3.Item(l).DrawingObject.Text = TestID
Coll3.Item(l).DrawingObject.Font.Color = 0
i = i + 1
Next

i = 0

For m = 1 To mn
        TestID = .Cells(LV4Row(m - 1), 2).Value
myDocument.Shapes.AddShape msoShapeRoundedRectangle, 350, 50 + i * 50, 88, 37
' シェイプを選択
Coll4.Add ActiveSheet.Shapes.Item(jn + kn + ln + m)
'塗りつぶしの設定
Coll4.Item(m).Fill.ForeColor.ObjectThemeColor = msoThemeColorBackground1
Coll4.Item(m).Line.ForeColor.RGB = RGB(0, 0, 0)
'文字列を入れる
Coll4.Item(m).DrawingObject.Text = TestID
Coll4.Item(m).DrawingObject.Font.Color = 0
i = i + 1
Next

End With
End Sub

上記コードで、以下のように接続関係以外は表示できるかと思います。
接続関係は、図からは読み取れないため実装しておりません。
センスのないコードですみませんが、まずは各レベル毎にデータを整理し、その後順に描画した方が良いかと思います。
配置や、文字、図の色、配置については、好みでご変更いただければと思います。

マクロの記録という機能で解決できました！ありがとうございました。