質問をすることでしか得られない、回答やアドバイスがある。

15分調べてもわからないことは、質問しよう!

ただいまの
回答率

90.35%

VBAのShell関数で起動したアプリの終了方法について

解決済

回答 1

投稿 編集

  • 評価
  • クリップ 0
  • VIEW 19K+

M-Kajiwara

score 22

質問内容

VBA(Access)
Shellで起動したアプリケーションを終了させるサンプルソースを作成したのですが上手く動作しません。
Shellでの起動までは動作するのですが、終了ができずメモ帳が開いたままになります。

質問1.「btnCloseHandle_Click」「btnSendMessage_Click」それぞれの関数で、開いたアプリケーションを終了できるようにしたいです。

サンプルのソースコード

Option Compare Database
Option Explicit

Private Declare Function OpenProcess Lib "kernel32.dll" (ByVal dwAccess As Long, ByVal fInherit As Integer, ByVal hObject As Long) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Long) As Long
Private Declare Function TerminateProcess Lib "kernel32" (ByVal hProcess As Long, ByVal uExitCode As Long) As Long

Private Const WM_CLOSE = &H10
Private Const SYNCHRONIZE = &H100000
Private Const PROCESS_TERMINATE = &H1

Private lngPid As Long
Private lngWid As Long

Private Sub btnCloseHandle_Click()
    lngPid = Shell("notepad.exe", vbNormalFocus)
    Call CloseHandle(lngPid)

End Sub

Private Sub btnSendMessage_Click()
    lngPid = Shell("notepad.exe", vbNormalFocus)
    lngWid = OpenProcess(SYNCHRONIZE, True, lngPid)
    Call SendMessage(lngWid, WM_CLOSE, 0&, 0&)

End Sub

' 2016/06/01 16:58 追記
Private Sub btnTerminateProcess_Click()
    lngPid = Shell("notepad.exe", vbNormalFocus)
    lngWid = OpenProcess(SYNCHRONIZE Or PROCESS_TERMINATE, True, lngPid)
    Call TerminateProcess(lngWid, 0&)

End Sub

環境

Windows7 x64
Access2010 x84(OS 64bit環境にOffice32bit版をインストールしています)

  • 気になる質問をクリップする

    クリップした質問は、後からいつでもマイページで確認できます。

    またクリップした質問に回答があった際、通知やメールを受け取ることができます。

    クリップを取り消します

  • 良い質問の評価を上げる

    以下のような質問は評価を上げましょう

    • 質問内容が明確
    • 自分も答えを知りたい
    • 質問者以外のユーザにも役立つ

    評価が高い質問は、TOPページの「注目」タブのフィードに表示されやすくなります。

    質問の評価を上げたことを取り消します

  • 評価を下げられる数の上限に達しました

    評価を下げることができません

    • 1日5回まで評価を下げられます
    • 1日に1ユーザに対して2回まで評価を下げられます

    質問の評価を下げる

    teratailでは下記のような質問を「具体的に困っていることがない質問」、「サイトポリシーに違反する質問」と定義し、推奨していません。

    • プログラミングに関係のない質問
    • やってほしいことだけを記載した丸投げの質問
    • 問題・課題が含まれていない質問
    • 意図的に内容が抹消された質問
    • 広告と受け取られるような投稿

    評価が下がると、TOPページの「アクティブ」「注目」タブのフィードに表示されにくくなります。

    質問の評価を下げたことを取り消します

    この機能は開放されていません

    評価を下げる条件を満たしてません

    評価を下げる理由を選択してください

    詳細な説明はこちら

    上記に当てはまらず、質問内容が明確になっていない質問には「情報の追加・修正依頼」機能からコメントをしてください。

    質問の評価を下げる機能の利用条件

    この機能を利用するためには、以下の事項を行う必要があります。

回答 1

checkベストアンサー

0

btnSendMessage_Click関数の中で開いたメモ帳を閉じたいのであれば、その時lngPid に取得しておいたウィンドウハンドルを使ってクローズしてあげればいいと思います。

いま閉じないと思われているのは、btnCloseHandle_Click関数の中でも

lngPid = Shell("notepad.exe", vbNormalFocus)


を行い、新たなメモ帳を起動し、そのウィンドウハンドルに対してクロ-ズしているからではないでしょうか?

追記

TerminateProcessで完結したものと思い込んでいましたが、まだ未解決のようでしたので遅くなってしまいましたが追記いたします。


まず、CloseHandleについてですが、ハンドルを解放する関数とされているので私もこれで終了できるつもりでいましたが、実際できないようです。
ここらへん知識乏しくて申し訳ないです。※詳しい方いましたら補足お願いしますm(__)m


次にOpenProcessについてですが、この戻り値はプロセスのハンドルでありウィンドウハンドルではありません。
このため、取得結果に対してSendMessageしても目的のウィンドウには届きません。
※運が悪ければ意図しない他のアプリを終了してしまうかもしれません。


最後にTerminateProcessについてですが、これはプロセスIDを使ってプロセスを終了することができます。
しかしタスクマネージャから強制終了(KILL)させているような終了方法なので、あまり好ましい方法ではありません。


TerminateProcess以外の方法で終了させる方法を紹介します。

方法1:プロセスIDでアプリをアクティブ化して、SendKeyで終了操作を送信する。

Sub Sample1()
    'メモ帳をShell起動してプロセスIDを取得
    lngPid = Shell("notepad.exe", vbNormalFocus)
    Call Shell("calc.exe", vbNormalFocus)  '←ダミーで別アプリも起動

    'プロセスIDでアプリをアクティブ化
    Call AppActivate(lngPid)

    'メモ帳の終了操作(Alt→F→X)をSend
    Application.SendKeys "%FX"
