配列同士の要素の差分を比較して出力したい

Question

特定のフォルダに含まれるPDFファイルの名称と特定のcsvの特定の列に含まれる値で差分を比較して出力したいと考えております。

下記のコードでhere-1とhere-2でそれぞれの値が取得できるところまでは到達することができました。下記の例で行くとpdfの名称には5が欠けていて、csvの特定の列にある文字列については、1と2が欠けているという情報を取得したいということになります。

ここで、通常の機械言語であれば、配列の差分を出力するメソッドや、それがない言語でもそれぞれの配列を二重にループさせて総当たりに有無を確認できるのですが、VBAに慣れておらず、配列をで検索するとstartとend値を宣言で指定する等、他の機械言語とは仕様が異なっており、配列の個数が拾ってみるまで分からない今回のケースではどのようにアプローチするべきなのかアドバイスを頂きたく、お願いいたします。

Sub get_diff()
 Dim current_path, src_path As String
 Dim pdf_path_dir As String
 
 current_path = ThisWorkbook.Path
 src_path = current_path & "\src\"
 
 pdf_path_dir = Dir(src_path & "*.pdf")
 
    Do While Len(pdf_path_dir) > 0
        Debug.Print Replace(pdf_path_dir, ".pdf", "")'here-1 // resultは1,2,3,4
        pdf_path_dir = Dir()
    Loop
 
 Dim csv_name As String
 Dim csv_wb As Workbook
 Dim csv_ws As Worksheet
 Dim get_col As Integer
 Dim i As Long
 Set csv_wb = ActiveWorkbook
 Set csv_ws = ActiveSheet
 
 csv_name = Dir(src_path & "*csv")
 Workbooks.Open Filename:=src_path & csv_name
 
 get_col = csv_ws.Range("1:1").Find("特定の値").Column
 i = 2
 Do While csv_ws.Cells(i, get_col) <> ""
  Debug.Print Replace(csv_ws.Cells(i, get_col).Value, " ", "")'here-2　// resultは3,4,5
  i = i + 1
 Loop
 
 
End Sub

Answer 1

連想配列(Dictionary)を使えばどうでしょう。

Dictionary（ディクショナリー）連想配列の使い方について｜VBA技術解説

---

コード例

Sub get_diff()
    Dim pdf_dic As New Dictionary 'Microsoft Scripting Runtime参照設定必須
    Dim csv_dic As New Dictionary
    
    Dim src_path As String
    Dim pdf_path_dir As String
    src_path = ThisWorkbook.Path & "\src\"
    pdf_path_dir = Dir(src_path & "*.pdf")
    
    Do While Len(pdf_path_dir) > 0
        pdf_dic(Replace(pdf_path_dir, ".pdf", "")) = ""
        pdf_path_dir = Dir()
    Loop

    Dim csv_name As String
    Dim csv_ws As Worksheet
    Dim get_col As Integer
    Dim i As Long

    csv_name = Dir(src_path & "*.csv")
    Set csv_ws = Workbooks.Open(Filename:=src_path & csv_name).Sheets(1)

    get_col = csv_ws.Range("1:1").Find("特定の値").Column
    i = 2
    Do While csv_ws.Cells(i, get_col) <> ""
        Dim buf As String
        buf = Replace(csv_ws.Cells(i, get_col).Value, " ", "")
        If pdf_dic.Exists(buf) Then
            pdf_dic.Remove buf 'csvと重複したら削除
        Else
            csv_dic(buf) = "" 'pdfにない値を格納
        End If
        i = i + 1
    Loop

    Debug.Print "PDFのみに存在: " & Join(pdf_dic.Keys)
    Debug.Print "CSVのみに存在: " & Join(csv_dic.Keys)

End Sub

Comments

[SugiuraY]

コメントありがとうございます。
ReDim array(Len(hoge))のような形で、後から個数を指定することで配列を作ることができました。
一方で、配列を2つ作ることができたのですが、片方の配列の要素がもう片方の配列に存在しないこととその存在しない要素を探すことがvbaのメソッドで見つけることができません。
hoge = [1,2,3] piyo = [2,3,4]のような配列まではできているのですが、
for eachで総当たりで重ねて検証しても例えばpiyoに1が存在しないことをどのように確認したらよいかアドバイスを頂けませんでしょうか？

[hatena19]

それは動的配列ですね。動的配列で、できないこともないですが、連想配列を使った方がはるかに楽です。
回答のリンク先を読んでみてください。

[hatena19]

回答にコード例を追記しましたので、ご参考に。

[SugiuraY]

ありがとうございます。Dictionary型を使うとこんなに楽に実装できるのですが、とても勉強になりました。コードについてもご教示いただきありがとうございます。