カウントした行数の内容をMsgBoxに表示したい（VBA）

Question

前提・実現したいこと

条件に一致したカウントした【セルの値】と【該当の行数】をMsgBoxに表示させたいです。

現状は、カウントした件数のみは自身で表示させる事ができました。
可能であれば下記のコードに追記（修正）する部分をご教示いただけますと幸いです。

◆完成イメージ
作成が完了しました。

回答数：2

15行目：123456
30行目：789012

該当のソースコード

Sub 会員番号が含まれていない回答数のカウント()

    Dim x As Long
    Dim i As Long
    Dim count As Long
    count = 0
    
    With Sheets("rawdata")
        x = .UsedRange.Cells(.UsedRange.count).Row
        If clear_flag = True Then
            Sheets("rawdata").Range("B2:B" & x).Interior.Pattern = xlNone
        End If
        For i = x To 2 Step -1
            If Sheets("●●/●●実施").Range("A:A").Find(What:=.Cells(i, 2), LookAt:=xlWhole) Is Nothing Then
                count = count + 1
            End If
        Next i
    End With

   '結果の表示
    MsgBox "作成が完了しました。" & vbCrLf & vbCrLf & "回答数：" & count

End Sub

▼追記

Sub 回答者の重複をカウント()

    Dim sh1 As Worksheet
    Dim maxrow As Long
    Dim wrow As Long
    Dim dicT As Object
    Dim key As String
    Dim count1 As Long
    count1 = 0

    Set dicT = CreateObject("Scripting.Dictionary")
    Set sh1 = Worksheets("rawdata")
    maxrow = sh1.Cells(Rows.count, "B").End(xlUp).Row
    
    For wrow = 2 To maxrow
        key = sh1.Cells(wrow, "B").Value
        If dicT.exists(key) = False Then
            dicT(key) = True
        Else
            count1 = count1 + 1
        End If
    Next

   '結果の表示
    MsgBox "重複数：" & count1

End Sub

Answer 1

これだとどうでしょう

    Dim tempStr As String

    ---略---

    If Sheets("●●/●●実施").Range("A:A").Find(What:=.Cells(i, 2), LookAt:=xlWhole) Is Nothing Then
        Count = Count + 1
        tempStr = vbCrLf & i & "行目:" & Cells(i, "A").Value & tempStr
    End If

    ---略---

    MsgBox "作成が完了しました。" & vbCrLf & vbCrLf & "回答数：" & Count & vbCrLf & tempStr

追記用

Sub 回答者の重複をカウント()

    Dim sh1 As Worksheet
    Dim maxrow As Long
    Dim wrow As Long
    Dim dicT As Object
    Dim key As String

    Dim tempStr As String
    Dim number As Variant

    Set dicT = CreateObject("Scripting.Dictionary")
    
    Set sh1 = Worksheets("rawdata")
    maxrow = sh1.Cells(Rows.count, "B").End(xlUp).Row

    For wrow = 2 To maxrow
        key = sh1.Cells(wrow, "B").Value
        
        If dicT.Exists(key) = False Then
            dicT.Add key, 1
        Else
            dicT(key) = dicT(key) + 1
        End If
    Next

    For Each number In dicT.keys
        If dicT.Item(number) > 1 Then
            tempStr = tempStr & number & "：" & dicT.Item(number) & vbCrLf
        End If
    Next number

    MsgBox tempStr

End Sub

Comments

[退会済みユーザー]

ご回答ありがとうございます。
いただいた内容で問題なく対応できました。

大変恐縮ですが、質問に追記したコードでも対応しようと試みました。
その際に正常に表示されず、1行目の項目が表示されてしまいました。
もしご教示いただけるようでしたらお願いできますでしょうか。

[bebebe_]

すみません、求めている内容が把握できていないです。
追記のコードのほうは問題ないように見えるので追記のコードに会員番号が含まれていない回答数のカウントも表示するようにしたいということですか？

[退会済みユーザー]

先日ご対応いただいた内容は
●●/●●実施 と rawdata を照合し、rawdataのB列に含まれているが●●/●●実施のA列には含まれていない場合に該当の会員番号を表示する。という事です。

今回求めているのは
rawdataのB列で重複している会員番号があった場合、表示したい。という意味になります。

[bebebe_]

追記の分も回答のほうに追加してみました。
求めている結果になっていますか？

[退会済みユーザー]

なっております。
大変助かりました。ありがとうございます。