fortranで，列の数が分からない表のデータを読み込みたい

Question

前提・実現したいこと

fortran で，表の形のデータを読みこんで配列に格納し，処理するプログラムを作っており，
読み取りの際に，行の数は固定で列の数が未知のデータに対応できるようにしたいと思っています。

入力データの表は以下のような感じになっており，(〇は数値)

見出し1 見出し2 見出し3　・・・・・・・・大体30列前後，未知
〇　　　〇　　　 〇 　 ・　　・　　・　　　
〇　　　〇　　　 〇 　　・　　・　　・　
〇　　　〇　　　 〇 　　・　　・　　・　
・　　　・　　　 ・
・　　　・　　　 ・　　
・　　　・　　　 ・
約20万行，固定

発生している問題・エラーメッセージ

自分としては，ソースコードのように見出しと数値を別々に読みこんだ上で，
一つ一つの列をまとめて読み込みながら列の方向にdoループを回していき
iostatが負を示した時点を表の終わりと見なすようにしたいと思っていました。

ただそのやり方では，結果を確認しても，並びが全く原型をとどめておらず，うまく読みこめていない様です。

allocateを使う事も考えましたが，readする前に行列の大きさを把握できなければならず，その方法が思いつきませんでした。

他に何か良い方法はないでしょうか。
よろしくお願いします。

(ちなみに，可能であれば行，列ともに未知でも可能な方法があれば,
合わせて教えて頂けると助かります。)

該当のソースコード(抜粋)

filename=a(p)
       open(10, file=trim(filename))
       write(*,*), trim(filename)
       
       l=0
       do j=1, 100
         !各項目の見出しの読み込み
         read(10,*,iostat=ios) (head(i,j), i=1,1)
         if(ios .lt. 0) exit
         l=l+1       
       end do
       write(*,*) l
       
             
       m=0
       do j= 1, 100
         !データの読み込み
　　　　　read(10,*,iostat=ios) (pix(i,j), i=1,size) 
         if(ios .lt. 0) exit
         m=m+1
       end do
      write(*,*) m 

該当のソースコード2

program test
    implicit none
    real, allocatable :: pix(:, :)
    integer :: nor, noc, nod, ip , i, j
    character(len = 10), allocatable :: degree(:)
    character(len = 99) :: buff
    
    write(*,*) "input the angle you process"
    read(*,*) buff
    write(*,*)"length of the input data", len(buff)
    
    open(10, file= "angle_list.txt")
    write(10,*) buff
    
    nod=0
    ip=0
    do while (ip < len(buff))
       ip = ip + 1
       if (buff(ip:ip) == ' ') cycle
       nod = nod + 1
       do while (buff(ip:ip) /= ' ')
         ip = ip + 1
       end do
    end do
    
     !roop: do while(ip < len(buff))
    !  ip= ip + 1
    !    if( buff(ip:ip)==" " ) then
    !     nod= nod + 1
    !      if( buff(ip+1:ip+1)==" " ) exit roop
    !    end if 
    !end do roop
       
    write(*,*)"variety of angle", nod
    
    allocate(degree(nod))
    
    close(10)
    
    open(10, file= "angle_list.txt")
    read(10,*) (degree(i),i=1, nod)
    
    write(*,*) "degree data" 
    do i=1, nod
    write(*,*) degree(i)
    end do
    
    deallocate(degree) 
    
end program

Comments

[curehoney]

列数は行ごとに違うんですかね？それとも１ファイル内では一定で、矩形に納まります？

[epsilon]

はい，列数は全部の行で同じになります

Answer 1

縦横のデータ数を知ったうえで、そのサイズに allocate してデータを一気に読み込むのが基本ですので、それに従うことにします。

ここでは、入力データの見出し語が空白区切りでデータと同数、数値データは矩形で、ファイル末尾にフッターのようなものが無いと仮定します。

まず見出し語行を文字列バッファーに読み込んで、内部ファイルとして空白区切りを探して見出し語数を数えます。

次にデータ行数を知るため、ファイル末まで空読みして行数を数えます。

これでデータ数の縦横が分かったので、配列を割り付け、ファイルをリワインドして先頭に巻き戻し、配列一括読み取りします。

注意点：Fortran は column first なので、一気読みすると配列を転置した形になります。

program test
    implicit none
    real, allocatable :: pix(:, :)
    integer :: nor, noc, ip
    character(len = 10), allocatable :: head(:)
    character(len = 999) :: buff
    open(10, file = 'test.dat')

    read(10, '(a)') buff

    noc = 0
    ip = 0
    do while (ip < len(buff))
       ip = ip + 1
       if (buff(ip:ip) == ' ') cycle
       noc = noc + 1
       do while (buff(ip:ip) /= ' ')
         ip = ip + 1
       end do
    end do
    print *, 'no. of columns', noc


    nor = 0
    do
      read(10, *, end = 99 )
      nor = nor + 1
    end do
99 print *, 'no. of rows', nor


   allocate(head(noc))
   allocate(pix(noc, nor)) ! column first なので転置で一気読み込みします

   rewind(10)
   read(10, *) head
   read(10, *) pix


   block
       character(len = 20) :: fmt
       print *, head
       write(fmt,'(a, i0, a)') '(', noc, 'f10.6)'
       print fmt, pix
   end block
end program test

aaaa bb c ddddd eeeee
1.0 2.0 3.0 4.0 5.0
0.999 0.888 0.777 0.666 0.555
1 2 3 4 5

・結果

 no. of columns           5
 no. of rows           3
 aaaa      bb        c         ddddd     eeeee
  1.000000  2.000000  3.000000  4.000000  5.000000
  0.999000  0.888000  0.777000  0.666000  0.555000
  1.000000  2.000000  3.000000  4.000000  5.000000

Comments

[epsilon]

ありがとうございます。

[epsilon]

すみません，追加でお聞きしたいのですが，
回答のコードの10行目以降の，列の数を数える処理をそのまま利用して，
画面に
45 60 75
のように入力した角度のデータの数を把握し，角度を配列に格納したいと思い，
質問欄のソースコード2のように行ったのですが，

以下の出力結果のように，データを3つ入力した場合でも
先頭の1つしか読み取れていないようです
色々試したのですが，何か解決方法などあればよろしくお願いします．

input the angle you process
45 60 75　←※画面入力
length of the input data 99
variety of angle 1
degree data
45

[curehoney]

質問に気づかなくてすみません。
今のままですと、変数が１個しかないので最初の一つしか読み込まれません。
全体をループするか、変数を配列に直して入力をため込んでおいて、ループすることが考えられます。
簡単な例で試してみるのが良いかと思います。

[epsilon]

返信が遅れ申し訳ありません。
ありがとうございます。