processing if文動作時にロゴを増やしたい

Question

###前提・実現したいこと

https://www.youtube.com/watch?v=5mGuCdlCcNM&t=24105s
上記動画のようなものを作りたいと考えていて、ロゴが四隅に当たった時(上下の衝突判定が同時に行われた際)にロゴを画面中央に新たに1つ描画したい。

PImage img;          // 画像 画像サイズはwidth262,height120
float x_pos,y_pos;   // 画像の初期位置 

float x_speed = 5;   // 画像の移動速度(横)
float y_speed = 5;   // 画像の移動速度(縦)

float r,g,b;    // 反射時の色変更
int n = 1;        // ロゴの数

float x_direction = random(-1,1);  // 右か左か
float y_direction = random(-1,1);  // 上か下か



void setup(){
  size(1280,720);
  frameRate(60);
  img = loadImage("DVD_logo2.png");
 
  x_pos = width / 2;
  y_pos = height / 2; 
}

void draw(){
  /* 角に当たった時にロゴを一個増やし現在のロゴ数を+1する仕様にする  */  
  
  background(0);            //背景の初期化
  DVD_image();              //DVD_image関数呼び出し
  int s = millis() / 1000;  //経過時間(仮)
  
  x_pos = x_pos + ( x_speed * x_direction );
  y_pos = y_pos + ( y_speed * y_direction );
  
  //壁にぶつかっていたら-1をdirectionに入れる。
  
  if (x_pos > width-(img.width / 2) || x_pos < (img.width / 2)) {
    x_direction *= -1;
    tint(r,g,b);
  }
  if (y_pos > height-(img.height / 2) || y_pos < (img.height / 2)) {
    y_direction *= -1;
    tint(r,g,b);
  }
  
  //角に当たった時の処理　
  
  if (x_pos < (img.width / 2)  && y_pos < (img.height / 2)  ) {                  //左上
    n += 1;
    DVD_image();
  }
  if (x_pos < (img.width / 2)  && y_pos > height - (img.height / 2) ){           //左下
    n += 1;
    DVD_image();
  }
  if (x_pos > width - (img.width / 2)  && y_pos < (img.height / 2)  ){           //右上
    n += 1;
    DVD_image();
  }
  if (x_pos > width - (img.width / 2)  && y_pos > height - (img.height / 2)  ){  //右下
    n += 1;
    DVD_image();
  }
    
  //ロゴのカウント
  textAlign(CENTER);
  textSize(24);
  fill(255,255,255,150);
  text("now DVDlogos : " + n + "", width/2, 25);
  
  //タイマー
  text("now time : " + s + "", width/2, 50);
  
}

void DVD_image(){    //画像の描画及び画像のRGB値 
  imageMode(CENTER);
  image(img, x_pos, y_pos);  
  
  r = random(80,255);
  g = random(80,255);
  b = random(80,255);
}

//角に当たった時の処理　のif文に関数を呼び出す処理を足せばよいものだと思っていたのですが、どうやら違ったようなのでお教えいただけないでしょうか。

Answer 1

ロゴを画面中央に新たに1つ描画したい。

どんどんロゴが増えていくということですよね？
だったらx_pos等の変数も、個数分必要になりますよね？

こういった場合は、クラスとArrayListを使用するとすっきり書けます。
ArrayList of objects / Examples / Processing.org

PImage img;
ArrayList<Logo> logos = new ArrayList<Logo>();


void setup() {
  size(1280, 720);
  //  frameRate(60);
  img = loadImage("https://teratail-v2.storage.googleapis.com/uploads/avatars/u13/132786/KnkDDC5A_thumbnail.jpg");

  // 偶然角に当たるのを待ってらんないのでｗ
  //Logo l = new Logo();
  //l.vx = 4.4225655130783;
  //l.vy = 2.3325767474042;
  //logos.add(l);

  logos.add(new Logo());
}

void draw() {
  background(0);

  int hitCount = 0;
  for (Logo logo : logos) {
    logo.update();
    
    if (logo.hitCorner()) {
      hitCount++;
    }

    logo.draw();
  }

  for (int i = 0; i < hitCount; i++) {
    logos.add(new Logo());
  }


  textAlign(CENTER);
  textSize(24);
  fill(255, 255, 255, 150);
  text("now DVDlogos : " + logos.size(), width / 2, 25);

  int s = millis() / 1000;
  text("now time : " + s, width / 2, 50);
}


class Logo {
  float x, y;
  float vx, vy;
  color c = #FFFFFF;

  Logo() {
    x = width / 2;
    y = height / 2;

    float a = random(TWO_PI);
    vx = cos(a) * 5;
    vy = sin(a) * 5;
  }

  void update() {
    x += vx;
    y += vy;

    if (width - (img.width / 2) < x || x < (img.width / 2)) {
      vx *= -1;
      changeColor();
    }
    if (height - (img.height / 2) < y || y < (img.height / 2)) {
      vy *= -1;
      changeColor();
    }
  }

  boolean hitCorner() {
    if (x < (img.width / 2) && y < (img.height / 2)) {
      return true;
    }
    if (x < (img.width / 2) && height - (img.height / 2) < y) {
      return true;
    }
    if (width - (img.width / 2) < x && y < (img.height / 2)) {
      return true;
    }
    if (width - (img.width / 2) < x && height - (img.height / 2) < y) {
      return true;
    }

    return false;
  }

  void draw() {
    imageMode(CENTER);
    tint(c);
    image(img, x, y);
  }

  void changeColor() {
    colorMode(HSB, 360, 100, 100);
    c = color(random(360), 100, 100);
    colorMode(RGB, 255, 255, 255);
  }
}

処理を書く場所が変わった程度ですが、わからない点があればコメントしてください。