VBA 特定の文字の場合に表の数を合計するマクロを作成したいが、実行時エラーが出てしまっており原因が知りたい

Question

表に記載してある「東京都」と「大阪府」の数字（都道府県名はB列、数字はC列に記載）を足し合わせ、最後に「東京都〇,大阪府〇」（〇はそれぞれの合計値）と表示するマクロを作成したいのですが、「実行時エラー1004　アプリケーション定義またはオブジェクト定義のエラーです」と出てしまいます。
どこが間違えているのか、教えて頂けますでしょうか？
なお、表にはB列に東京都や大阪府が下に値が追加された場合でもコードを修正しなくてよいように作成したいです。そのため、For文のiの範囲を2から最終行の値までに設定しているのですが、このあたりのループ分の書き方も合っているか教えて頂けますと幸いです。

Sub Count()
    
    Dim ws As Worksheet
    
    Set ws = Worksheets("集計")
    
    Dim i As Long
    
    Dim TokyoTotal As Long
    
    Dim OsakaTotl As Long
    
    
    For i = 2 To 1048576
    
        TokyoTotal = WorksheetFunction.SumIf(ws.Cells(1, 2), "東京", ws.Cells(i, 3))
        
        OsakaTotal = WorksheetFunction.SumIf(ws.Cells(1, 2), "大阪", ws.Cells(i, 3))
        
    Next i
    
    
    If ws.Cells(i, 2).Value = "東京" Or ws.Cells(i, 2).Value = "大阪" Then
    
        '何もしない
    Else
    
        MsgBox "正しく入力してください"
    
    End If
    
    
    MsgBox "東京" & TokyoTotal & "," & "大阪" & OsakaTotal
    

End Sub

Answer 1

SumIf は範囲を指定して集計するものなので、ループする必要はないです。

入力してある最終行の取得法は検索すればすぐ見つかります。

Sub Count()

    Dim ws As Worksheet
    Set ws = Worksheets("集計")

    Dim lastRow As Long
    lastRow = ws.Cells(ws.Rows.Count, 2).End(xlUp).Row '最終行の取得

    Dim TokyoTotal As Long
    Dim OsakaTotal As Long

    With ws.Cells(1, 2).Resize(lastRow, 1)
        TokyoTotal = WorksheetFunction.SumIf(.Cells, "東京", .Offset(, 1))
        OsakaTotal = WorksheetFunction.SumIf(.Cells, "大阪", .Offset(, 1))
    End With


    MsgBox "東京" & TokyoTotal & "," & "大阪" & OsakaTotal

End Sub