VBAメール作成マクロのコード どこに間違いがあるのかが分からない

Question

VBAにて、outlookのメールを自動で作成するマクロを作成しているのですが、
メールが作成されないため、どこか間違いがあるのか、教えて頂けますでしょうか？
なお、実行時は特に何もエラーは表示されないですが、メールが作成されない状態となっています。
（参照シート名や参照セルは合っております。）

Sub sendStartMail()

    On Error GoTo Error1
    
    Dim outlookObj As Outlook.Application

    Dim outlookMail As Outlook.MailItem
    
    Dim ws As Worksheet
    
    
    Set outlookObj = CreateObject("Outlook.Application")
    
    Set outlookMail = outlookObj.CreateItem(olMailItem)
    
    Set ws = Worksheets("メール作成")
    
    
    With outlookMail
        .To = ws.Range("C2").Value
        .Cc = ws.Range("C3").Value
        .Subject = ws.Range("C4").Value
        .Body = ws.Range("C5").Value
    End With
    
    Exit Sub
    
Error1:
    
    MsgBox Err.Description
    

End Sub

Answer 1

保存していないからでは？

コードを見た限りでは、メールを仮に作成して、保存せずに捨てているように見えます。

根拠は、MailItemにSave()メソッドがあることです。
MailItem オブジェクト (Outlook)
MailItem.Save()

一般的なサンプルコードでは、Send()での送信が目的となり、その処理内での保存が実行されるため、明示されていないものと思われます。

なお、実際の挙動は未検証であることをご了承ください。

Answer 2

https://docs.microsoft.com/ja-JP/office/vba/api/Outlook.MailItem.Display
などを参考にして
outlookMail.Display 'みたいにアイテム作成後、.Display で表示してみては？

    Set outlookObj = CreateObject("Outlook.Application")

    Set outlookMail = outlookObj.CreateItem(olMailItem)
    outlookMail.Display  '※ここに追加 ↑で作成後、.Display で表示してみては？

    Set ws = Worksheets("メール作成")