面倒なログ出力を一行にまとめたい。

Question

###前提・実現したいこと
List内の要素文字列を10ずつにまとめてログ出力したい。
List内には1～100までの(順不同,必ずしも1～100まで入っているわけではなく入っていない数値に関しては変わりに空白が入る。)数値が入っている。 例：1,10,5,90,75, ,・・・(便宜上カンマを入れている。必ずしも10以上入るわけではない。空白が入った次点でそれ以降に数値が入ることはない。)

###該当のソースコード

'下記だと条件にあった要素ごとに出力される。
details.Where(Function(x) Not String.IsNullOrEmpty(x.Code)).ToList(). _
        ForEach(Sub(i) logger.Info(i.Code))

###補足情報(言語/FW/ツール等のバージョンなど)
上記ソースコードだと
1
10
5
90
75
と出力されるが、一行に出力したい。区切り文字(,)で区切り、10文字までを一行にてまとめて出力したいと考えております。複数行に渡ってコードを書けば実現できなくはないですが、Linqの勉強も兼ねて一行を目指しております。
わかり難い説明で申し訳ございませんがよろしくお願い致します。

Answer 1

普段はC#でしかLINQ書かないので、細かい書き方はちょっと怪しいですが…。

むりやりワンライナーで書くならこんな感じでしょうか。

details.TakeWhile(Function(d) Not String.IsNullOrEmpty(d.Code)).
        Select(Function(d, i) New With {Key .Detail = d, Key .GrpIdx = i \ 10}).
        GroupBy(Function(a) a.GrpIdx).
        Select(Function(g) String.Join(",", g.Select(Function(a) a.Detail.Code))).
        ToList().
        ForEach(Sub(l) logger.Info(l))

• 最初のTakeWhileは、ご提示いただいたコードのとおりWhereでも構いませんが、

空白があった時点でそれ以降の要素を見る必要がないならばTakeWhileのほうが意図がわかりやすいと思います。

• Selectで10件ずつIndexをつけてから、GroupByでグループ化しています。

• 「n件ずつグループ化する」というのを1つの拡張メソッドにして名前をつけてしまえば

もう少し読みやすくなるかもしれません。

Public Module IEnumerableExt

    <Runtime.CompilerServices.Extension()>
    Public Function ToGroupsOf(Of T)(collection As IEnumerable(Of T), count As Integer) As IEnumerable(Of IGrouping(Of Integer, T))
        If collection Is Nothing Then
            Throw New ArgumentNullException("collection")
        End If
        If count <= 0 Then
            Throw New ArgumentOutOfRangeException("count")
        End If

        Return collection.Select(Function(x, i) New With {Key .Val = x, Key .GrpIdx = i \ count}).
                          GroupBy(Function(a) a.GrpIdx, Function(a) a.Val)
    End Function
End Module

details.TakeWhile(Function(d) Not String.IsNullOrEmpty(d.Code)).
        ToGroupsOf(10).
        Select(Function(g) String.Join(",", g.Select(Function(d) d.Code))).
        ToList().
        ForEach(Sub(l) logger.Info(l))