エクセルVBAのテキストボックスの形式をチェックする

Question

前提・実現したいこと

化学物質を特定するものとしてCAS番号というものがあり、世界中で広く使われています。
その形式は　桁数不明の数字（大体2～7桁）－　2桁の数字　－　1桁の数字　となります。
例）鉄：7439-89-6、炭酸カルシウム：471-34-1　などです。

ユーザーフォームにこのCAS番号を入力を出来るテキストボックスを作成し、正しいCAS番号が入力されていないとメッセージが出るようにしたく、以下のようなコードを作成しました。

以下のコードで問題なく動きますが、コードが三段階になるので、一段階で出来る方法が有るでしょうか。

一段階目：ハイフンの数が2でなければ警告
二段階目：一つ目のハイフンの前の文字が数字でなければ警告
三段階目：一つ目のハイフンより後の文字の形式が##-#でなければ警告

###問題点
一つ目のハイフンより前の文字の桁数が不明の為、一段階で出来ません。

該当のソースコード

Private Sub TextBox1_AfterUpdate()

    Dim TopNum As String, NextNum As String
    
    'ハイフンの数が2でなければ警告
    If CountHyphen(Me.TextBox1) <> 2 Then
        MsgBox "正しいCas番号を記入してください", vbCritical
        Exit Sub
    End If
    
    TopNum = Left(Me.TextBox1, InStr(Me.TextBox1, "-") - 1) '一つ目のハイフンより前の文字
    NextNum = Mid(Me.TextBox1, InStr(Me.TextBox1, "-") + 1) '一つ目のハイフンより後の文字
    
    '一つ目のハイフンの前の文字が数値でなければ警告
    If IsNumeric(TopNum) = False Then
        MsgBox "正しいCas番号を記入してください", vbCritical
        Exit Sub
    End If
    
    '一つ目のハイフンの後の文字の形式が##-#でなければ警告
    If Not (NextNum Like "##-#") Then
        MsgBox "正しいCas番号を記入してください", vbCritical
        Exit Sub
    End If
    
End Sub

Function CountHyphen(ByVal MyStr As String) As Long

    'ハイフンの数を数える関数
    Dim i As Long
    For i = 1 To Len(MyStr)
        If Mid(MyStr, i, 1) = "-" Then
            CountHyphen = CountHyphen + 1
        End If
    Next i

End Function

試したこと

ネットで検索したのですが、いい方法が検索できませんでした。
いい方法が有れば知りたく。よろしくお願いします。

Answer 1

下記のような正規表現を利用するのはどうでしょうか。

Private Sub CommandButton1_Click()
    Dim re As Object
    Set re = CreateObject("VBScript.RegExp")
    re.Pattern = "^\d+-\d{2}-\d{1}$"
    If re.test(TextBox1.Text) Then
        MsgBox "OK", vbOKOnly
    Else
        MsgBox "NG", vbOKOnly
    End If
End Sub

なお、厳密には、CAS登録番号の最後の1桁はチェックディジットになっているようです。

Comments

[Ponsuke1108]

回答ありがとうございます。正規表現、勉強になりました。またチェックディジットについても知りませんでしたので大変勉強になりました。

Answer 2

とりあえずSplit関数について調べると、幸せになると思います。

---

このユーザーフォームだけでなく、他で使うこともできるように関数化しておくと便利でしょう。

標準モジュール

Public Function IsCAS(s As String) As Boolean
    Dim a As Variant
    a = Split(s, "-", 2)
    If UBound(a) = 1 Then
        If (Not a(0) Like "*[!0-9]*") And a(1) Like "##-#" Then IsCAS = True
    End If
End Function

ユーザーフォーム

Private Sub TextBox1_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
    If IsCAS(Me.TextBox1.Text) Then
        Cancel = True
        MsgBox "正しいCas番号を記入してください"
    End If
End Function

Comments

[Ponsuke1108]

回答ありがとうございました。いつも勉強になります。LIKE演算子をしっかり勉強します。おすすめのサイトが有れば教えてください。