テキストファイル読み込みスクリプト

Question

テキスト読み込みスクリプトについて。

あるデータが出力されたテキストファイルがあります。
そのテキストを読み込み、エクセルファイルに出力したいです。

出力されるデータは以下のようなフォーマットです。

文字列１ 文字列２ 開始時間(YYYY/MM/DD) 開始時刻(hh:mm) 終了日付(YYYY/MM/DD) 終了時刻(hh:mm)

各文字の間は半角スペースで区切られています。
出力されたデータを１行づつ読み込み、文字列毎に１セルに吐き出したいです。
以下のような動作ができればいいかなと考えています。
スクリプト実行 → ダイアログが出力し、読み込むテキストファイル選択 → エクセルファイル出力

出力結果は以下のように出力したいと考えています。

VBSがいいです。
どなたか分かる方、回答宜しくお願い致します。

Answer 1

Excelにファイルの中身を貼り付けて、[データ]-[区切り位置]-[カンマやタブ～]-[スペース]-[完了]、ではダメなんですか？

---

追記
乗りかかった船なので作ってみました。
拡張子vbsで保存してから実行してください。
最後にBook1.xlsxを保存しますか？と聞かれるので「はい」で適当なファイル名を指定してください。
ヘッダーの罫線や、列幅などは何もしてませんので、勝手にカスタマイズしてください。

Option Explicit
On Error Resume Next

Dim oFSO
Dim objr
Dim str
Dim oXlsApp
Dim oSheet
Dim row
Dim str2
Dim i
Dim fname

do
	Set oXlsApp = CreateObject("Excel.Application")
	If oXlsApp Is Nothing Then
		WScript.Echo "Excel起動エラー: " & Err.Description
		exit do
	End If

	fname = oXlsApp.GetOpenFilename(",*.*")
	If fname = False Then
		exit do
	End If

	Set oFSO = WScript.CreateObject("Scripting.FileSystemObject")
	If Err.Number <> 0 Then
		WScript.Echo "エラー: " & Err.Description
		exit do
	End If

	Set objr = oFSO.OpenTextFile(fname)
	If Err.Number <> 0 Then
		WScript.Echo "ファイルオープンエラー: " & fname & " " & Err.Description
		exit do
	End If

	'oXlsApp.Application.Visible = true
	oXlsApp.Application.Workbooks.Add()
	Set oSheet = oXlsApp.Worksheets(1)
	oSheet.Cells(2, 2).value = "文字列１"
	oSheet.Cells(2, 3).value = "文字列２"
	oSheet.Cells(2, 4).value = "開始日付"
	oSheet.Cells(2, 5).value = "開始時刻"
	oSheet.Cells(2, 6).value = "終了日付"
	oSheet.Cells(2, 7).value = "終了時刻"

	row = 3
	Do While objr.AtEndOfStream <> True
		str = objr.ReadLine
		str2 = split(str, " ")
		For i = 0 To UBound(str2)
			oSheet.Cells(row, i + 2).value = str2(i)
		Next
		row = row + 1
	Loop
	oXlsApp.Quit
	objr.Close
	exit do
loop

Set oXlsApp = Nothing
Set objr = Nothing
Set oFSO = Nothing

Comments

[Oramun]

ある運用上できないです。
スクリプト実行 → テキスト読み込み → エクセルファイル生成 という動作を望んでいます。
スクリプトのみ触れる状態です。

[ttyp03]

スクリプトを書いてみたので、本文の方に追記しておきました。
お試しください。

[Oramun]

丸投げの質問でしたのに、回答ありがとうございます。
VBScript で作ってほしいとのことでしたが、作ったことがなく苦戦していました。
勉強します。回答ありがとうございました。