フォームの一部をキャプチャする

Question

VB.NET2010でフォームの一部をキャプチャするプログラムを作りましたが、入力したデータやラベルの文字が表示できません。

 Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
    'コントロールの外観を描画するBitmapの作成
    Dim bmp1 As New Bitmap(Me.Width, Me.Height)
    Me.DrawToBitmap(bmp1, New Rectangle(0, 0, Me.Width, Me.Height))

    '画像を切り抜く
    Dim bmpcut As New Rectangle(709, 185, 435, 366)
    Dim bmp2 As Bitmap = bmp1.Clone(bmpcut, bmp1.PixelFormat)
    '画像の保存
    bmp2.Save("C:\Users\Public\test.jpg")
    '後始末
    bmp1.Dispose()
    bmp2.Dispose()
End Sub

上の画像を期待したのですが、取得できたのは下の画像でした。
VB.NETでは無理なのでしょうか？
また、他の方法があるのでしょうか？
何方か力を貸してください。お願いします。

環境
Windows10
Microsoft Visual Studio 2010

Answer 1

DrawToBitmap は WM_PRINT メッセージを送って描画するので、
コントロールの実装によっては、表示と異なってしまう可能性があります。

表示どおりにキャプチャするなら、以下のような Function を作成して

Imports System.Runtime.InteropServices

Class FormUtil

    Private Const SRCCOPY As Integer = &HCC0020

    <DllImport("gdi32.dll")>
    Private Shared Function BitBlt(ByVal hdc As IntPtr,
                            ByVal nXDest As Integer,
                            ByVal nYDest As Integer,
                            ByVal nWidth As Integer,
                            ByVal nHeight As Integer,
                            ByVal hdcSrc As IntPtr,
                            ByVal nXSrc As Integer,
                            ByVal nYSrc As Integer,
                            ByVal dwRop As Integer) As Boolean
    End Function

    Public Shared Function CreateClientBitmap(ByVal con As Control, ByVal rect As Rectangle) As Bitmap
        Dim bmp As New Bitmap(rect.Width, rect.Height)
        Using bmpGraphics As Graphics = Graphics.FromImage(bmp),
              formGraphics As Graphics = Graphics.FromHwnd(con.Handle)
            Dim bmpDC As IntPtr = bmpGraphics.GetHdc()
            Dim formDC As IntPtr = formGraphics.GetHdc()
            BitBlt(bmpDC, 0, 0, rect.Width, rect.Height, formDC, rect.Left, rect.Top, SRCCOPY)
            bmpGraphics.ReleaseHdc()
            formGraphics.ReleaseHdc()
        End Using
        Return bmp
    End Function

End Class

こんな感じで使います。

Private Sub Button3_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button3.Click
    Using bmp As Bitmap = FormUtil.CreateClientBitmap(Me,
                                           New Rectangle(709, 185, 435, 366))
        bmp.Save("C:\Users\Public\test.jpg", Imaging.ImageFormat.Jpeg)
    End Using
End Sub

Comments

[sake]

ありがとうございました。
丁寧なモジュールまで作成していただき、大変助かりました。