vb.netでフォームの大きさが1106より大きくならない

Question

Visual Studio Community 2017のVB.netでフォームを拡大しているのですが、ボタンを押してフォームの高さと幅を拡大していくと、フォームの高さが1106で高さの拡大がストップしてしまいます。フォームの高さの拡大がストップしても横幅はしばらく拡大するのですが3306の大きさで横幅もストップしてしまいます。いくらボタンを押してもフォームの大きさは高さ1106、横幅3306より大きくなりません。横幅は3306もあるのでそんなに大きくする必要性は感じないのですが、高さが1106より大きくならないので困っています。

以下に簡単なソースを載せます。

Public Class Form1
  Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Me.Height *= 1.1
    Me.Width *= 1.1

    TextBox1.Text = Me.Height
    TextBox2.Text = Me.Width
  End Sub
End Class

ちなみに高さが1106より大きくならないと判断しているのは、フォームに設置されたテキストボックスの値が1106より大きくならない事から判断しています。
どのようにすれば高さをもっと大きくできるでしょうか。

Comments

[KOZ6.0]

「フォームのサイズをMaxWindowTrackSize（デスクトップ）以上にする」
https://dobon.net/vb/dotnet/form/maxwindowtracksize.html

[tada_tadaa]

どうもありがとうございました。

Answer 1

KOZ6.0様に教えていただいたリンク先のページを参考に、以下のソース文で高さも横幅も、1106、3306より大きくすることができました。

Public Class Form1

  <System.Runtime.InteropServices.DllImport("user32.dll")>
  Private Shared Function MoveWindow(
    ByVal hWnd As IntPtr,
    ByVal X As Integer,
    ByVal Y As Integer,
    ByVal nWidth As Integer,
    ByVal nHeight As Integer,
    ByVal bRepaint As Boolean) As Boolean
  End Function

  ''' <summary>
  ''' ウィンドウの位置とサイズを変更する
  ''' </summary>
  ''' <param name="rect">変更後のウィンドウの位置とサイズ</param>
  Public Sub SetWindowBounds(ByVal rect As Rectangle)
    'MaximumSizeを大きくしておく
    If Me.MaximumSize.Width < rect.Width Then
      Me.MaximumSize =
            New Size(rect.Width, Me.MaximumSize.Height)
    End If
    If Me.MaximumSize.Height < rect.Height Then
      Me.MaximumSize =
            New Size(Me.MaximumSize.Width, rect.Height)
    End If

    MoveWindow(Me.Handle, rect.X, rect.Y, rect.Width, rect.Height, True)
    Me.UpdateBounds()

    TextBox1.Text = Me.Height
    TextBox2.Text = Me.Width
  End Sub


  'Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
  '  Me.Height *= 1.1
  '  Me.Width *= 1.1

  '  TextBox1.Text = Me.Height
  '  TextBox2.Text = Me.Width
  'End Sub

  Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
    Dim rect1 As Rectangle
    rect1.X = Me.Location.X
    rect1.Y = Me.Location.Y
    rect1.Height = Me.Height * 1.1
    rect1.Width = Me.Width * 1.1

    SetWindowBounds(rect1)
  End Sub
End Class

どうもありがとうございました。

Comments

[tada_tadaa]

https://dobon.net/vb/dotnet/form/maxwindowtracksize.htmlより

” 通常フォームの大きさは、SystemInformation.MaxWindowTrackSizeプロパティで取得できる大きさより大きくすることができません。これは、「フォームの位置と大きさを取得、変更する」や「フォームのサイズを制限する」で説明している通りです。
どうしてもフォームをMaxWindowTrackSize以上の大きさにしたい場合は、Win32 APIを使用する必要があります。”

だそうです。