Findメソッド使用して数字を含むセルの検索

Question

前提・実現したいこと

VBA（ボタン）を使って何らかの数字が入っているセル（文字列の中に入っている場合も含む）
を順番に選択したい。（マクロを登録しているボタンを押すと数字が含まれるセルを順番に選択していくイメージ）

発生している問題・エラーメッセージ

条件検索が1つしかできない

該当のソースコード

Cells.Find(What:="1", After:=ActiveCell, LookIn:=xlValues, LookAt:= _
        xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , MatchByte:=False, SearchFormat:=False).Activate
    

試したこと

これでは1を含むセルを列順に検索できるが、0,2,3,4,5,6,7,8,9を検索できない。
FindNextを使用しても上手く動かない。

Answer 1

「順番に選択したい。」というのが具体的にどのようなことなのか、よく分からないので、
とりあえず、数字が入っている（数字が含まれている）セルの背景色を赤にするコードです。

Sub Sample()
    Dim c As Range
    For Each c In ActiveSheet.UsedRange
        If Application.Evaluate("COUNT(FIND({0,1,2,3,4,5,6,7,8,9}," & _
                                 c.Address & "))") > 0 Then
            c.Interior.ColorIndex = 3
        End If
    Next
End Sub

---

コメントより

シート上にコマンドボタンが配置されていて、それをクリックすると最初の数字を含むセルを選択(Activate)。

次に、コマンドボタンをクリックすると次の数字を含むセルを選択。
・・・

上記の仕様でのコード例
シート上にActiveXのコマンドボタンを配置。
シートモジュールに下記のコードを記述する。

Option Explicit
Private idx As Long

Private Sub CommandButton1_Click()
    Dim i As Long
    With ActiveSheet.UsedRange
        If idx = 0 Or idx >= .Count Then idx = 1
        For i = idx To .Count
            If Application.Evaluate("COUNT(FIND({0,1,2,3,4,5,6,7,8,9}," & .Item(i).Address & "))") > 0 Then
                .Item(i).Activate                
                Exit For
            End If
        Next
        idx = i + 1
    End With
End Sub

コマンドボタンをクリックするたびに数値を含むセルを順番に選択していきます。
最後までいったら、もう一度クリックすると最初からまた選択していきます。

追記

コメントより

ちなみに横列で検索していく動きになってますが、縦列で検索していく事は可能でしょうか？

Option Explicit
Private idx As Long

'縦移動
Private Sub CommandButton1_Click()
    Dim r As Long, c As Long, i As Long
    With UsedRange
        If idx = 0 Or idx >= .Count Then idx = 1
        For c = 1 To .Columns.Count
            For r = 1 To .Rows.Count
                i = i + 1
                If i < idx Then
                ElseIf Application.Evaluate("COUNT(FIND({0,1,2,3,4,5,6,7,8,9}," & .Item(r, c).Address & "))") > 0 Then
                    .Item(r, c).Activate
                    GoTo ExitFor
                End If
            Next
        Next
ExitFor:
        idx = i + 1
    End With
End Sub

Comments

[MSC]

ご回答ありがとうございます。分かりにくい記述で申し訳ないです。
数字を含むセルをA1セルから順番に選択する（単純に選択せるだけ）だけです。
回答で頂いたコードですと、数字を含むセルを同時に選択していますが、
一つずつセルを選択していくイメージです。
処理内容は数字を含むセルを1セルづつ選択していくだけです。

自身が提示した該当のコードですと、"1"を含むセルをA1から列ごとに順番に
選択することはできのですが、その他の0,2,3,4,5,6,7,8,9を含むセルを選択できようになっています

[hatena19]

例えば、下記のようなことでしょうか。
シート上にコマンドボタンが配置されていて、それをクリックすると最初の数字を含むセルを選択(Activate)。
次に、コマンドボタンをクリックすると次の数字を含むセルを選択。
・・・
最後まで選択して、コマンドボタンをクリックしたら、
メッセージボックスで「これ以降に数字を含むセルはありません。」

[MSC]

はい。作用でございます。
msgboxでの表示は必要ないですが、
数字の含むセルを次々と選択（Activate）してくれたら良いんです。

[hatena19]

回答にコードを追記しましたので、ご参考に。

[MSC]

ありがとうございます。実現したい動作ができました。
ちなみに横列で検索していく動きになってますが、縦列で検索していく事は可能でしょうか？

Answer 2

文字列の中に含まれるのは数字であって数値ではないですし、そもそもActiveに出来るセルは１つだけですからちょっと選択肢が違うように感じます。
セル検索範囲が不明ですが順次セルの値を調べていって該当するか否かの判定をするしかないのでは？
データが行列でどのようになっているのかわかりませんがそう感じました。