List(Of String()) をLinqでgroup byして集計したい

Question

###やりたいこと
番号,数値,名前 で構成されたリストがあり、番号ごとに数値の合計と件数を取得したい。
例えば以下のデータが入っているとすると
1, 15000, sss
1, 1300, ccc
2, 10000, aaa
2, 50003, aaa
2, 200, oooo

結果として
1, 16300, 2
2, 60203, 3
↑が出てきて、これをまた別のList(Of String())に入れたい。

###やってみたこと

        Dim resultList As New List(Of String())

        resultList.Add(New String() {"1", "15000", "sss"})
        resultList.Add(New String() {"1", "1300", "ccc"})
        resultList.Add(New String() {"2", "10000", "aaa"})
        resultList.Add(New String() {"2", "50003", "iii"})
        resultList.Add(New String() {"2", "200", "oooo"})

        Dim aaa As New List(Of String())
        aaa = resultList.GroupBy(Function(s) Tuple.Create(s(0)),
                Function(s2, s)
                    Return New With {
                        .ShopID = s2.Item1,
                        .Value1 = s.Sum(Function(s3) s3(1)),
                        .Value2 = s.Count(Function(s3) s3(2))
                    }
                End Function)

###結果
aaa = のところで型が違う様な意味のエラーが出てしまいます。

###質問
Linqはさっぱり分からない中手探りで書いたのですが、ここからどうすれば良いのでしょうか？

Answer 1

aaaの型はList(Of String())なので、
GroupBy()メソッドの第2引数のラムダ式の戻り値はString()である必要があります。
匿名型では型が合いません。

また、s.Count(Function(s3) s3(2))の部分ですが、
Count()メソッドに与えるラムダ式は
カウントをする条件を表す式Func<TSource, bool> predicateなので、
この使い方だとエラーになってしまいます。

また、GroupBy()メソッドの第1引数は別にTupleを使わなくても良いんじゃないかな？とか
ちょこちょこ変えてますが、以上を踏まえて

Dim aaa As List(Of String()) 
aaa = resultList.GroupBy(
	Function(s) s(0), 
	Function(s1, s2) New String() {
		s1, 
		s2.Sum(Function(s3) s3(1)).ToString(), 
		s2.Select(Function(s3) s3(2)).Distinct().Count().ToString()
        }).ToList()

みたいに書いてみました。

Comments

[maed]

回答ありがとうございます。
ラムダ式の書き方がなかなか理解できない…。

s1だけどうしてインデックス不要で文字列になっているのでしょうか？

[TAKA_0921]

ラムダ式は、
1. 式形式
2. ステートメント形式
と2パターンありますが、今回はどれも式形式のものを使っています。
詳しくはググってみてください。

GroupBy()メソッドはいくつかOverloadがありますけど、
今回使っているのは
<ExtensionAttribute>
Public Shared Function GroupBy(Of TSource, TKey, TResult) (
source As IEnumerable(Of TSource),
keySelector As Func(Of TSource, TKey),
resultSelector As Func(Of TKey, IEnumerable(Of TSource), TResult)
) As IEnumerable(Of TResult)
ですね。(今回は、TSource : String(), TKey : String, TResult : String())

keySelectorはsourceの各要素(String())に対して、
「何をkeyとして使うか」を指定するものですね。
なので、ラムダ式の引数はString()で、戻り値はStringになっています。

次のresultSelectorは、
「さっきkeySelectorで指定したkey、
およびそのkeyでGroupingした結果(IEnumerable(Of String())から
何を最終的なElementにするか」を指定するものです。
なので、ラムダ式の第1引数はkeyと同じString、第2引数はIEnumerable(Of String())、
戻り値はString()になっています。