アクティブではない状態で指定したシートの行数をカウントしたい（VBA）

Question

前提・実現したいこと

複数ファイルから指定したシートのみを取り込み保存するVBAを実行した際に
アクティブではない状態のrawdataシートA列・B列の　空白ではない　行数をカウントしたいです。

発生している問題・エラーメッセージ

エラーは発生していませんが、B列のカウントが出来ずに困っています。
（アクティブシートだとカウントはできますので、B列カウントのシート指定が作動してないように思いますが自身で原因が特定できません。）

該当のソースコード

Sub 各列のカウント()

    'A列カウント
    Dim last As Long
    Dim i As Long
    Dim count As Long
    Dim minrow As Long
    Dim sh_org As Worksheet
    Set sh_org = Sheets("rawdata")
    
    minrow = 2
    last = sh_org.Range("A5000").End(xlUp).Row'最終行は固定で5000

    If last >= minrow Then
        count = 1
        For i = last - 1 To minrow Step -1
            If Range("A" & i) <> "" Then
              count = count + 1
            End If
        Next
    End If
    
    'B列カウント
    Dim last1 As Long
    Dim count1 As Long
   
    last1 = sh_org.Range("B5000").End(xlUp).Row'最終行は固定で5000

    If last1 >= minrow Then
        count1 = 1
        For i = last1 - 1 To minrow Step -1
            If Range("B" & i) <> "" Then
              count1 = count1 + 1
            End If
        Next
    End If

    '結果の表示
    MsgBox "A列：" & count & vbCrLf & "B列：" & count - count1

End Sub

Answer 1

If文のところで、シートを指定していないのが原因ですね。（指定しないとアクティブシートが対象になる）

'           If Range("B" & i) <> "" Then
            If sh_org.Range("B" & i) <> "" Then

別案

空白以外のセルのカウントなら、CountA関数を使うと簡単です。

    minrow = 2
    last = sh_org.Range("A5000").End(xlUp).Row '最終行は固定で5000
    If last >= minrow Then
       count = WorksheetFunction.CountA(sh_org.Range("A" & minrow & ":A" & last - 1))
    End If

Comments

[退会済みユーザー]

ご回答ありがとうございます。
ご指摘いただいた点を修正し、問題なくカウントできました。

別案、非常に勉強になります。
今後も質問する事があるかと思いますので、ご都合よろしい場合はまたお願いいたします。