End Sub


対象アプリを一度アクティブ化するので、画面最前面に表示されることになります。

方法2:プロセスIDからウィンドウハンドルを取得する

Option Explicit

'WindowsAPI定義
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Long) As Long
Public Declare Function IsWindowVisible Lib "user32.dll" (ByVal hwnd As Long) As Long
Public Declare Function GetWindowThreadProcessId Lib "user32.dll" (ByVal hwnd As Long, ByRef ProcessId As Long) As Long
Public Declare Function EnumWindows Lib "user32" (ByVal lpEnumFunc As Long, ByVal lParam As Long) As Long

'定数定義
Public Const WM_CLOSE = &H10

'共通変数
Public lngPid As Long
Public lngWid As Long

Sub Sample2()
    Dim lWid As Long

    'メモ帳をShell起動してプロセスIDを取得する
    lngPid = Shell("notepad.exe", vbNormalFocus)
    Call Shell("calc.exe", vbNormalFocus)  '←ダミーで別アプリも起動

    'プロセスIDからウインドウハンドルを取得
    lWid = GetHwndFromPid(lngPid)

    If lWid = 0 Then
        MsgBox "NotFound"
        Exit Sub
    End If

    Call SendMessage(lngWid, WM_CLOSE, 0&, 0&)

End Sub

'プロセスIDからウィンドウハンドルを検索
Public Function GetHwndFromPid(ByVal pid As Long) As Long
    Dim hwnd As Long
    '初期化
    lngWid = 0
    Call EnumWindows(AddressOf GetProc, 0)

    GetHwndFromPid = lngWid

End Function

'EnumWindowsのコールバック関数
Public Function GetProc(ByVal hwnd As Long, lParam As Long) As Boolean
    GetProc = True
    If IsWindowVisible(hwnd) <> 0 Then
        '非表示ウィンドウでない場合、PIDのチェック
        If GetPidFromHwnd(hwnd) = lngPid Then
            '同じPIDを見つけたら、ウィンドウハンドルを格納
            lngWid = hwnd
            '戻り値FalseでEnumWindowsのループが終了
            GetProc = False
        End If
    End If
End Function

'ウィンドウハンドルからをプロセスIDを取得
Public Function GetPidFromHwnd(ByVal hwnd As Long) As Long
    Dim pid As Long

    Call GetWindowThreadProcessId(hwnd, pid)

    GetPidFromHwnd = pid
End Function


APIも多く、コールバック関数を使ったりと難易度高めになってしまいますが、ウィンドウハンドルを取得する場合はこの方法が確実です。


遅レスとなってしまいましたが、参考になれば幸いです。

投稿

編集

  • 回答の評価を上げる

    以下のような回答は評価を上げましょう

    • 正しい回答
    • わかりやすい回答
    • ためになる回答

    評価が高い回答ほどページの上位に表示されます。

  • 回答の評価を下げる

    下記のような回答は推奨されていません。

    • 間違っている回答
    • 質問の回答になっていない投稿
    • スパムや攻撃的な表現を用いた投稿

    評価を下げる際はその理由を明確に伝え、適切な回答に修正してもらいましょう。

  • 2016/06/01 13:10

    早いご回答ありがとうございます。
    サンプルソースでは、それぞれの関数でメモ帳を起動した直後に終了するようにしています。

    jawa様がおっしゃっているのは、
    btnSendMessage_Click関数で開いたメモ帳を、
    btnCloseHandle_Click関数で閉じる場合の問題点、
    という風に私は捉えたのですがどうでしょうか。

    2種類の終了方法を試すために、分かりにくいソースになってすみません。

    キャンセル

  • 2016/06/01 13:22 編集

    そうでしたか、失礼しました。

    では、64bit環境で実行しているようですので、Long型では戻り値が足りていないのかもしれません。
    lngPid をLongPtr型としてみてはいかがでしょうか?

    参考:https://msdn.microsoft.com/ja-jp/library/ee691831.aspx

    ※検証環境がないので憶測の回答ですみません。

    キャンセル

  • 2016/06/01 17:04

    > lngPid をLongPtr型としてみてはいかがでしょうか?
    検証を行いましたが、残念ながら動作は変わらずでした。

    参考までにTerminateProcessを試したところ、
    こちらはメモ帳の起動後に終了することができました。
    ※ソースコードに追記しました。

    参考URLもありがとうございます。
    Officeの64bitと32bitで問題が出ることは聞いたことがありましたが、
    具体的にどこが問題になるのか知らなかった為、とても参考になりました。

    キャンセル

  • 2016/08/16 17:09

    追記に気付かず長い間放置してしまいました。
    申し訳ないです。

    OpenProcessについて、
    プロセスのハンドルを渡すことで正しく終了させることができました。

    アプリを終了させる方法として、
    TerminateProcessを使用していましたが、プロセスKILLしているとのことなので、
    OpenProcessを利用することで、無事目的を達成しました。

    その他の終了方法についても、教えて頂きありがとうございます。
    状況に応じ選択肢の一つとさせて頂きます。

    ありがとうございました。

    キャンセル

15分調べてもわからないことは、teratailで質問しよう!

  • ただいまの回答率 90.35%
  • 質問をまとめることで、思考を整理して素早く解決
  • テンプレート機能で、簡単に質問をまとめられる

同じタグがついた質問を見る