パワーポイントのマクロのエラーについて

Question

パワーポイントのマクロを作っていて手詰まりました。

◆作りたいもの
ＰＰＴのテキストボックス6からページ番号を読み取って、それに対応したテキストファイルを読み込んでテキストボックス5へ入れる

Sub Sample2()
    Dim buf As String
    Dim pge As String
    Dim sld As Slide, shp As Shape
    For Each sld In ActivePresentation.Slides
        For Each shp In sld.Shapes
            With shp
                If shp.Name = "テキスト ボックス 6" Then
                    pge = "ppt_" & shp.TextFrame.TextRange.Text & ".txt"
                End If
            End With
        Next shp
        With CreateObject("Scripting.FileSystemObject")
            With .GetFile(pge).OpenAsTextStream
                buf = .ReadAll
                .Close
            End With
        End With
        For Each shp In sld.Shapes
            If shp.Name = "テキスト ボックス 5" Then
                shp.TextFrame.TextRange.Text = buf
            End If
        Next shp
    Next sld
End Sub

With .GetFile(pge).OpenAsTextStream　で「実行時エラー５」になります。

エラー箇所を抜き出してその部分だけ実行するとエラーになりません。
一体何が問題なのかご教示いただけたら幸いです。

Comments

[cx20]

とりあえず、VBAのコードの先頭に
-----------------------------
Option Explicit
-----------------------------
を追加してみて下さい。

[geech]

変数名に間違いがあったところを修正いたしました。
Option Explicit　を追加しましたが、実行時エラー５に変化はありませんでした。

[cx20]

実行時エラーの箇所について、再度確認してみて下さい。
CreateObject("Scripting.FileSystemObject")　
の箇所ではエラーにならないと思います。

[geech]

おっしゃる通り間違えてました。正しくは
With .GetFile(pge).OpenAsTextStream
の部分です。

Answer 1

With CreateObject("Scripting.FileSystemObject")　で「実行時エラー５」になります。

エラー箇所、そこではないと思います。

With CreateObject("Scripting.FileSystemObject")
    With .GetFile(pge).OpenAsTextStream
        buf = .ReadAll
        .Close
    End With
End With

上記のコードですが、With を使わずに書くと以下のようになります。
このコードで実行してみて、どこでエラーになっているのか確認してみて下さい。

Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

Dim file
Set file = fso.GetFile(pge)

Dim stream
Set stream = file.OpenAsTextStream

buf = stream.ReadAll
stream.Close

Comments

[geech]

Set file = fso.GetFile(pge)　の部分で「実行時エラー５」になります。

[cx20]

はい。それが原因です。
GetFile() は 指定されたファイルが存在しない場合にエラーになります。

■ GetFile メソッド (Visual Basic for Applications)
https://docs.microsoft.com/ja-jp/office/vba/language/reference/user-interface-help/getfile-method

「pge」に何が設定されているかデバッグ実行して確認してみて下さい。
変数をウォッチするか、Debug.Print を使うとことで変数の中身がイミディエイトウィンドウに表示されるので確認することが出来るかと思います。
-------------------------------------
Debug.Print "ファイル名：" & pge
-------------------------------------

[geech]

おかげさまで理由が判りました。

最初にマクロを作成した時は全ページ「テキスト ボックス 6」がある状態だったので問題なく動いていた。
しかし、１ページ目にそれが無い状態のページを追加したために、pgeに値が入らなくなりエラーとなった。

ヒントをいただきありがとうございます。
一人で煮詰まっていたので大変助かりました。ありがとうございました。