ローディング画面に時間制限をつける

Question

以下のコードで、ローデイング画面を実装しているのですが、

int x = 0;
int y = 180;
int d = 10;
int dx = 15;
void setup() {
size(900, 900);
frameRate(15);
strokeWeight(20);
}

void draw() {
background(0);
noFill();
stroke(255);
ellipse(width/2,height/2,500,500);
fill(255);
arc(width/2,height/2,500,500,radians(x),radians(y));
x += dx;
y += d;
if(x == (y-10)){
d = 15;
dx = 10;
fill(random(255),random(255),random(255));
}
if(y >= x+350){
dx = 15;
d = 10;
fill(random(255),random(255),random(255));
}
stroke(0);
ellipse(width/2,height/2,150,150);
}
このコードのみだとエラーが出ないで、うまくいくのですが、

var date = new Date();
date.setTime( date.getTime() + ( 30 * 1000 ));
$.cookie( "hoge", "30 seconds", { expires: date });
をつけると、

$.cookie( "hoge", "30 seconds", { expires: date });

ここの部分で"unexpected token”　とエラーが起きてしまいます。
時間制限をつけるには、どのように修正すればいいでしょうか？

Answer 1

ここの部分で"unexpected token”　とエラーが起きてしまいます。

唐突に出てきましたが、何を参考にこの３行を足そうと思ったのでしょうか？
jQuery（JavaScriptライブラリ）かなんかに見えますが、なんにしろProcessing（Java）では使えません。

時間制限をつけるには、どのように修正すればいいでしょうか？

よくあるのは最初にmillis()を取得しておき、今のmillis()と比較でしょうか。
millis() / Reference / Processing.org

second()なんかもありますが、これらは今の時刻の値（0～59）で積算しないので今回の目的には使いづらいので注意です。
Time Date / Reference / Processing.org

int x = 0;
int y = 180;
int d = 10;
int dx = 15;

int ms;

void setup() {
  size(900, 900);
  frameRate(15);
  strokeWeight(20);
  textSize(64);
  textAlign(CENTER, CENTER);

  ms = millis(); // 開始時のmillis取得
}

void draw() {
  background(0);

  // 今のmillis - 開始時のmillis が 3000（ms＝３秒）未満なら loading
  if (millis() - ms < 3 * 1000) {
    loading();
  } else { // なにか本編
    fill(255);
    text("start", 0, 0, width, height);
  }
}

void loading() {
  noFill();
  stroke(255);
  ellipse(width/2, height/2, 500, 500);

  fill(255);
  arc(width/2, height/2, 500, 500, radians(x), radians(y));

  x += dx;
  y += d;
  if (x == (y-10)) {
    d = 15;
    dx = 10;
    fill(random(255), random(255), random(255));
  }
  if (y >= x+350) {
    dx = 15;
    d = 10;
    fill(random(255), random(255), random(255));
  }
  stroke(0);
  ellipse(width/2, height/2, 150, 150);
}

void mouseClicked() {
  // 再度ローディングを出したいなら入れなおす
  ms = millis();
}