マウス操作で動作を開始して、自動で止まる（何秒で止まる、何回壁に当たったら止まるなどなど）というコード書くにはどこに何を書けばいいでしょうか。

Question

コード```int x=(int)random(640);
int y=(int)random(480);
int xdirection=1;
int ydirection=1;
int x2=(int)random(640);
int y2=(int)random(480);
int xdirection2=1;
int ydirection2=1;

int r1=(int)random(155)+100;
int g1=(int)random(155)+100;
int b1=(int)random(155)+100;
int r2=(int)random(155)+100;
int g2=(int)random(155)+100;
int b2=(int)random(155)+100;

void setup() {
size(800, 800);
colorMode(RGB, 255);
background(255, 255, 255);
}
void mousePressed(){}
void draw() {
fill(255, 255, 255, 60);
noStroke();
rect(0, 0, width, height);

stroke(0, 0, 0);
fill(r1, g1, b1);
ellipse(x, y, 50, 50);
frameRate(10);
fill(r2, g2, b2);
ellipse(x2, y2, 20, 20);
frameRate(13);
if (x>width) {
xdirection=-1;
r1=(int)random(155)+100;
g1=(int)random(155)+100;
b1=(int)random(155)+100;
}
if (x2>width) {
xdirection2=-1;
r2=(int)random(155)+100;
g2=(int)random(155)+100;
b2=(int)random(155)+100;
}
if (x<0) {
xdirection=1;
r1=(int)random(155)+100;
g1=(int)random(155)+100;
b1=(int)random(155)+100;
}
if (x2<0) {
xdirection2=1;
r2=(int)random(155)+100;
g2=(int)random(155)+100;
b2=(int)random(155)+100;
}
if (y>height) {
ydirection=-1;
r1=(int)random(155)+100;
g1=(int)random(155)+100;
b1=(int)random(155)+100;
}
if (y2>height) {
ydirection2=-1;
r2=(int)random(155)+100;
g2=(int)random(155)+100;
b2=(int)random(155)+100;
}
if (y<0) {
ydirection=1;
r1=(int)random(155)+100;
g1=(int)random(155)+100;
b1=(int)random(155)+100;
}
if (y2<0) {
ydirection2=1;
r2=(int)random(155)+100;
g2=(int)random(155)+100;
b2=(int)random(155)+100;
}

x=x+(xdirection*10);
y=y+ydirection*10;
x2=x2+xdirection2*10;
y2=y2+ydirection2*10;
}

```初心者です。課題でProcessingでコードを書いているのですが、マウス操作で動作を開始して、自動で止まる（何秒で止まる、何回壁に当たったら止まるなどなど）というコード書くにはどこに何を書けばいいでしょうか。困っています。


よろしくお願いします。

Comments

[y_waiwai]

このままではコードが読みづらいので、質問を編集し、<code>ボタンを押し、出てくる’’’の枠の中にコードを貼り付けてください

[1T2R3M4]

先生に確認すればいいのでは。

[dodox86]

> どこに何を書けばいいでしょうか。困っています。

この理解状況ではすべて動く完動品のコードを回答する以外、無いです。そしてそれは丸投げです。初心者だからとか関係ありません。

[yuunosu]

https://teratail.com/users/y_waiwaiさん　変更しました。これでどうでしょうか？

[thkana]

https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q11252348861
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q12252352332
これはお友達かな? https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q11252342121

https://teratail.com/help#posted-otherservice というこの掲示板のルールがあります。
「やむを得ず複数のサイトに質問を投稿された場合は、質問内容にマルチポストをする理由を書き、他のサイトの投稿へのリンクを貼ってください。また、解決した際には必ずteratail及びすべての投稿に解決した旨と、どのように解決したかを記載してください。」の処置をしてください。

Answer 1

マウス操作で動作を開始して、自動で止まる

開始・停止をどう書くか悩んでいるということでしょうか？

変数やif文がわかっていれば、さほど難しくはないのですが。。。
何か変数を用意して、例えば0だったらx・yを増やさない（減らさない）とするとか（フラグにはbooleanがいいですが）

あるいは今回の目的なら、loop()・noLoop()でもよさそうです。
loop() / Reference / Processing.org
noLoop() / Reference / Processing.org

何秒で止まる

millis()でプログラム開始時からのミリ秒が取れます。
millis() / Reference / Processing.org

動かし始めた時のミリ秒を取っておいて、今のミリ秒と比較すればいいでしょう。

何回壁に当たったら止まる

if文の中身はいいとして、条件部分も書けませんか？（だったらこのプログラムをどう書いたんでしょう？？）
何一つわかってないということになってしまいますよ（先生もガッカリです）

わからないことは別に恥ずかしいことではありません（誰でも最初はわからなかったのですから）
しかし「わからない」を言い訳にして何もやらないんでは、「この人はやる気がないんだな」と思われてしまいます。

エラーになってもいいから「多分こんな感じ」というのを、（コードで）見せてもらわないと他人には伝わりません。

---

• ボールはひとつに
  無駄に長くなるので^^;
• xdirection（方向）の代わりに、vx（速度）に変更
  今後４５度以外の角度にも対応できる。
• 符号の反転は-1を掛ける
  if文２つをまとめられるようになった。
• HSBモードを使用
  色相だけいじればよくなるので変数を減らせる。

colorMode() / Reference / Processing.org
Hue / Examples / Processing.org

int x;
int y;
int vx = 10;
int vy = 10;
int hue = (int)random(255);

int start;

void setup() {
  size(700, 500);
  colorMode(HSB);
  background(255);

  x = (int)random(width);
  y = (int)random(height);

  noLoop();
}

void mousePressed() {
  start = millis();
  loop();
}

void draw() {
  fill(255, 60);
  noStroke();
  rect(0, 0, width, height);

  stroke(0);
  fill(hue, 128, 255);
  circle(x, y, 50);

  if (x < 0 || width < x) {
    vx *= -1;
    hue = (int)random(255);
  }
  if (y < 0 || height < y) {
    vy *= -1;
    hue = (int)random(255);
  }

  x += vx;
  y += vy;


  if (5 * 1000 <= millis() - start) {
    println("５秒経ったよ");
    noLoop();
  }
  //if (10 <= なにか) {
  //  println("１０回跳ね返ったよ");
  //  noLoop();
  //}
}

１０回跳ね返ったら止まるようにしてみてください。

Comments

[yuunosu]

ありがとうございます。