ExcelVBAから任意の拡張子でのファイル指定方法

Question

ExcelVBAにて「*.abc」のような拡張子でファイルを出力するプログラムを開発しています。
ファイル名はユーザに指定させたいため、FileDialog(msoFileDialogSaveAs)を試したのですが、いずれも拡張子を指定することができませんでした。

何か方法はありますでしょうか。
以下、検証したコードです。

(1) Filterを指定せず、ファイル名の初期値のみを設定するとファイル名欄に「aaa.abc.xlsx」と表示されてしまう

Sub test1()
    With Application.FileDialog(msoFileDialogSaveAs)
        .InitialFileName = "aaa.abc"
        .Title = "出力ファイルの指定"
        If .Show = True Then
            MsgBox "指定ファイルは" & vbLf & .SelectedItems(1)
        End If
    End With
End Sub

(2) Filterを「.abc」だけにするためClearを行うと、実行時エラー438「オブジェクトは、このプロパティまたはメソッドをサポートしていません」となる(msoFileDialogSaveAsの場合はFilterは変更不可)
※ Addのみとしても同様

Sub test2()
    With Application.FileDialog(msoFileDialogSaveAs)
        .InitialFileName = "aaa.abc"
        With .Filters
            .Clear
            .Add "abcファイル", "*.abc", 1
        End With
        .Title = "出力ファイルの指定"
        If .Show = True Then
            MsgBox "指定ファイルは" & vbLf & .SelectedItems(1)
        End If
    End With
End Sub

(3) Filter条件が指定できるファイルオープンダイアログにすると、存在するファイルしか指定できないため、OKボタン押下時にエラーとなってしまう。(msoFileDialogFilePickerを指定しても同様)

Sub test3()
    With Application.FileDialog(msoFileDialogOpen)
        .InitialFileName = "aaa.abc"
        With .Filters
            .Clear
            .Add "abcファイル", "*.abc", 1
        End With
        .Title = "出力ファイルの指定"
        If .Show = True Then
            MsgBox "指定ファイルは" & vbLf & .SelectedItems(1)
        End If
    End With
End Sub

Comments

[YT0014]

質問文を編集して、拡張子を指定することができなかったコードを、コードマークダウンにて、ご提示ください。

Answer 1

大変失礼しました。GetSaveAsFilenameにて普通に対応できました。

Dim sFileName
sFileName = Application.GetSaveAsFilename("aaa.abc", "abc Files,*.abc", 1)
MsgBox sFileName

Comments

[YT0014]

解決されたようで何よりです。

[KenzTanak]

ありがとうございました!!